Wie kann ich die Versionskontrollintegration von zsh selektiv deaktivieren, wenn sich mein CWD auf einem Remote-Dateisystem befindet?

Ich verwende zsh unter OSX und muss gelegentlich auf einem bereitgestellten sshfs-Volume arbeiten. Allerdings ist Git über sshfs-Mounts WIRKLICH langsam. Meine Eingabeaufforderung verwendet das in zsh integrierte Programm für den vc-Modus. In diesem Fall möchte ich diesen Teil jedoch überspringen.

Ich möchte die VC-Integration jederzeit selektiv deaktivieren, wenn sich mein CWD auf einem bereitgestellten Dateisystem befindet. Wie kann ich das machen?

Ich aktiviere derzeit Git-Informationen in meiner Eingabeaufforderung, indem ich (ungefähr) dieses Snippet meiner .zshrc-Datei verwende (naja, .oh-my-zsh / themes, aber Sie haben die Idee):

zstyle ':vcs_info:*' enable hg git bzr svn p4

zstyle ':vcs_info:(hg*|git*):*' get-revision true
zstyle ':vcs_info:(hg*|git*):*' check-for-changes true

# rev+changes branch misc
zstyle ':vcs_info:hg*' formats "[%i%u %b%m]"
zstyle ':vcs_info:hg*' actionformats "(%{$fg_bold[red]%}%a%{$reset_color%})[%i%u %b%m]"

# hash changes branch misc
zstyle ':vcs_info:git*' formats "[%{$fg[yellow]%}%12.12i%{$reset_color%} %u %{$fg[magenta]%}%b%{$reset_color%}%m]"
zstyle ':vcs_info:git*' actionformats "(%a)[%{$fg[yellow]%}%12.12i%{$reset_color%} %u %{$fg[magenta]%}%b%{$reset_color%}%m]"

zstyle ':vcs_info:git*+set-message:*' hooks git-st git-stash

zstyle ':vcs_info:hg*:netbeans' use-simple true

zstyle ':vcs_info:hg*:*' get-bookmarks true

zstyle ':vcs_info:hg*:*' get-mq true
zstyle ':vcs_info:hg*:*' get-unapplied true
zstyle ':vcs_info:hg*:*' patch-format " mq(%g):%{$fg[green]%}%n%{$reset_color%}/%{$fg_bold[blue]%}%c%{$reset_color%} %{$fg[green]%}%p%{$reset_color%}"
zstyle ':vcs_info:hg*:*' nopatch-format ""

zstyle ':vcs_info:hg*:*' unstagedstr " ?"
zstyle ':vcs_info:hg*:*' hgrevformat "%{$fg[yellow]%}%r%{$reset_color%}" # only show local rev.
zstyle ':vcs_info:hg*:*' branchformat "%{$fg[magenta]%}%b%{$reset_color%}" # only show branch

# Show remote ref name and number of commits ahead-of or behind
function +vi-git-st() {
    local ahead behind remote
    local -a gitstatus

    # Are we on a remote-tracking branch?
    remote=${$(git rev-parse --verify ${hook_com[branch]}@{upstream} \
        --symbolic-full-name 2>/dev/null)/refs\/remotes\/}

    if [[ -n ${remote} ]] ; then
        # for git prior to 1.7
        # ahead=$(git rev-list origin/${hook_com[branch]}..HEAD | wc -l)
        ahead=$(git rev-list ${hook_com[branch]}@{upstream}..HEAD 2>/dev/null | wc -l | tr -s ' ')
        (( $ahead )) && gitstatus+=( " ${c3}+${ahead}${c2}" )

        # for git prior to 1.7
        # behind=$(git rev-list HEAD..origin/${hook_com[branch]} | wc -l)
        behind=$(git rev-list HEAD..${hook_com[branch]}@{upstream} 2>/dev/null | wc -l | tr -s ' ')
        (( $behind )) && gitstatus+=( " ${c4}-${behind}${c2}" )

        hook_com[branch]="${hook_com[branch]} [${remote}${(j:/:)gitstatus}]"
    fi
}

# Show count of stashed changes
function +vi-git-stash() {
    local -a stashes

    if [[ -s ${hook_com[base]}/.git/refs/stash ]] ; then
        stashes=$(git stash list 2>/dev/null | wc -l)
        hook_com[misc]+=" (${stashes} stashed)"
    fi
}

precmd () { vcs_info }
PROMPT='
%{$(get_prompt_user_color)%}%n%{$reset_color%} at %{$(get_prompt_host_color)%}%m%{$reset_color%} in %{$fg_bold[green]%}%~%{$reset_color%} ${vcs_info_msg_0_}
$(virtualenv_info)$(prompt_char) '

Schauen Sie sich die Informationen zur Versionskontrolle an

Suchen Sie nach dem Abschnitt "Deaktivierungsmuster" (ungefähr 20% weiter unten auf der Seite).
Angenommen, Ihre Remote-Mounts sind fest oder relativ fest, dh /mnt/remote/*Sie können sie alle auflisten, und Sie sollten in der Lage sein, einen regulären Ausdruck für sie zu finden.

Das Beispiel unter dem Link ist Deaktivieren vcs_infounter ~/.zsh/:

zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh(|/*)"

Ich nehme an, Sie könnten den zshrc oder einen gleichwertigen (sorry - bash - Benutzer) ermitteln, der beim Start remote ist (oder in regelmäßigen Abständen oder ...) und das Update zstyleentsprechend durchführen.