Wie erhalte ich nachfolgende Daten des gzip-Archivs?

Ich habe ein gzip-Archiv mit nachgestellten Daten. Wenn ich es damit entpacke, heißt gzip -des: " Dekomprimierung OK, nachlaufender Müll ignoriert " (dasselbe gilt für gzip -tdie Methode zum Erkennen solcher Daten).

Jetzt würde ich diesen Müll gerne kennenlernen, aber seltsamerweise konnte ich keinen Weg finden, ihn zu extrahieren. gzip -l --verbosesagt mir, dass die "komprimierte" Größe des Archivs die Größe der Datei ist (dh mit den nachfolgenden Daten), das ist falsch und nicht hilfreich. fileist auch keine Hilfe, also was kann ich tun?

Jetzt herausgefunden, wie man die nachfolgenden Daten erhält.

Ich habe ein Perl-Skript erstellt, das eine Datei mit den nachfolgenden Daten erstellt. Es basiert stark auf https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=604617#10 :

#!/usr/bin/perl
use strict;
use warnings; 

use IO::Uncompress::Gunzip qw(:all);
use IO::File;

unshift(@ARGV, '-') unless -t STDIN;

my $input_file_name = shift;
my $output_file_name = shift;

if (! defined $input_file_name) {
  die <<END;
Usage:

  $0 ( GZIP_FILE | - ) [OUTPUT_FILE]

  ... | $0 [OUTPUT_FILE]

Extracts the trailing data of a gzip archive.
Outputs to stdout if no OUTPUT_FILE is given.
- as input file file causes it to read from stdin.

Examples:

  $0 archive.tgz trailing.bin

  cat archive.tgz | $0

END
}

my $in = new IO::File "<$input_file_name" or die "Couldn't open gzip file.\n";
gunzip $in => "/dev/null",
  TrailingData => my $trailing;
undef $in;

if (! defined $output_file_name) {
  print $trailing;
} else {
  open(my $fh, ">", $output_file_name) or die "Couldn't open output file.\n";
  print $fh $trailing;
  close $fh;
  print "Output file written.\n";
}