Gibt es überhaupt eine Möglichkeit, diese beiden endgültig zu unterscheiden?

Mir ist klar, dass ich auf dem Startbildschirm nach einer Taskleiste oder einem Netzschalter suchen kann, aber ich bin mehr daran interessiert zu wissen, ob irgendwo tatsächlich 8.1 Update 1 angezeigt wird. Ich weiß, dass MS diese Seite hat , aber eine programmatische Methode, dies zu erkennen schön, vor allem, weil die neuesten ISOs das Update Slipstreaming haben.

Soweit ich das beurteilen kann, sind die Ausgaben von verund wmic oszwischen Windows 8.1 und Windows 8.1 gleich. Update 1 und die Systemeigenschaften melden weiterhin Windows 8.1.

Mögliche Lösungen

Im Folgenden finden Sie einige Batch-Skripte, mit denen überprüft werden kann, ob das Betriebssystem Windows 8.1 mit oder ohne KB2919355 ist . Der Exit-Code lautet wie folgt:

• 0: Windows 8.1
• 1: Windows 8.1 Update (KB2919355 installiert)
• 2: Nicht Windows 8.1

Stapelskript A - Aktualisierungsprüfung

Dies ist der zuverlässigste Weg. Das Skript prüft zunächst, ob das Betriebssystem Windows 8.1 ist, indem es die Version mit vergleicht 6.3.9600. Anschließend werden alle installierten Updates abgefragt, um zu überprüfen, ob das KB2919355-Update bereits installiert wurde.

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

wmic qfe get hotfixid | findstr /i /c:"KB2919355" >nul
set /a errorlevel=%errorlevel% ^^ 1

exit /b %errorlevel%

Batch-Skript B - Versionsprüfung erstellen

Alternativ können Sie die Windows-Buildversion überprüfen, die schneller als das erste Skript ist, da Sie nicht alle Updates auflisten müssen. Da ein Registrierungswert verwendet wird, ist er möglicherweise nicht so zuverlässig.

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

for /f "tokens=4 delims=. " %%G in (
'"reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "BuildLabEx" | findstr /i /c:"REG_SZ" "'
) do set /a build=%%~G

if %build% geq 17031 exit /b 1
exit /b 0

Batch-Skript C - Versionsprüfung erstellen (Internet Explorer)

Genau wie im vorherigen Skript ist auch hier das Konzept ähnlich, außer dass stattdessen die Internet Explorer (IE) -Version aktiviert ist.

@echo off

for /f "usebackq tokens=2 delims==" %%G in (
`wmic os get version /value ^| findstr /c:"="`
) do set version=%%~G

if not "%version%" == "6.3.9600" exit /b 2

for /f "tokens=3,6 delims=. " %%G in (
'"reg query "HKLM\SOFTWARE\Microsoft\Internet Explorer" /v "svcVersion" | findstr /i /c:"REG_SZ" "'
) do set /a major=%%~G & set /a build=%%~H

if %major% equ 11 if %build% geq 17031 exit /b 1
if %major% geq 12 exit /b 1
exit /b 0

Hinweis Das Skript geht davon aus, dass jede IE-Version höher oder gleich 12 auf einem Windows 8.1-System mit installiertem Update KB2919355 verfügbar ist.

Für alle zukünftigen Sicherheits- und Nicht-Sicherheitsupdates für Windows RT 8.1, Windows 8.1 und Windows Server 2012 R2 muss dieses Update installiert sein. Wir empfehlen, dass Sie dieses Update auf Ihrem Windows RT 8.1-, Windows 8.1- oder Windows Server 2012 R2-basierten Computer installieren, um weitere zukünftige Updates zu erhalten.

_{Quelle: Windows RT 8.1, Windows 8.1 und Windows Server 2012 R2 Update: April 2014}

In Anbetracht des oben Gesagten ist es vernünftig zu glauben, dass für jede neuere IE-Version das Update als Voraussetzung erforderlich ist , genau wie SP2 für die Installation von IE 9 unter Windows Vista erforderlich ist .

Analysieren Sie die BuildLabExZeichenfolge

reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" | findstr BuildLabEx

und wenn die Anzahl größer ist als 17031die Benutzer, haben Sie das Update 1 installiert.

Wir verwenden ein Befehlszeilenprogramm namens WuInstall ( http://www.wuinstall.com ), das einige nützliche Dinge rund um das Patchen erledigt, darunter Batch-Skripte, mit denen überprüft werden kann, ob die Updates installiert sind

Befehlszeile, um alle installierten Updates anzuzeigen

WUInstall.exe / search / Kriterien "IsInstalled = 1" / offline

Um zu überprüfen, ob eine bestimmte KB installiert ist (es gibt viele Filteroptionen), können Sie Folgendes überprüfen:

WUInstall.exe / search / Kriterien "IsInstalled = 1" / offline / match "KB982214"

Das Dienstprogramm führt eine Befehlszeilenausgabe aus, die mit der Option / xmlout in eine XML-Datei umgeleitet oder einfach in eine Datei mit zB> out.txt umgeleitet werden kann

Ich suche einfach in Windows nach einem "Winstore" -Ordner, da ich festgestellt habe, dass dies ein offensichtlicher Unterschied in allen Windows-Versionen ist.

Kann sogar den Befehl WinStore ausführen, um ihn anzuzeigen.

REM Simulation der Betriebssystemprüfung: Installieren Sie c: cd \ falls vorhanden "c: \ windows \ WinStore" und gehen Sie zu WIN8

: Win8 REM-spezifischer Code für eine Win8-Maschine