Liste bekannter Dateitypen

Wie kann ich eine Liste der Namen von Dateitypen abrufen, die vim derzeit kennt?

Ich möchte in der Lage sein, dies zu tun, damit ich, wenn vim einen Dateityp nicht automatisch erkennt, einige der von vim bekannten Dateitypen ausprobieren kann.

Ich weiß, dass Vimscript-Dateien, die sich mit Dateitypen befassen, ftpluginnach Konvention in das Verzeichnis gestellt werden, aber das müssen sie nicht (ich bin nicht sicher, aber ich denke nicht, dass die Vimscript-Dateien im ftpluginVerzeichnis etwas Besonderes sind), also möchte ich nur Fragen Sie vim, welche Dateitypen es kennt, unabhängig davon, wie es von ihnen erfahren hat.

Einfache Lösung

Geben Sie :setfiletype (mit einem Leerzeichen danach) ein und drücken Sie dann Ctrl-d.

Sehen Sie :help cmdline-completionfür weitere Informationen über die automatische Vervollständigung in der Befehlszeile des vim.

Komplizierte Lösung

Diese Lösung verwendet die 'runtimepath'Option, um alle verfügbaren Syntaxverzeichnisse abzurufen, und ruft dann eine Liste der Vimscript-Dateien in diesen Verzeichnissen ab, deren Erweiterungen entfernt wurden. Dies ist möglicherweise nicht die sicherste Methode, daher sind Verbesserungen willkommen:

function! GetFiletypes()
    " Get a list of all the runtime directories by taking the value of that
    " option and splitting it using a comma as the separator.
    let rtps = split(&runtimepath, ",")
    " This will be the list of filetypes that the function returns
    let filetypes = []

    " Loop through each individual item in the list of runtime paths
    for rtp in rtps
        let syntax_dir = rtp . "/syntax"
        " Check to see if there is a syntax directory in this runtimepath.
        if (isdirectory(syntax_dir))
            " Loop through each vimscript file in the syntax directory
            for syntax_file in split(glob(syntax_dir . "/*.vim"), "\n")
                " Add this file to the filetypes list with its everything
                " except its name removed.
                call add(filetypes, fnamemodify(syntax_file, ":t:r"))
            endfor
        endif
    endfor

    " This removes any duplicates and returns the resulting list.
    " NOTE: This might not be the best way to do this, suggestions are welcome.
    return uniq(sort(filetypes))
endfunction

Sie können diese Funktion dann wie gewünscht verwenden, z. B. um alle Werte in der Liste auszudrucken. Das könnten Sie so machen:

for f in GetFiletypes() | echo f | endfor

Beachten Sie, dass dies wahrscheinlich ziemlich stark komprimiert werden kann. Dies dient nur der Lesbarkeit. Ich werde nicht alle hier verwendeten Funktionen und Befehle erklären, aber hier sind alle Hilfeseiten für sie:

• :help 'runtimepath'
• :help :let
• :help :let-&
• :help split()
• :help :for
• :help expr-.
• :help :if
• :help isdirectory()
• :help glob()
• :help fnamemodify()
• :help add()
• :help uniq()
• :help sort()

Wenn Ihre Version von vim aktuell genug ist (v7.4.2011 +), können Sie mit der Funktion, die wir jetzt zur Definition der manuellen automatischen Vervollständigung verwenden können, nach bekannten Dateitypen fragen: getcompletion()

:echo getcompletion('', 'filetype')

Wenn Sie die Liste auf Dateitypen beschränken möchten, die mit a beginnen 'c', rufen Sie an

:echo getcompletion('c', 'filetype')

und so weiter.

Hinweis: Im Gegensatz zu Lösungen, in denen die Dateinamen und Verzeichnisnamen $VIMRUNTIME/{syntax,filetype}/analysiert werden, wird auch diese Lösung analysiert 'runtimepath'. Soweit ich weiß, werden keine neuen Dateitypen angezeigt, die im laufenden Betrieb set ft=foobaroder nach automatischen Befehlen definiert / registriert wurden .

Sie können auch alle Dateitypen im Terminal drucken, indem Sie die folgenden 2 Befehle ausführen:

1.

cd $(vim -e -T dumb --cmd 'exe "set t_cm=\<C-M>"|echo $VIMRUNTIME|quit' | tr -d '\015')

2.

cat <(ls -1 ftplugin/*.vim) <(ls -1 syntax/*.vim) | tr '\n' '\0' | xargs -0 -n 1 basename | sort | uniq | cut -f 1 -d '.'

Der erste Befehl navigiert einfach zu Ihrem vim-Laufzeitpfad (für mich war es / usr / share / vim / vim80 ).

Der zweite Befehl listet alle Dateitypnamen in den beiden Ordnern auf, in denen vim die Dateitypdefinitionen speichert.

Aktualisieren

Verbesserungsvorschläge für die beiden Befehle von muru, die Folgendes bieten:

1.

cd $(vim -Nesc '!echo $VIMRUNTIME' -c qa)

2.

find syntax ftplugin -iname '*.vim' -exec basename -s .vim {} + | sort -u