Wie kann ich Flash Player automatisch aktualisieren, wenn eine neue Version veröffentlicht wird?

Zusammenfassung:

Flash Player - Update - Service nicht auf einem zuverlässigen Zeitplan ausgeführt werden , und nicht automatisch Updates herunterladen und anwenden , wenn es nicht laufen.

Angesichts der Wichtigkeit, eine aktuelle Version von Flash Player zu installieren (für diejenigen von uns, die Chrome nicht mit dem integrierten Player verwenden), möchte ich einen Weg finden, um sicherzustellen, dass neue Updates sofort erkannt werden und installiert.

Was folgt, sind die Details meiner Bemühungen, dieses Problem selbst zu lösen ...

Anhang A: Flash Player-Aktualisierungsdienst

OK, zurück in Flash Player 11.2 (oder so?) Adobe hinzugefügt den Flash Player Update Service (FlashPlayerUpdateService.exe) wurde angeblich der Flash Player auf dem Laufenden halten ...

• Bei der Installation wird FPUS so konfiguriert, dass es als Windows-Dienst ausgeführt wird, wobei der Starttyp auf Manuell eingestellt ist.

• Eine geplante Aufgabe (Adobe Flash Player Updater.job) wird hinzugefügt, um diesen Dienst stündlich zu starten.

So weit, so gut - diese Einrichtung vermeidet einen ständig laufenden Dienst, stellt jedoch sicher, dass die Überprüfungen häufig genug ausgeführt werden, um Aktualisierungen schnell abzufangen. Der Software-Updater von Google ist auf ähnliche Weise konfiguriert, und das funktioniert einwandfrei ...

... Und doch, als ich die Version meines installierten Flash Players überprüfte, stellte ich fest, dass es 11.6.602.180 war , der, basierend auf den Zeitstempeln der Dateien in, C:\Windows\System32\Macromed\Flashzuletzt am Dienstag, dem 12. März, aktualisiert (oder installiert) wurde. 2013 --- 12.03.13, 17:00:08 Uhr .

Ich habe diese Beobachtung am Donnerstag, 25. April 2013, 25.04.13, 19:00:00 Uhr gemacht und beim Überprüfen der Adobe-Website festgestellt, dass die aktuelle Version von Flash Player 11.7.700.169 war .

Das ist mehr als ein Monat seit dem letzten Update. Ein neues Update ist eindeutig auf der Website verfügbar, ohne jedoch darauf hinzuweisen, dass die auf meinem Computer ausgeführte stündliche Überprüfung dies bemerkt hat oder beabsichtigt, es herunterzuladen.

Anhang B: Manuelles Ausführen des Flash Player-Updaters

Wenn Sie einmal ausgeführt haben , erhalten Sie ein Fenster mit der Schaltfläche Installieren . Wenn Sie darauf drücken, wird das Installationsprogramm für die aktuelle Version heruntergeladen (automatisch, ohne einen Browser zu öffnen) und ausgeführt. Anschließend klicken Sie auf das Installationsprogramm und sind fertig. Es war manuell, aber es hat funktioniert! Als ich feststellte, dass meine aktuelle Installation veraltet ist (siehe Anhang A), habe ich zuerst diesen manuellen Aktualisierungsprozess versucht. Jedoch...FlashUtil32_<version>_Plugin.exe -update plugin

• Beim Ausführen (in meinem Fall ) wird nur ein Fenster mit einer Download-Schaltfläche angezeigt. Wenn Sie auf diese Download-Schaltfläche klicken, wird mein Browser mit der URL https://get3.adobe.com/flashplayer/update/activex geöffnet .FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• Beim Ausführen (in meinem Fall ) wird nur ein Fenster mit einer Download-Schaltfläche angezeigt. Wenn Sie auf diese Download-Schaltfläche klicken, wird mein Browser mit der URL https://get3.adobe.com/flashplayer/update/plugin geöffnet .FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

Ich könnte mit der Download-Seite fortfahren, an die ich gesendet wurde, das Kontrollkästchen foistware deaktivieren ("Kostenlos! McAfee Security Scan Plus") und das Installationsprogramm herunterladen (ActiveX, keine foistware: install_flashplayer11x32axau_mssd_aih.exe, Plugin, keine foistware: install_flashplayer11x32au_mssd_aih.exe) Wahrscheinlich haben Sie einen aktualisierten Flash ... aber wozu dient der Flash Player-Aktualisierungsdienst, wenn ich eine andere Exe manuell herunterladen und ausführen muss?

Epilog

Ich habe seitdem den Verdacht, dass der Update-Service absichtlich behindert wird, um Early Adopters auf die manuelle Download-Seite zu bringen. Wenn dies zutrifft, gibt es wahrscheinlich keine Lösung dafür, meinen eigenen Updater zu schreiben. hoffentlich irre ich mich.

Vielleicht wendet der Updater nur Updates im Bereich 11.6.x an?

Sie könnten immer direkte Links zu den Installationsprogrammen verwenden, was ich für zuverlässiger halte : ActiveX ; Plugin .

Mit dieser .bat- Datei wird versucht, den Flash Player für Internet Explorer, Firefox (SeaMonkey usw.), Chromium-basiert (Chrome, Opera 15+ usw.) automatisch zu aktualisieren oder zu installieren :

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

Erforderliches Wget können Sie hier herunterladen und müssen es in dasselbe Verzeichnis stellen, in dem .bat abgelegt wurde.

Ein etwas fortgeschritteneres Beispiel in Autoit .

Features: Einfache Überprüfung auf neue Version, wenn hier keine neue Version, dann beenden Sie das Programm ohne Download Flash Player Installer. Wenn das Download-Installationsprogramm fehlgeschlagen ist, wird das Meldungsfeld mit dem Fehler angezeigt und beendet. Verstecktes Eingabeaufforderungsfenster. Ich brauche kein Wget.

Nach der Installation von Autoit und Editor . Klicken Sie mit der rechten Maustaste auf Desktop-> Neu-> Autoit-Skript. Klicken Sie mit der rechten Maustaste auf diese erstellte Datei-> Bearbeiten. Jetzt sollten Sie das ScITE-Fenster sehen und nach der Zeile "Fügen Sie Ihren Code hier unten hinzu" diesen Code hinzufügen:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

Drücken Sie dann im SciTE-Fenster Extras-> Erstellen oder F7. Jetzt erhalten Sie eine eigenständige ausführbare Datei in demselben Verzeichnis, in dem sich das Autoit-Skript befand.

Ich empfehle, für diesen "Updater" einen neuen Ordner (mit Schreibzugriffsberechtigung) zu erstellen. Sie können diesem "Updater" eine Verknüpfung hinzufügen, um auch zu starten .

Hier App zum Deinstallieren von Flash Player.

Ich möchte nur mein Batch-Skript mit Ihnen teilen. Speichern Sie diesen Code einfach in Ihrem Notizblock und nennen Sie ihn Download_Install_Last_Flash_Player.bat

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************