Erstellen Sie eine neue (.txt) Datei im Finder - Tastaturkürzel

Ich wollte wissen, ob es eine Möglichkeit gibt, Tastaturkürzel festzulegen, um neue Dateien im Finder zu erstellen. Zum Beispiel in der Standardeinstellung können Sie einen neuen Ordner mit erstellen CMD+ Shift+ N. Gibt es eine Tastenkombination zum Erstellen einer neuen Textdatei? Ich bin ein Programmierer, daher wäre dies äußerst nützlich

Ich wäre auch daran interessiert, einen anderen Dateityp mithilfe von Tastaturkürzeln zu erstellen.

Ich habe versucht, Automator zu verwenden, aber ich finde es ziemlich verwirrend und bin mir nicht sicher, wie ich eine Tastenkombination daran anschließen würde.

Nun, hier geht es mit einem AppleScript.

Erstellen Sie zuerst das AppleScript:

1. Öffnen Sie Automator
2. Erstellen Sie eine Schnellaktion
3. Setzen Sie den Eingang auf keinen Eingang
4. Ziehen Sie das AppleScript- Workflowelement " Ausführen" per Drag & Drop auf die graue Fläche.
5. Fügen Sie den Code von unten in das AppleScript ein
6. Speichern Sie den Workflow als Neue Datei erstellen.
   Wenn Sie iCloud Drive aktiviert haben, stellen Sie sicher, dass Sie die Datei unter Library/Services/in Ihrem Basisordner speichern .

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

So fügen Sie es als Verknüpfung hinzu:

• Gehen Sie zu Systemeinstellungen -> Tastatur -> Verknüpfungen -> Dienste
• Scrollen Sie nach unten, bis Sie den Dienst Neue Datei erstellen finden
• Weisen Sie ihm eine Verknüpfung zu, indem Sie auf die rechte Seite none klicken , was zu a wird Add Shortcut.
  Klicken Sie auf die Schaltfläche und geben Sie die gewünschte Verknüpfung ein.
  Ich benutze ⌘ Command+ ⌥ Option+N

Ich habe ein AppleScript erstellt, das dem von @ YoshiBotX sehr ähnlich ist, aber einige Verbesserungen aufweist.

Die Idee ist, einen Automator-Workflow zu erstellen und ihm eine Verknüpfung zuzuweisen, indem Sie die folgenden Schritte ausführen:

• Öffnen Sie Automator und erstellen Sie einen Service .
• Setzen Sie die Eingabe auf keine Eingabe und die Anwendung auf Finder.app .
• Ziehen Sie das AppleScript- Workflowelement " Ausführen" auf die graue Fläche und legen Sie es dort ab.
• Fügen Sie den Inhalt dieses AppleScript in das Textfeld ein.
• Speichern Sie den Workflow unter einem vernünftigen Namen (z. B. Neue Datei ).
• Gehen Sie zu Einstellungen -> Tastatur -> Verknüpfungen -> Dienste und weisen Sie ihr eine Verknüpfung zu.

Lassen Sie uns nun das AppleScript anzeigen:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Der Einfachheit halber füge ich dieses AppleScript in diesen GitHub Gist ein .

Sie können einen Automator-Service selbst erstellen - dies ist recht einfach. Anschließend können Sie ihm eine Tastenkombination zuweisen, damit Sie den Dienst nicht über das Menü Dienste aktivieren müssen (was Sie auch tun können).

Öffnen Sie Automator und wählen Sie Service als Typ des neuen Dokuments.

Stellen Sie den Dienst so ein, dass in Finder.app keine Eingaben empfangen werden, und fügen Sie dem Workflow die Aktion "Neues TextEdit-Dokument" hinzu.

Speichern Sie den Dienst und öffnen Sie dann Systemeinstellungen → Tastatur → Verknüpfungen → Dienste. Dort finden Sie den Dienst unter Allgemein mit dem Namen, den Sie beim Speichern des Dienstes angegeben haben.

Fügen Sie dem Dienst eine Tastenkombination hinzu, indem Sie den Dienst auswählen und dann auf "Verknüpfung hinzufügen" klicken.

Hier können Probleme auftreten, wenn die Verknüpfung bereits verwendet wird. Seien Sie also kreativ und erstellen Sie eine, die für Sie funktioniert.

Sie können einem Skript auch eine Verknüpfung wie folgt zuweisen :

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

Die Einfügeposition ist entweder das Ziel des vordersten Finder-Fensters oder des Desktops.

Terminal öffnen und eingeben

touch filename

oder

> filename

Dies ist ein Repost eines Beitrags, den ich letztes Jahr gemacht habe. Ich habe gute Erfahrungen mit den folgenden gemacht.

Sie können zwei nützliche Dienstprogramme herunterladen und installieren, mit denen Sie eine neue Textdatei (oder RTF-Datei) in einem aktuell geöffneten Ordner erstellen können, den Sie mit dem Finder anzeigen.

Die Dienstprogramme heißen NewTextFileHere und NewRTFHere und können von heruntergeladen werden

http://mac.softpedia.com/developer/Jonas-Wisser-37498.html

Symbole für eine dieser Apps können dann in alle Finder-Fenster eingefügt werden.

Genau das, wonach ich gesucht hatte, Richard Fuhr. Danke dafür.

Ein Hinweis: Der Link dieser URL für NewTextFileHere scheint auf eine leere Seite zu laden. Aber ich habe eine Suche durchgeführt und die App hier gefunden: http://mac.softpedia.com/progDownload/NewTextFileHere-Download-70374.html

Wenn Sie BetterTouchTools bereits installiert haben (es war früher eine kostenlose App, jetzt gibt es ein Pay-What-You-Want-Modell mit einer 30-tägigen Testversion), können Sie mit a die Aktion finden, die "Utility Actions > Create New File in Current Folder"genau dies ausführt Pop-up, damit Sie den Namen auswählen können. Weisen Sie die gewünschte Verknüpfung zu (ich habe Wahl + Umschalt + N gewählt), und Sie können loslegen.

Wenn Sie MacVim verwenden, gibt es eine Option Finder -> Services, um einen neuen vim-Puffer zu erstellen:

Ich habe dies auf die Abkürzung ShiftcmdMin abgebildet System Preferences -> Keyboard -> Shortcuts: