Excel-Datumsformel - Gibt den nächsten angegebenen Wochentag zurück

1

Ich brauche eine Formel, die immer am nächsten angegebenen Wochentag zurückgegeben wird.

Zum Beispiel

IF(A1="A",RETURN NEXT FRIDAY, IF(A1="B",RETURN NEXT TUESDAY.....ETC

Ich brauche dies deshalb, weil ich eine Gruppe von Konten habe und jedes Konto einen bestimmten Liefertermin hat. Wenn ein Konto der Gruppe A zugewiesen wurde, erfolgt die Lieferung montags, und wenn sie der Gruppe B zugewiesen wurden, Lieferung erfolgt dienstags usw.

Ich denke, aus diesen Beispielen wird die Formel zu einem unterschiedlichen Tag und Datum führen, abhängig davon, welcher Tag "heute" ist. Was ich brauche, ist, dass jedes Konto in Gruppe A standardmäßig auf den nächsten Montag gesetzt wird, unabhängig davon, an welchem Wochentag es derzeit ist. Gruppe A wäre also heute + 4, wenn es Montag ist, aber heute + 3, wenn es Dienstag ist. Ich hoffe das macht Sinn.

microsoft-excel

— Lee Francis
quelle

Müssen Sie sich um Wochenenden, Feiertage, Schalttage kümmern? Welche Version von Excel verwenden Sie auch? Haben Sie auch (wieder) ein Datumsfeld zum Berechnen (wie ein "zugewiesenes Datum")? Sind Sie schließlich bereit, VBA zu verwenden (es ist komplexer, aber einfacher zu bewerkstelligen).

— dav

Hallo David, danke für deine Hilfe. Ja, ich muss Wochenenden und vorzugsweise uk Bankfeiertage ausschließen, obwohl die Feiertage nicht wesentlich sind. Das Datumsfeld zum Berechnen wäre immer = today (), da ich die Formel brauche, um am nächsten Freitag, Montag usw. zurückzukehren, und ich wäre bereit, VBA zu verwenden, aber ich habe noch keine Erfahrung mit VBA. Formel wäre vorzuziehen. Danke nochmal für deine Hilfe

— Lee Francis

1

..Excel Version?

— barry houdini

3

Sie können meinen Vorschlag aus den Kommentaren von Scott verwenden, um den nächsten Tag mit dem variablen Teil zu erhalten, der mit Ihrem Brief verknüpft ist. Wenn also "A" Montag "B" ist, Dienstag, "C" Mittwoch, "D" Donnerstag und "E" Freitag (und Dies sind die einzigen Optionen. Dann können Sie diese Formel verwenden, um am nächsten Wochentag die richtigen Ergebnisse zu erhalten

=TODAY()+8-WEEKDAY(TODAY()-MATCH(A1,{"A","B","C","D","E"},0))

Sie sagten anfangs, Sie wollten Feiertage ausschließen, aber wenn A1 "A" ist und der nächste Montag ein Feiertag ist, wann sollte dann die Lieferung erfolgen?

Wenn Sie am nächsten Werktag nach diesem Montag (unabhängig vom Wochentag) arbeiten, können Sie die obige Funktion in die WORKDAY-Funktion integrieren

=WORKDAY(TODAY()+8-WEEKDAY(TODAY()-MATCH(A1,{"A","B","C","D","E"},0))-1,1,H$1:H$10)

Wo Feiertage in H1: H10 aufgeführt sind

Wenn Sie immer eine Lieferung an einem Montag benötigen, sollte der nächste Montag also ein Feiertag sein (oder der nächste Montag, der kein Feiertag ist), können Sie die Funktion WORKDAY.INTL verwenden (nur in Excel verfügbar) 2010 und später)

=WORKDAY.INTL(C$1,1,REPLACE("1111111",MATCH(A1,{"A","B","C","D","E"},0),1,0),H$1:H$10)

— barry houdini
quelle

Danke Barry, das ist fantastisch. Das hat mir enorm geholfen. Danke nochmal für deine Hilfe

— Lee Francis

1

WEEKDAY( irgendein Datum  )

gibt den Wochentag zurück: Sonntag = 1, Montag = 2, ..., Samstag = 7. So

TODAY()-WEEKDAY(TODAY())

ist der vorige Samstag so

TODAY()-WEEKDAY(TODAY())+2

ist Montag dieser Woche (verwenden Sie 3, 4, 5 oder 6 für Dienstag, ... Freitag). Ich schreibe dies an einem Dienstag, also Montag dieser Woche war gestern und Dienstag dieser Woche ist heute. Um das zu bekommen Nächster eine (z. B. nächsten Dienstag) verwenden

TODAY()-WEEKDAY(TODAY())+3 + IF(WEEKDAY(TODAY())>=3,7)

Viel Glück beim Überspringen von Ferien! :)

— Scott
quelle

1

Sie können die letzte Formel mit dieser Formel vereinfachen: =TODAY()+8-WEEKDAY(TODAY()-2), ändern Sie die 2 für verschiedene Wochentage

— barry houdini