Ausführen von virtuellem Linux mit qemu unter Windows

16

Ich versuche, Qemu 1.3 für Windows zu verwenden, um lubuntu auf einem USB-Stick mit Windows 7 auszuführen. Nachdem ich Qemu auf meinen USB-Stick heruntergeladen und entpackt habe, erhalte ich Folgendes, wenn ich auf qemu.io.exe klicke

qemu-io.exe>

Wie starte ich meine heruntergeladene Linux .iso-Datei? Es klingt einfach, ist mir aber auf der Qemu-Website nicht klar.

linux virtualization qemu

— user61629
quelle

3

Das Qemu-Handbuch wäre ein guter Anfang. Es wird Ihnen helfen, herauszufinden, was Sie als nächstes tun sollen, nämlich Qemu zu sagen, was zu tun ist und wie genau das zu tun ist.

— Xyon
quelle

2

Ich nehme das als Antwort, obwohl das Handbuch nicht sehr spezifisch für das zu sein scheint, was ich versuche zu tun. Ich bin nicht begeistert von den Dokumenten hier, es sei denn, ich vermisse etwas.

— user61629

22

Hier erfahren Sie, wie ich eine Minimalversion von CentOS 7 unter Windows 7 Enterprise (64 Bit) ausführe, ohne Mitglied der Administratorgruppe zu sein (kein Administrator).

Die Grundidee ist:

Laden Sie qemu für Windows herunter und entpacken Sie es überall
Laden Sie ein ISO-Image der Linux-Distribution herunter, die Sie ausführen möchten
Erstellen Sie eine Datei, die Ihre Festplatte für die virtuelle Maschine ist
Führen Sie qemu aus und booten Sie vom CD-Image
Installieren Sie das Betriebssystem
Starten Sie die virtuelle Maschine neu, diesmal ohne das CD-Image

Netzwerke und ausgefallene Grafiken sind schwer zu finden. Eigentlich immer noch Probleme ...

1. Laden Sie QEMU herunter

Verwenden Sie eine vorkompilierte Binärdatei auf der QEMU-Linkseite . Ich habe dafür Version 2.8.0 verwendet .

Um diese Version als Nicht-Administrator zu "installieren", öffnen Sie eine Eingabeaufforderung, geben Sie den Befehl aus set __COMPAT_LAYER=RunAsInvokerund führen Sie qemu-w64-setup-20170131.exediese Eingabeaufforderung aus. Installieren Sie in einem Ordner, in dem Sie über Schreibberechtigungen verfügen, z. B. "Eigene Dateien" oder ähnliches.

2. Laden Sie ein ISO-Image von Linux herunter

Wieder helfen Sie sich. Ich habe die Minimal Distribution von CentOS 7 verwendet , die Datei heißt CentOS-7-x86_64-Minimal-1611.iso.

3. Erstellen Sie eine virtuelle Festplatte

Ich habe dafür eine Batch-Datei verwendet. Kopieren Sie Folgendes in eine Datei mit dem Namen createvm.batund passen Sie die Variablen an Ihre Umgebung an:

@echo off
rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem Safety net
rem ==================================
if not exist hda.img (
    rem CREATE a virtual hard disk 
    %QEMUDIR%\qemu-img.exe create hda.img 40G
) else (
    echo file hda.img already exist. Delete or move and try again.
    goto:eof
)

4. Führen Sie QEMU aus und starten Sie von der virtuellen CD

Verwenden Sie für diesen einen Stapel, da Sie ihn möglicherweise häufig verwenden. Kopieren Sie das Folgende in installvm.bat:

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"
set "ISOFILE=CentOS-7-x86_64-Minimal-1611.iso"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -cdrom %ISOFILE% -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot

5. Installieren Sie das Betriebssystem

Ich hatte Probleme mit dem GUI-Installationsprogramm. Wenn Sie aufgefordert werden, CentOS zu installieren, TABdrücken Sie die Taste und ersetzen Sie das Wort quietam Ende dieser Zeile durch das Wort text.

Befolgen Sie die Installationsanweisungen auf dem Bildschirm. Nach Abschluss der Installation wird die virtuelle Maschine beendet. Dies kann eine Weile dauern, insbesondere wenn Sie als Benutzer ohne Administratorrechte ausgeführt werden.

6. Führen Sie Ihr Linux-Image in QEMU aus

Diesen Schritt führen Sie immer wieder aus, um die VM jedes Mal auszuführen, wenn Sie sie benötigen. Kopieren Sie das Folgende in runvm.bat:

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot -device e1000,netdev=user.0 -netdev user,id=user.0,hostfwd=tcp::2222-:22

Ich habe eine lokale Portforward hinzugefügt: Wenn Sie ssh / putty zu localhost: 2222 senden, erreichen Sie den SSH-Daemon Ihrer VM. Beachten Sie dies firewalldoder blockieren Sie iptables möglicherweise den Datenverkehr, je nachdem, wie Sie Linux installiert haben.

— ixe013
quelle

1

Sehr geschätzt!

— user61629