Wie konfiguriere ich Firefox über ein Skript?

Ich möchte die folgenden Firefox-Einstellungen über ein Skript (VBS oder Batch) konfigurieren.

• Standard-Homepage
• Standardsuchmaschine
• Deaktivieren Sie die automatische Aktualisierung

Ist das möglich?

Sie können dies tun, indem Sie Mozilla-Einstellungsdateien mit Ihrer bevorzugten Skriptsprache erstellen oder bearbeiten.

Eine Liste der Einstellungen, die über diese Dateien festgelegt werden können, finden Sie in den Mozilla-Einstellungen und in der Dokumentation zu about: config. Die Einstellungen , die Ihrer Liste entsprechen, scheinen jedoch folgende zu sein: -

• browser.startup.homepage (Standard-Homepage)
• browser.search.defaultenginename (Standardsuchmaschine)
• app.update.auto (Aktivieren / Deaktivieren der automatischen Aktualisierung)

Abhängig von Ihrer Umgebung ist es jedoch möglicherweise besser, die Einstellungen über ein benutzerdefiniertes Add-On (siehe die XPI-Kommentare im Kurzhandbuch zu den Mozilla-Einstellungen ) oder über ein Gruppenrichtlinienobjekt mit FirefoxADM oder ähnlichem zu übertragen.

Sie können die Optionen des privaten Browsers in einer Datei user.js im Ordner Benutzerprofile überschreiben. Ich benutze es oft, um einige Optionen zu überschreiben, zum Beispiel Pipelining. Firefox muss neu gestartet werden, nachdem Sie die Datei user.js aktualisiert haben. Wenn die Datei user.js nicht vorhanden ist, müssen Sie eine erstellen.

um den Teil der Antwort, nach der ich gesucht habe, buchstäblich zu kopieren / einzufügen (win env.)

'C:\Users\User\AppData\Roaming\Mozilla\Firefox\Profiles\#####.default\prefs.js'

hinzufügen

user_pref("browser.startup.homepage", "http://www.URL");

Meine Versuche, mit dem Pfad Get-Content / cat string.txt / "String" >> auf entfernte Computer zu kopieren, endeten damit, dass prefs.jsaufgrund der Escape-Zeichen in der Zeichenfolge Müll in die Datei eingefügt wurde .

cd /D "%APPDATA%\Mozilla\Firefox\Profiles\*.default"

set ffile=%cd%

echo user_pref("browser.startup.homepage", "http://superuser.com");>>"%ffile%\prefs.js"
echo user_pref("browser.search.defaultenginename", "Google");>>"%ffile%\prefs.js"
echo user_pref("app.update.auto", false);>>"%ffile%\prefs.js"
set ffile=

cd %windir%

Der Thread ist ein bisschen alt, aber ich möchte meine Lösung trotzdem teilen. Hoffe das hilft jemandem. Wir hatten ein ähnliches Problem und wollten die Zertifikate aus dem Windows Store in Firefox hinzufügen. Also habe ich ein Skript dafür erstellt. Wie auch immer, Sie können es an Ihre Bedürfnisse anpassen: Fügen Sie einfach die Zeilen unter :: create cfg_file_name.cfg [...] hinzu oder entfernen Sie sie und fügen Sie ein, was Sie benötigen, z. B. zum Starten der Homepage und so weiter. Denken Sie daran, das ^ vor dem letzten zu setzen), sonst funktioniert es nicht! echo pref("browser.startup.homepage", "http://superuser.com"^);

Seit Version 49 können Sie es so machen:

@echo off
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: MAIN INFORMATION
:: Title: Change about:config entries in Mozilla Firefox
:: Author: I-GaLaXy-I
:: Version: 1.1
:: Last Modified: 10.01.2018
:: Last Modified by: I-GaLaXy-I
::------------------------------------------------------------------------------
:: This script will add two files, which will change about:config parameters of
:: Mozilla Firefox. You can change the name of these two files and remove or add
:: parameters according to your needs. Renaming the files could be essential, if
:: a user creates own files and you don't want to overwrite them.
:: 
:: If the two files already exist and the script is run, the complete content
:: of both files will be overwritten!
::
:: Note: You may have to run it with administrative privileges!
::
:: More information: https://developer.mozilla.org/en-US/Firefox/Enterprise_deployment
:: http://kb.mozillazine.org/Locking_preferences
::------------------------------------------------------------------------------
:: Subtitle: Import CAs from Windows certificate store
:: More information: https://serverfault.com/questions/722563/how-to-make-firefox-trust-system-ca-certificates
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Set the name of the .cfg file
set cfg_file_name=add_win_certstore_cas

:: Set the name of the .js file
set js_file_name=add_win_certstore_cas

:: Registry keys to check for the installation path of Mozilla Firefox
set regkey1="HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\Windows\CurrentVersion\App Paths\firefox.exe" /v "Path"
set regkey2="HKEY_LOCAL_MACHINE\SOFTWARE\Clients\StartMenuInternet\FIREFOX.EXE\shell\open\command" /ve

:: Get installation path of Mozilla Firefox (if not found exit script):
reg query %regkey1%
if %errorlevel%==0 (
    :: First key found, getting path
    for /f "tokens=2* delims=    " %%a in ('reg query %regkey1%') do set path_firefox=%%b
) else (
    :: If first key not found, try another one:
    reg query %regkey2%
    if !errorlevel!==0 (
        for /f "tokens=2* delims=    " %%a in ('reg query %regkey2%') do set path_firefox=%%b
        set path_firefox=!path_firefox:\firefox.exe=!
        for /f "useback tokens=*" %%a in ('!path_firefox!') do set path_firefox=%%~a
) else (
    :: No key found, exit script
    exit
))

:: Create cfg_file_name.cfg if it doesn't exist and input the following lines.
:: Caution! If cfg_file_name.cfg already exists, all lines will be overwritten!
:: Add more lines as needed with the following syntax: 
::echo pref("<name_of_config_entry>", <value>^);
(
    echo //Firefox Settings rolled out via KACE from Systec
    echo //Do not manually edit this file because it will be overwritten!
    echo //Import CAs that have been added to the Windows certificate store by an user or administrator.
    echo pref("security.enterprise_roots.enabled", true^);
) > "%path_firefox%\%cfg_file_name%.cfg"

:: Create js_file_name.js if it doesn't exist and input the following lines.
:: Caution! If js_file_name.js already exists, all lines will be overwritten!
(
    echo /* Firefox Settings rolled out via KACE from Systec
    echo Do not manually edit this file because it will be overwritten! */
    echo pref("general.config.obscure_value", 0^);
    echo pref("general.config.filename", "%cfg_file_name%.cfg"^);
) > "%path_firefox%\defaults\pref\%js_file_name%.js"

:: Files created, exit
exit