Ist es möglich, zwei verschiedene Farbhintergründe in einem einzigen VIM-Puffer zu verwenden?

Ich suche nach einer möglichen Lösung für das Anwenden von zwei verschiedenen Hintergrundfarben in einem einzelnen Vim-Puffer, abhängig vom Kontext, wie in diesem hervorragenden Textbeispiel .

Ein Anwendungsfall besteht darin, Codeausschnitte in Markup-Dateien anders zu färben, damit sie besser zur Geltung kommen.

Ich habe jedoch noch nie ein Beispiel mit einem solchen Setup gesehen.

Ist das überhaupt in vim möglich?

Weil ich neugierig war, wie gut das funktionieren würde, habe ich so etwas zusammen gehackt.

Wie in den Kommentaren zur früheren Antwort erwähnt, besteht die einzige Möglichkeit darin, Regionen mit Leerzeichen zu füllen. was ist genau das, was wir tun; Bevor Sie schreiben, entfernen wir diese Leerzeichen, sodass Sie niemanden damit belästigen sollten.

Beachten Sie, dass dieses Beispiel sehr spezifisch für den Abschriften-Dateityp ist!

Nebenwirkungen :

• Beim Kopieren von Text werden auch viele Leerzeichen kopiert
• Die Verwendung von $und Endfunktioniert nicht mehr wie erwartet (siehe Spalte 80), und Tasten wie jund kverhalten sich ebenfalls anders.
• Der Hintergrund wird nicht angezeigt, wenn 'list'aktiviert ist
• Völlig leere Zeilen funktionieren nicht, Sie müssen manuell einen Tabulator oder 4 Leerzeichen hinzufügen
• ... vielleicht mehr?

Zuerst müssen Sie dies zu Ihrem hinzufügen ~/.vim/after/syntax/markdown.vim:

syn clear markdownCodeBlock                                                 
syn region markdownCodeBlock start="    \|\t" end="$"                       
hi def markdownCodeBlock ctermbg=230 guibg=lightyellow                      

Sie können die Farben natürlich nach Ihren Wünschen anpassen ;-)

Dann fügen Sie dies zu Ihrem vimrc hinzu:

fun! MarkdownBlocks()                                                       
    fun! s:fill(line)                                                       
        " Remove all trailing whitespace                                    
        let l:line = substitute(a:line, " *$", "", "")                      

        " Add trailing whitespace up to 'textwidth' length                  
        return l:line . repeat(' ', (&tw > 0 ? &tw : 80) - strdisplaywidth(l:line))
    endfun                                                                  

    " Get all lines in a list                                               
    let l:lines = getline(1, line('$'))                                     

    " Map s:fill() to the lines that are a code block                       
    call map(l:lines, 'v:val[0] == "\t" || v:val[:3] == "    " ? s:fill(v:val) : v:val')

    " Reset the buffer to the lines                                         
    call setline(1, l:lines)                                                
endfun                                                                      

" Remove all the trailing spaces                                            
fun! MarkdownBlocksClean()                                                  
    let l:save_cursor = getpos(".")                                         
    silent %s/^\(    \|\t\)\(.\{-}\)\( *\)$/\1\2/e                          
    call setpos('.', l:save_cursor)                                         
endfun                                                                      
au BufWritePre *.markdown call MarkdownBlocksClean()                        

" Set spaces on loading the file, leaving insert mode, and after writing it 
au FileType markdown call MarkdownBlocks()                                  
au InsertLeave *.markdown call MarkdownBlocks()                             
au BufWritePost *.markdown call MarkdownBlocks()                            

Ich werde den Code nicht Zeile für Zeile erklären, die Kommentare sollten den allgemeinen Kern klarstellen ;-)

Es ist durchaus möglich, für syntaktisch hervorgehobene Elemente eine andere Hintergrundfarbe zu verwenden. Definieren Sie einfach die guibgund ctermbgFarben in Ihrem hilightBefehl. Ersteres legt die Hintergrundfarbe für GUI Vim und letzteres für Terminal Vim fest.

Dies hat jedoch die wichtige Einschränkung, dass nur die Hintergrundfarben für Zeichen festgelegt werden können, die tatsächlich in der Datei vorhanden sind.

Dies hat zur Folge, dass sich die Hintergrundfarbe nicht über das Ende des Texts in einer Zeile bis zum Fensterrand erstrecken kann. Daher ist die Färbung der in Ihrem Beispiel gezeigten Codeblöcke nicht möglich:

Sie können auch die Hintergrundfarbe ganzer Linien mit der Funktion „Signieren“ ändern. (Siehe linehlin :help sign.txt)

Beachten Sie jedoch Folgendes:

1. Dazu muss Code geschrieben werden, um Zeichen in jede Zeile zu setzen, die gefärbt werden müssen, und diese müssen aktualisiert werden, wenn sich der Inhalt der Datei ändert.

2. Standardmäßig wird beim Platzieren eines Zeichens die Zeichenspalte links im Fenster angezeigt. Es ist möglich, die Farbe der Zeichenspalte mit der Markierungsgruppe zu ändern SignColumn, und in neueren Versionen von Vim kann sie vollständig entfernt werden. (Siehe :help 'signcolumn'.)

Um beispielsweise die Carpetsmoker-Lösung so anzupassen , dass sie den ( stabileren ) Zeichenmechanismus verwendet, können Sie Folgendes tun:

" Define a highlight group and a sign that uses it
highlight default markdownCodeBlock ctermbg=230 guibg=lightyellow
sign define codeblock linehl=markdownCodeBlock

" Use signs to highlight code blocks
function! MarkdownBlocks()
    function! s:applySign(idx, val)
        if a:val[0] == "\t" || a:val[:3] == "    "
            let l = a:idx + 1
            execute "sign place " . l . " line=" . l . " name=codeblock file=" . expand("%:p")
        endif
    endfunction

    " Remove old signs
    execute "sign unplace * file=" . expand("%:p")

    " Get all lines in a list
    let l:lines = getline(1, line('$'))
    " Add new signs
    call map(l:lines, function('s:applySign'))
endfunction

" Set signs on loading the file, leaving insert mode, and after writing it
au FileType markdown call MarkdownBlocks()
au InsertLeave *.markdown call MarkdownBlocks()
au BufWritePost *.markdown call MarkdownBlocks()

Dies vereinfacht den Code etwas und hat weniger Einschränkungen als die Carpetsmoker-Version.

@ChristianBrabandt ‚s DynamicSigns Plugin die Sign - Funktion für diesen Zweck macht die Verwendung einfacher: Er beschreibt , wie es so in tun , verwendet diese Antwort .