Deaktivieren oder verzögern Sie den Aero Peek-Effekt mit Alt + Tab in Windows 7

Unter Windows 7 wird durch Drücken von Alt+ Tabder Effekt „Transparente Fenster“ (Aero) angezeigt. Der Bildschirmwechsel lenkt ab, während ich versuche, anhand der Miniaturvorschau herauszufinden, zu welchem ​​Fenster ich wechseln soll (was für mich die meiste Zeit ausreicht). Gibt es eine Möglichkeit, den Aero Peek-Effekt auszuschalten oder seine Aktivierung auf etwa 6 Sekunden zu verzögern?

In der Taskleiste wird der Aero Peek-Effekt bei Bedarf aufgerufen, wenn ich mit der Maus über die tatsächlichen Miniaturansichten fahre. Dieses Verhalten ist kein Problem, und wenn ich eine Auswahl habe, möchte ich nicht, dass es deaktiviert wird.

Möglicherweise finden Sie vistaswitcher mehr nach Ihren Wünschen. Es gibt eine sofortige Vorschau-Box in der Mitte des Bildschirms (konfigurierbar), ohne dass die Transparenz langsam ausgeblendet wird. Versuch es!

Es gibt keine Möglichkeit, Aero Peek für nur Alt-Tab richtig zu deaktivieren , aber Sie können die Verzögerung auf einen absurd hohen Wert einstellen, wodurch sie effektiv deaktiviert wird. Es gibt einen weiteren Beitrag , der diesen Prozess detailliert beschreibt. Im Wesentlichen müssen Sie den DWORD-Wert LivePreview_msin HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\AltTabeiner sehr großen Anzahl erstellen . Dieser Schlüssel speichert die Zeit in Millisekunden bis zur Verzögerung. 60000 sollten also ausreichen, da ich bezweifle, dass Sie die Alt-Tab-Taste länger als eine Minute gedrückt halten.

Beachten Sie, dass durch das Festlegen des Registrierungsschlüssels 0Aero-peek für Alt-Tab vollständig deaktiviert wird. Sie müssen sich abmelden und erneut anmelden, damit die Änderung wirksam wird.

Sie können dies in der Leistung beheben. Ich hatte das gleiche Problem. Es ist nicht "unser Gehirn hat Probleme", es ist beschissene Benutzerfreundlichkeit aufgrund von aufgedunsenen Funktionen. Alt-Tab war in Vista mehr oder weniger perfekt.

Gehen Sie zu Anpassen visueller Effekte (über Leistung in der Systemsteuerung) und deaktivieren Sie Aero Peek.

Ein weiterer Trick, den Sie machen können, ist die Verwendung des "alten" Alt-Tabs, der in Windows 7 vorhanden ist:

1. Halten Sie die linke Alt-Taste gedrückt
2. Tippen Sie auf die rechte Alt-Taste
3. Halten Sie die linke Alt-Taste weiterhin gedrückt und drücken Sie die Tabulatortaste, wie Sie es normalerweise tun würden, um durch Aufgaben zu blättern

Sie werden feststellen, dass dies den alten Umschalter im Alt-Tab-Stil verwendet und keine Fenster für Sie ausgeblendet.

Sie könnten an einer Windows 7-Funktion interessiert sein, die der Alt-Tab-Funktion ähnelt: WinKey + 1, WinKey + 2, WinKey + 3 usw. Diese Hotkeys aktivieren die Fenster in der Taskleiste an den Positionen 1, 2, 3 usw.

Wenn Sie Ihre häufig verwendeten Programme an die Taskleiste anheften, befinden sie sich immer an einer bestimmten "Steckplatzposition" in der Taskleiste. Aus diesem Grund ist es ganz einfach zu merken, welcher WinKey + N mit welchem ​​Programm übereinstimmt . Durch wiederholtes Drücken von WinKey + N wird die Alt-Tabulatortaste nur durch die geöffneten Fenster des Programms gedrückt . Ich finde dies besonders nützlich bei Windows Explorer-Fenstern, da oft viele geöffnet sind.

Ich weiß, dass dies ein ziemlich altes Thema ist, aber ich mochte die Areo Peek-Funktion auch nie, wenn ich Alt+ TABzum Wechseln von Aufgaben verwendete. Außerdem lehne ich Areo Peek nicht vollständig ab - ich schaue mir zum Beispiel gerne meinen Windows-Desktop mit WIN+ an Space.

Ich habe viel versucht, Areo Peek nur für das Wechseln von Alt+ TABAufgaben zu deaktivieren , aber für mich hat nichts wirklich funktioniert. Ich kenne alle Registrierungshinweise, zum Beispiel das Einstellen der Aero Peek-Verzögerung in Millisekunden auf einen sehr hohen Wert. Dies funktioniert aber nicht, zumindest nicht auf allen Rechnern - aus meiner Erfahrung können Sie einen hohen Wert einstellen, der intern immer noch auf 3000 ms begrenzt ist (möglicherweise hat dies vor dem Service Pack für Windows 7 funktioniert).

Also habe ich beschlossen, einen anderen Weg zu gehen und zu versuchen, dieses Problem über AutoHotkey zu lösen . Dieses Skript deaktiviert Aero Peek nur für Alt+ TABund nur für dieses - damit Sie die anderen Aero Peek-Funktionen weiterhin verwenden können.

Das Skript wurde gegen die AutoHotkey-Version "AutoHotkey_L 1.1.00.00" mit Windows 7 Professional 64-Bit mit einem Windows-Benutzer mit Administratorrechten getestet - und soll bisher auf allen Systemen funktionieren, von denen ich Feedback erhalten habe. Installieren Sie einfach AutoHotkey und legen Sie fest, dass die Skriptdatei beim Start von Windows automatisch ausgeführt wird. Es ist sehr leicht und verbraucht nur sehr wenig Ressourcen und CPU-Zeit.

Ich poste es einfach hier in der Hoffnung, dass dies jedem helfen wird, der dieses Problem hat. Bitte laden Sie das Skript herunter von:

http://dl.dropbox.com/u/15020526/Privat/Software/GA/AutoHotkey/DisableAeroPeekForAltTab_1.0.zip

; ==============================================================
;
; AVOID "AERO PEEK" FOR ALT-TAB - AUTOHOTKEY-SCRIPT
; 
; Disables Windows 7 Areo Peek feature for ALT-TAB, and only 
; for this, so that other Areo Peek features (like WIN+SPACE) 
; can still be used.
;
; This script can be run with AutoHotkey (http://www.autohotkey.com/),
; tested against Version AutoHotkey_L 1.1.00.00 with Windows 7 
; Professional 64 bit with a Windows user with admin rights.
;
; @author   Timo Rumland <timo.rumland${at}the-cr.de>, 19.09.2011
; @version  1.0
;
; --------------------------------------------------------------
;
; LICENSE
; 
; This software is distributed under the FreeBSD License.
;
; Copyright (c) 2011 Timo Rumland <timo.rumland${at}the-cr.de>. All rights reserved.
; 
; Redistribution and use in source and binary forms, with or without modification, are
; permitted provided that the following conditions are met:
; 
;    1. Redistributions of source code must retain the above copyright notice, this list of
;       conditions and the following disclaimer.
; 
;    2. Redistributions in binary form must reproduce the above copyright notice, this list
;       of conditions and the following disclaimer in the documentation and/or other materials
;       provided with the distribution.
; 
; THIS SOFTWARE IS PROVIDED BY <COPYRIGHT HOLDER> ''AS IS'' AND ANY EXPRESS OR IMPLIED
; WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
; FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL <COPYRIGHT HOLDER> OR
; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
; ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
; ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
; 
; The views and conclusions contained in the software and documentation are those of the
; authors and should not be interpreted as representing official policies, either expressed
; or implied, of <copyright holder>.
;
; ==============================================================

#NoEnv
#SingleInstance     force
SendMode            Input 
SetWorkingDir       %A_ScriptDir%
SetTitleMatchMode   2       ; 2: A window's title can contain WinTitle anywhere inside it to be a match. 


; =======
; Global
; =======

    visualEffectsRegistryKey                := Object()
    visualEffectsRegistryKey.valueType      := "REG_DWORD"
    visualEffectsRegistryKey.rootKey        := "HKEY_CURRENT_USER"
    visualEffectsRegistryKey.subKey         := "Software\Microsoft\Windows\CurrentVersion\Explorer\VisualEffects"
    visualEffectsRegistryKey.valueName      := "VisualFXSetting"
    visualEffectsRegistryKey.value          := 3    ; Manual Visual FX Settings

    enableAeroPeekRegistryKey               := Object()
    enableAeroPeekRegistryKey.valueType     := "REG_DWORD"
    enableAeroPeekRegistryKey.rootKey       := "HKEY_CURRENT_USER"
    enableAeroPeekRegistryKey.subKey        := "Software\Microsoft\Windows\DWM"
    enableAeroPeekRegistryKey.valueName     := "EnableAeroPeek"
    enableAeroPeekRegistryKey.enabledValue  := 1
    enableAeroPeekRegistryKey.disabledValue := 0


; ===============
; Initialization
; ===============

    ; Initially write "VisualFXSetting" registry key to "manual settings"
    writeRegistryKey( visualEffectsRegistryKey, visualEffectsRegistryKey.value )


; ========
; Hotkeys
; ========

    ; -----------------------------------------------------------------------------
    ; This is the ALT-TAB hotkey that triggers setting Aero Peek to disabled 
    ; right before Windows displays the ALt-TAB-Menu. After releasing the ALT-key,
    ; Areo Peek will be enabled again.
    ; -----------------------------------------------------------------------------
    ~!Tab::

        writeRegistryKey( enableAeroPeekRegistryKey, enableAeroPeekRegistryKey.disabledValue )
        KeyWait Alt
        writeRegistryKey( enableAeroPeekRegistryKey, enableAeroPeekRegistryKey.enabledValue )

    return


; ==========
; Functions
; ==========

    ; ----------------------------------------------------------------------
    ; Writes the given value to the given registry key. The "registryKey"
    ; is an object with the properties "valueType", "rootKey", "subKey" and
    ; "valueName", suitable to the AHK function "RegWrite".
    ; ----------------------------------------------------------------------
    writeRegistryKey( registryKey, value )
    {
        valueType   := registryKey.valueType
        rootKey     := registryKey.rootKey
        subKey      := registryKey.subKey
        valueName   := registryKey.valueName

        RegWrite %valueType%, %rootKey%, %subKey%, %valueName%, %value%
    }

Sie können es unter der FreeBSD-Lizenz frei verbreiten.

Sie können die Miniaturvorschau in der Mitte des Bildschirms mit der Maus bewegen, während Sie ALT + Tab gedrückt halten. Obwohl die Hintergrundfenster immer noch aktiv sind, wird Ihre Aufmerksamkeit durch die Mausbewegung auf die Miniaturansichten gelenkt. Ich finde das weniger verwirrend als das wiederholte Drücken der Tabulatortaste bei gedrückter ALT-Taste. Klicken Sie dann einfach auf das Fenster, das Sie verschieben möchten.

Auch Win + Tab ist weniger verwirrend. Möglicherweise gewöhnen Sie sich schneller daran als mit Alt + Tab.

Beachten Sie auch, dass Sie das Gegenteil tun können. Bisher haben wir gelernt, auf die mittleren Thumbnails zu achten. Mit dem mit ALT + TAB angebotenen Fenster-Radfahren können Sie jedoch lernen, die mittleren Miniaturansichten zu ignorieren und sich stattdessen auf den Fenster-Zyklus zu konzentrieren. Nach einer Weile bin ich mir ziemlich sicher, dass Sie sich fragen werden, warum dies jemals ein Problem für Sie war. Es ist alles in unserem Gehirn :)

Sie CAN für nur Aero Peek deaktivieren ALT+TAB

Die Lösung besteht darin, den folgenden Registrierungswert festzulegen, der das Windows XP-Verhalten von ALT+ wiederherstellt TAB:

1. Führen Sie REGEDIT.EXE aus
2. Navigiere zu HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer
3. Erstellen Sie einen neuen DWORD-Wert mit dem Namen AltTabSettingsund setzen Sie seinen Wert auf1
4. Die Änderung wird sofort wirksam.

_{credit: Diese SuperUser Antwort}

Die verknüpfte Antwort enthält auch einen PowerShell-Befehl, mit dem der obige Wert erstellt wird:

Set-ItemProperty HKCU:\Software\Microsoft\Windows\CurrentVersion\Explorer AltTabSettings ([int]1)