Ich laufe zur Zeit OS X (10.9.1) und versucht , nur die ⌘+ ⇧+ .Tastenkombination in einem Dialogfeld speichern und es funktionierte gut.
Ich habe auch Setup ein Applescript auf meiner Maschine mit einer Tastenkombination ^+ ⌘+ ⇧+ , .die die Sichtbarkeit von versteckten Dateien im Finder schaltet , wann immer ich will. Auf diese Weise muss ich keinen Terminalbefehl manuell ausführen, um versteckte Dateien anzuzeigen, und ich kann ihn schnell deaktivieren, um zu vermeiden, dass Systemdateien versehentlich geändert werden. Ich verwende FastScripts (auch im Mac App Store erhältlich ), um die Tastenkombination für mein AppleScript festzulegen und das AppleScript in meinem ~/Library/ScriptsOrdner abzulegen.
Aktualisieren
Ich habe mein Skript so aktualisiert, dass Finder nicht jedes Mal beendet werden muss, wenn Sie die Anzeige versteckter Dateien ein- / ausblenden möchten. Wie markhunte hervorhob, können Sie den Ansichtsstatus des Finder-Fensters umschalten, um die Liste der Inhalte zu aktualisieren. Danke, markhunte, dass du mich darauf aufmerksam gemacht hast! Hier ist das aktualisierte Skript:
(*
Author: Anil Natha
Description:
This script toggles the visibility of hidden files in OS X. This includes
showing hidden files in Finder windows and on the desktop.
Last Updated: 2015-02-20
*)
tell application "System Events"
try
set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
on error
set hiddenFilesDisplayStatus to "NO"
end try
set hiddenFilesNewDisplayStatus to "NO"
if hiddenFilesDisplayStatus is "NO" then
set hiddenFilesNewDisplayStatus to "YES"
end if
do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus
end tell
tell application "Finder"
set allWindows to windows
repeat with currentWindow in allWindows
set currentWindowView to get the current view of the currentWindow
set alternateWindowView to list view
if currentWindowView is list view then
set alternateWindowView to icon view
end if
set the current view of the currentWindow to alternateWindowView
set the current view of the currentWindow to currentWindowView
end repeat
end tell
Eine ältere Version des Skripts ist unten aufgeführt. Obwohl es funktioniert, empfehle ich, es jetzt nicht mehr zu verwenden, da das obige Skript effizienter funktioniert.
tell application "System Events"
set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
set hiddenFilesNewDisplayStatus to "NO"
if hiddenFilesDisplayStatus is "NO" then
set hiddenFilesNewDisplayStatus to "YES"
end if
do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus
do shell script "killall Finder"
end tell