Wie verwende ich sort für einen awk print-Befehl?

Ich habe ein paar Befehle in einem awk-Skript, das ich schreibe:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2}

Welche Ausgänge:

Here are some players and their numbers, sorted by last name
Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55

Wie kann ich den sortBefehl in meinem awk-Skript verwenden , um NUR die Spieler und ihre Nummern zu sortieren?

Sie können | sort -k2Ihrem Befehl hinzufügen . Dies wird alphabetisch nach der zweiten Spalte sortiert.

Beispiel:

$ echo "Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55" | sort -k2

führt zu

Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

Obwohl ich es nicht empfehlen würde (angesichts der relativ einfachen Weiterleitung des Ergebnisses über einen externen sortBefehl), können Sie dies zumindest mit neueren Versionen von GNU awk (mindestens 4.0 IIRC) tun, wie unter Sortieren von Array-Werten und -Indizes mit gawk beschrieben

So können Sie es implementieren, vorausgesetzt, Sie haben die Daten in einem assoziativen Array, in dem sich der Index befindet Firstname Lastname. Zuerst müssen Sie eine benutzerdefinierte Vergleichsfunktion definieren, die den Index aufteilt, zuerst vergleicht und Lastnamedann (als Tie Breaker) Firstnamez

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

Jetzt können Sie die PROCINFO["sorted_in"]in den Kommentaren von @zwets erwähnte Array-Sortiermethode verwenden

PROCINFO["sorted_in"] = "mycmp";
for(i in a) print i, a[i];

Etwas zusammensetzen

#!/usr/bin/gawk -f

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

{
  a[$1" "$2] = $3;
}

END {
  PROCINFO["sorted_in"] = "mycmp";
  for(i in a) print i, a[i];
}

Testen:

$ ./namesort.awk yourfile
Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

In kleineren oder älteren Versionen von awk ist es möglicherweise am besten, die von indizierten Daten zu speichern, Lastname Firstnamestattdessen mit den herkömmlichen zu sortieren asortiund dann die Felder der Indizes zu teilen und auszutauschen, während Sie das Array durchlaufen, um es zu drucken:

awk '
  {a[$2" "$1]=$3} 
  END {
    n=asorti(a,b); for (i=1;i<=n;i++) {split(b[i],s); print s[2], s[1], a[b[i]]}
}' yourfile

Um sortnur durch das Leerzeichen getrennt zweite Feld Taste -k2,2:

... | sort -k2,2

Standardmäßig sorterfolgt die Sortierung lexikografisch.

Beachten Sie, dass -k2Sie möglicherweise nicht das gewünschte Ergebnis erhalten , wenn Sie das letzte Feld für den Sortierschlüssel nicht erwähnen, dh wenn Sie nur das Feld verwenden, da dies sortfür alle Felder ab der zweiten gilt.

Überprüfen Sie auch man sort.

Versuchen

awk -f myscript.awk | sort -k2

Wobei myscript.awk rein awk-Befehle enthält.

Wenn Ihr eigentliches Skript ein Shell-Skript ist, haben Sie mehrere Möglichkeiten, einschließlich

• Rohrausgabe durch Sortierung. ./myscript.bash | sort -k2

• Rewrite - Code als Funktion im Skript
  statt

  $ cat t1
  #!/bin/bash
  for i in 2 4 3 1 5;
  do
    echo $i
  done
  
  $ ./t1
  2
  4
  3
  1
  5
  

  Tun

  $ cat t2
  #!/bin/bash
  function foo {
    for i in 2 4 3 1 5;
    do
      echo $i
    done
  }
  foo | sort
  
  $ ./t2
  1
  2
  3
  4
  5
  

Beachten Sie jedoch, dass Sie die Sortierung auch auf die do ... done-Struktur anwenden können, anstatt eine Funktion zu erstellen.

    do
       echo $i
    done | sort

So sortieren Sie Ihre zu druckenden Daten:

• Angenommen, Sie möchten das zweite Feld (durch Leerzeichen getrennt) drucken. Verwenden Sie Folgendes:

  awk '{print $2}' data.txt | sort
  

  z.B:

  $cat>data.txt
  1 Kedar 20
  2 Amit 30
  3 Rahul 21
  ^C
  
  $awk '{print $2}' | sort
  Amit
  Kedar
  Rahul
  

• Wenn Sie das gesamte drucken möchten, data.txtaber in Spalte 2 sortiert sind, dann:

  $awk '{print}'|sort -k2
  2 Amit 30
  1 Kedar 20
  3 Rahul 21
  

Verwenden Sie diese Logik (en) in Ihrer Anforderung.

Sie können man sortfür interessantere Funktionen von verwenden sort.

Was ist mit unten:

 awk 'BEGIN{str="1\n2\n3\n4"; system("echo -e \""str"\" | sort -r")}'

es funktioniert, wenn ich getestet habe.

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2"}

So sortieren Sie die Ausgabe in eine Datei:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2 > sortedFile"}