Was ist das Windows-Batch-Äquivalent zum Linux-Shell-Befehl, echo -nder den Zeilenumbruch am Ende der Ausgabe unterdrückt?

Die Idee ist, innerhalb einer Schleife in dieselbe Zeile zu schreiben.

Mit setund dem /pParameter können Sie ohne Zeilenumbruch wiedergeben:

C:\> echo Hello World
Hello World

C:\> echo|set /p="Hello World"
Hello World
C:\>

Quelle

Verwenden von: echo | set /p=oder <NUL set /p=funktionieren beide, um die neue Zeile zu unterdrücken.

Dies kann jedoch sehr gefährlich sein, wenn beim Überprüfen des ERRORLEVEL erweiterte Skripte geschrieben werden, da die Einstellung set /p=ohne Angabe eines Variablennamens den ERRORLEVEL auf 1 setzt.

Ein besserer Ansatz wäre, einfach einen Dummy-Variablennamen wie folgt zu verwenden:
echo | set /p dummyName=Hello World

Dies wird genau das produzieren, was Sie wollen, ohne dass im Hintergrund hinterhältige Dinge vor sich gehen, da ich es auf die harte Tour herausfinden musste, aber dies funktioniert nur mit der Piped-Version. <NUL set /p dummyName=Helloerhöht weiterhin den FEHLER auf 1.

Die einfache SET / P-Methode weist Einschränkungen auf, die zwischen den Windows-Versionen geringfügig variieren.

• Führende Anführungszeichen können entfernt werden

• Führender Leerraum kann entfernt werden

• Führen =führt zu einem Syntaxfehler.

Weitere Informationen finden Sie unter http://www.dostips.com/forum/viewtopic.php?f=3&t=4209 .

jeb hat eine clevere Lösung veröffentlicht, die die meisten Probleme bei der Ausgabe von Text ohne Zeilenvorschub löst , selbst mit führendem Leerzeichen oder = Ich habe die Methode so verfeinert, dass absolut jede gültige Stapelzeichenfolge ohne die neue Zeile unter jeder Windows-Version sicher gedruckt werden kann ab XP. Beachten Sie, dass die :writeInitializeMethode ein Zeichenfolgenliteral enthält, das möglicherweise nicht gut auf der Site veröffentlicht wird. Es ist eine Bemerkung enthalten, die beschreibt, wie die Zeichenfolge aussehen soll.

Die Methoden :writeund :writeVarsind so optimiert, dass nur Zeichenfolgen mit störenden Hauptzeichen mit meiner modifizierten Version der COPY-Methode von jeb geschrieben werden. Nicht störende Zeichenfolgen werden mit der einfacheren und schnelleren SET / P-Methode geschrieben.

@echo off
setlocal disableDelayedExpansion
call :writeInitialize
call :write "=hello"
call :write " world!%$write.sub%OK!"
echo(
setlocal enableDelayedExpansion
set lf=^


set "str= hello!lf!world^!!!$write.sub!hello!lf!world"
echo(
echo str=!str!
echo(
call :write "str="
call :writeVar str
echo(
exit /b

:write  Str
::
:: Write the literal string Str to stdout without a terminating
:: carriage return or line feed. Enclosing quotes are stripped.
::
:: This routine works by calling :writeVar
::
setlocal disableDelayedExpansion
set "str=%~1"
call :writeVar str
exit /b


:writeVar  StrVar
::
:: Writes the value of variable StrVar to stdout without a terminating
:: carriage return or line feed.
::
:: The routine relies on variables defined by :writeInitialize. If the
:: variables are not yet defined, then it calls :writeInitialize to
:: temporarily define them. Performance can be improved by explicitly
:: calling :writeInitialize once before the first call to :writeVar
::
if not defined %~1 exit /b
setlocal enableDelayedExpansion
if not defined $write.sub call :writeInitialize
set $write.special=1
if "!%~1:~0,1!" equ "^!" set "$write.special="
for /f delims^=^ eol^= %%A in ("!%~1:~0,1!") do (
  if "%%A" neq "=" if "!$write.problemChars:%%A=!" equ "!$write.problemChars!" set "$write.special="
)
if not defined $write.special (
  <nul set /p "=!%~1!"
  exit /b
)
>"%$write.temp%_1.txt" (echo !str!!$write.sub!)
copy "%$write.temp%_1.txt" /a "%$write.temp%_2.txt" /b >nul
type "%$write.temp%_2.txt"
del "%$write.temp%_1.txt" "%$write.temp%_2.txt"
set "str2=!str:*%$write.sub%=%$write.sub%!"
if "!str2!" neq "!str!" <nul set /p "=!str2!"
exit /b


:writeInitialize
::
:: Defines 3 variables needed by the :write and :writeVar routines
::
::   $write.temp - specifies a base path for temporary files
::
::   $write.sub  - contains the SUB character, also known as <CTRL-Z> or 0x1A
::
::   $write.problemChars - list of characters that cause problems for SET /P
::      <carriageReturn> <formFeed> <space> <tab> <0xFF> <equal> <quote>
::      Note that <lineFeed> and <equal> also causes problems, but are handled elsewhere
::
set "$write.temp=%temp%\writeTemp%random%"
copy nul "%$write.temp%.txt" /a >nul
for /f "usebackq" %%A in ("%$write.temp%.txt") do set "$write.sub=%%A"
del "%$write.temp%.txt"
for /f %%A in ('copy /z "%~f0" nul') do for /f %%B in ('cls') do (
  set "$write.problemChars=%%A%%B    ""
  REM the characters after %%B above should be <space> <tab> <0xFF>
)
exit /b

Als Ergänzung zur Antwort von @ xmechanix bemerkte ich beim Schreiben des Inhalts in eine Datei:

echo | set /p dummyName=Hello World > somefile.txt

Dies fügt am Ende der gedruckten Zeichenfolge ein zusätzliches Leerzeichen hinzu , was unpraktisch sein kann, insbesondere da wir versuchen, das Hinzufügen einer neuen Zeile (eines weiteren Leerzeichens) am Ende der Zeichenfolge zu vermeiden.

Glücklicherweise zitieren Sie die zu druckende Zeichenfolge, dh verwenden Sie:

echo | set /p dummyName="Hello World" > somefile.txt

Druckt die Zeichenfolge am Ende ohne Zeilenumbruch oder Leerzeichen.

Eine Lösung für den gestrippten Leerraum in SET / P:

Der Trick ist das Backspace-Zeichen, das Sie im Texteditor EDIT for DOS aufrufen können . Um es in EDIT zu erstellen, drücken Sie Strg + Strg . Ich würde es hier einfügen, aber diese Webseite kann es nicht anzeigen. Es ist jedoch auf dem Editor sichtbar (es ist wie ein kleines schwarzes Rechteck mit einem weißen Kreis in der Mitte).

Also schreibst du das:

<nul set /p=.9    Hello everyone

Der Punkt kann ein beliebiges Zeichen sein. Er dient nur dazu, SET / P mitzuteilen, dass der Text dort vor den Leerzeichen beginnt und nicht beim " Hallo ". Die " 9 " ist eine Darstellung des Backspace-Zeichens, das ich hier nicht anzeigen kann. Sie müssen es anstelle der 9 setzen, und es löscht das " . ", Danach erhalten Sie Folgendes:

    Hello Everyone

anstatt:

Hello Everyone

Ich hoffe, es hilft

Sie können die Newline mit "tr" aus gnuwin32 ( coreutils- Paket) entfernen.

@echo off
set L=First line
echo %L% | tr -d "\r\n"
echo Second line
pause

Übrigens, wenn Sie viel schreiben, ist gnuwin32 eine Goldmine.

Hier ist eine andere Methode, sie verwendet Powershell Write-Host, der einen -NoNewLine-Parameter hat, kombiniert diesen mit start /bund bietet die gleiche Funktionalität aus dem Batch.

NoNewLines.cmd

@ECHO OFF
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 1 - ';Write-Host -NoNewLine 'Result 2 - ';Write-Host -NoNewLine 'Result 3 - '"
PAUSE

Ausgabe

Result 1 - Result 2 - Result 3 - Press any key to continue . . .

Das folgende ist etwas anders, funktioniert nicht genau so, wie es das OP will, ist aber interessant, da jedes Ergebnis das vorherige Ergebnis überschreibt, das einen Zähler emuliert.

@ECHO OFF
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 1 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 2 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 3 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 4 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 5 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 6 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 7 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 8 - '"
start /b /wait powershell.exe -command "Write-Host -NoNewLine 'Result 9 - '"
PAUSE

Von hier aus

<nul set /p =Testing testing

und auch beginnend mit Leerzeichen zu wiederholen

echo.Message goes here

Vielleicht ist es das, wonach du suchst, es ist ein Drehbuch der alten Schule ...: P.

set nl=^& echo. 
echo %nl%The%nl%new%nl%line%nl%is%nl%not%nl%apparent%nl%throughout%nl%text%nl%
echo only in prompt.
pause

oder versuchen Sie vielleicht, eine aktuelle Zeile zu ersetzen, anstatt in eine neue Zeile zu schreiben? Sie können damit experimentieren, indem Sie "% bs%" nach "." Zeichen und auch durch Abstand der anderen "% bs%" nach der "Beispielnachricht".

for /f %%a in ('"prompt $H&for %%b in (1) do rem"') do set "bs=%%a"
<nul set /p=.%bs%         Example message         %bs%
pause

Ich finde das wirklich interessant, weil es eine Variable für einen anderen Zweck als den vorgesehenen verwendet. Wie Sie sehen können, steht "% bs%" für eine Rücktaste. Das zweite "% bs%" verwendet die Rücktaste, um Leerzeichen nach der "Beispielnachricht" hinzuzufügen, um die Ausgabe des "Pausenbefehls" zu trennen, ohne tatsächlich ein sichtbares Zeichen nach der "Beispielnachricht" hinzuzufügen. Dies ist jedoch auch mit einem regulären Prozentzeichen möglich.

DIY- cw.exeDienstprogramm (Konsolenschreiben)

Wenn Sie es nicht sofort finden, können Sie selbst basteln. Mit diesem cwDienstprogramm können Sie alle Arten von Zeichen verwenden. Zumindest würde ich das gerne glauben. Bitte testen Sie es und lassen Sie es mich wissen.

Werkzeuge

Alles, was Sie brauchen, ist .NET installiert, was heutzutage sehr verbreitet ist.

Materialien

Einige Zeichen eingegeben / kopiert.

Schritte

1. Erstellen Sie eine .batDatei mit dem folgenden Inhalt.

/* >nul 2>&1

@echo off
setlocal

set exe=cw
for /f "tokens=* delims=" %%v in ('dir /b /s /a:-d  /o:-n "%SystemRoot%\Microsoft.NET\Framework\*csc.exe"') do set "csc=%%v"

"%csc%" -nologo -out:"%exe%.exe" "%~f0"

endlocal
exit /b %errorlevel%

*/

using System;

namespace cw {
    class Program {
        static void Main() {
            var exe = Environment.GetCommandLineArgs()[0];
            var rawCmd = Environment.CommandLine;
            var line = rawCmd.Remove(rawCmd.IndexOf(exe),exe.Length).TrimStart('"');
            line = line.Length < 2 ? "\r" : line.Substring(2) ;
            Console.Write(line);
        }
    }
}

2. Starte es.

3. Jetzt haben Sie ein nettes 4KB-Dienstprogramm, mit dem Sie das löschen können .bat.

Alternativ können Sie diesen Code als Unterprogramm in einen beliebigen Stapel einfügen, das Ergebnis .exean senden %temp%, ihn in Ihrem Stapel verwenden und ihn löschen, wenn Sie fertig sind.

Wie benutzt man

Wenn Sie etwas ohne neue Zeile schreiben möchten:
cw Whatever you want, even with "", but remember to escape ^|, ^^, ^&, etc. unless double-quoted, like in "| ^ &".

Wenn Sie einen Wagenrücklauf wünschen (bis zum Zeilenanfang), führen Sie einfach aus
cw

Versuchen Sie dies über die Befehlszeile:

for /l %a in (1,1,1000) do @(cw ^|&cw&cw /&cw&cw -&cw&cw \&cw)

Ich habe aus @arneps Idee eine Funktion gemacht:

echo | set / p = "Hallo Welt"

hier ist es:

:SL (sameline)
echo|set /p=%1
exit /b

Verwenden Sie es mit call :SL "Hello There"
Ich weiß, dass dies nichts Besonderes ist, aber ich habe so lange gebraucht, um darüber nachzudenken, dass ich dachte, ich würde es hier posten.

Beispiel 1: Dies funktioniert und erzeugt Exit-Code = 0. Das ist gut. Beachten Sie das "." direkt nach dem Echo.

C: \ Users \ phife.dog \ gitrepos \ 1 \ repo_abc \ scripts #
@echo. | set / p JUNK_VAR = Dies ist eine Meldung, die so angezeigt wird, als würde Linux echo -n sie anzeigen ... & echo% ERRORLEVEL%

Dies ist eine Meldung, die so angezeigt wird, als würde Linux echo -n sie anzeigen ... 0

Beispiel 2: Dies funktioniert , erzeugt jedoch den Exit-Code = 1. Das ist schlecht. Bitte beachten Sie das Fehlen von "." Nach dem Echo. Das scheint der Unterschied zu sein.

C: \ Users \ phife.dog \ gitrepos \ 1 \ repo_abc \ scripts #
@echo | set / p JUNK_VAR = Dies ist eine Meldung, die so angezeigt wird, als würde Linux echo -n sie anzeigen ... & echo% ERRORLEVEL%

Dies ist eine Meldung, die so angezeigt wird, als würde Linux echo -n sie anzeigen ... 1

Inspiriert von den Antworten auf diese Frage habe ich ein einfaches Counter-Batch-Skript erstellt, das den Fortschrittswert (0-100%) in derselben Zeile druckt (wobei der vorherige überschrieben wird). Vielleicht ist dies auch für andere wertvoll, die nach einer ähnlichen Lösung suchen.

Anmerkung : Es *handelt sich um nicht druckbare Zeichen. Diese sollten mit der Tastenkombination [ Alt+ Numpad 0+ Numpad 8] eingegeben werden. Dies ist das backspaceZeichen.

@ECHO OFF

FOR /L %%A in (0, 10, 100) DO (     
    ECHO|SET /P="****%%A%%"    
    CALL:Wait 1
)

GOTO:EOF

:Wait
SET /A "delay=%~1+1"
CALL PING 127.0.0.1 -n %delay% > NUL
GOTO:EOF

Ich glaube, es gibt keine solche Option. Alternativ können Sie dies versuchen

set text=Hello
set text=%text% world
echo %text%

Sie können die neue Zeile mit dem Befehl set / p unterdrücken. Der Befehl set / p erkennt kein Leerzeichen. Dazu können Sie einen Punkt und ein Rücktastezeichen verwenden, damit es erkannt wird. Sie können eine Variable auch als Speicher verwenden und darin speichern, was Sie drucken möchten, sodass Sie die Variable anstelle des Satzes drucken können. Beispielsweise:

@echo off
setlocal enabledelayedexpansion
for /f %%a in ('"prompt $H & for %%b in (1) do rem"') do (set "bs=%%a")
cls
set "var=Hello World! :)"
set "x=0"

:loop
set "display=!var:~%x%,1!"
<nul set /p "print=.%bs%%display%"
ping -n 1 localhost >nul
set /a "x=%x% + 1"
if "!var:~%x%,1!" == "" goto end
goto loop

:end
echo.
pause
exit

Auf diese Weise können Sie alles ohne neue Zeile drucken. Ich habe das Programm erstellt, um die Zeichen einzeln zu drucken, aber Sie können auch Wörter anstelle von Zeichen verwenden, indem Sie die Schleife ändern.

Im obigen Beispiel habe ich "enabledelayedexpansion" verwendet, damit der Befehl set / p "!" Nicht erkennt. Zeichen und druckt stattdessen einen Punkt. Ich hoffe, dass Sie nicht das Ausrufezeichen "!" ;)

Späte Antwort hier, aber für alle, die Sonderzeichen in eine einzelne Zeile schreiben müssen , die die Antwort von dbenham als etwa 80 Zeilen zu lang empfinden und deren Skripte (möglicherweise aufgrund von Benutzereingaben) unter den Einschränkungen der einfachen Verwendung beschädigt werden können set /p, es ist wahrscheinlich am einfachsten , nur um Ihre .bat oder .cmd mit einem kompilierten C ++ oder C-Sprache ausführbar zu paaren und dann einfach coutoder printfdie Charaktere. Auf diese Weise können Sie auch problemlos mehrere Male in eine Zeile schreiben, wenn Sie eine Art Fortschrittsbalken oder etwas mit Zeichen anzeigen, wie es OP anscheinend war.