Der Wert meiner Variablen ist 0, aber ich habe ihn nicht auf 0 gesetzt

Heute habe ich festgestellt, dass eine meiner zsh-Funktionen nicht funktioniert. Ich habe das Problem untersucht und der Schuldige war folgender:

for i in a b
do
echo "$i"
done
0
0

Dann habe ich ein neues zsh eröffnet und dabei funktionierten die Dinge normal:

for i in a b
do
echo "$i"
done
a
b

Kann mir jemand den Grund erklären, warum sich der erste komisch verhält?

% typeset -i i
% for i in a b; print $i
0
0

Variablen in zshkönnen verschiedene Typen zugewiesen werden, oben -ifür "intern als Ganzzahl darstellen", wodurch die Variable als solche dargestellt wird. Dies kann auch über erfolgen integer i. Es gibt verschiedene Möglichkeiten, um zu überprüfen, was eine Variable ist:

% print ${(t)i}
integer
% typeset -p i
typeset -i i=0

Und die übliche Shell +zu deaktivieren (siehe auch set -x, set +x) es:

% typeset +i i
% for i in a b; print $i
a
b

Es kann nützlich sein, herauszufinden, was den Typ dieser Variablen geändert hat, und diese Änderung auf einen lokalen Bereich (innerhalb einer Funktion) zu beschränken, damit der globale Namespace nicht mit zufälligen Typen verschmutzt wird, insbesondere bei häufig verwendeten wegwerfbaren Variablennamen wie z i. Es ist ziemlich einfach, den globalen Namespace zu verschmutzen, da lediglich eine Zuweisung zu einer nicht deklarierten Variablen erforderlich ist:

% () { local l=42; g=43 }
% print $l

% print $g
43

Oder jemand könnte das -gFlag unnötig zu einem hinzufügen typeset, wodurch die Variable global wird:

% () { typeset -g -i h=42 }
% for h in a b; print $h
0
0

Exportierte Variablen bleiben möglicherweise in neuen Prozessen erhalten (ein untergeordnetes Nicht-Subshell-Via forkoder ein Ersatz-Via exec), jedoch nicht der Typ:

% export -i h=42
% print $h ${(t)h}
42 integer-export

% ( print ${(t)h} )
integer-export

% exec zsh -l
% print $h ${(t)h}
42 scalar-export