Zsh-Terminal fortsetzen (OS X Lion)

OS X Lion verfügt über die Funktion "Fortsetzen". Wenn Sie eine App erneut öffnen, werden alle Fenster und deren Inhalte wiederhergestellt. Das funktioniert auch bei Terminal. Wenn Sie jedoch Zsh anstelle von Bash verwenden, wird das geöffnete Verzeichnis nicht wiederhergestellt. Wie kann ich das beheben?

UPDATE : Dies ist aus den in den Kommentaren genannten Gründen nicht ganz korrekt. Verwenden Sie die Antwort unten . Vielen Dank an @ChrisPage für die Extrameile :)

Die Antwort kann durch Reverse Engineering gefunden werden /etc/bashrc. Ich habe viele Ansätze aus dem Internet ausprobiert, aber Apples Weg scheint am besten zu funktionieren (siehe Abbildung).

Fügen .zshrcSie Folgendes hinzu

# Set Apple Terminal.app resume directory
if [[ $TERM_PROGRAM == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]] {
  function chpwd {
    local SEARCH=' '
    local REPLACE='%20'
    local PWD_URL="file://$HOSTNAME${PWD//$SEARCH/$REPLACE}"
    printf '\e]7;%s\a' "$PWD_URL"
  }

  chpwd
}

Viel Spaß bei der Wiederaufnahme.

Zur Verdeutlichung bezieht sich diese Antwort auf die mysteriöse Meldung in den Terminal.app-Einstellungen von OS X Lion:

** Programme benachrichtigen das Terminal über Escape-Sequenzen über das aktuelle Arbeitsverzeichnis. Möglicherweise müssen Sie Ihre Shell oder andere Programme konfigurieren, um dieses Verhalten zu aktivieren. *

Diese Antwort funktioniert, wenn Sie zsh als Shell verwenden. Terminal Resume für Bash wurde bereits von Apple implementiert.

Hier ist meine Anpassung von / etc / bashrc für zsh. Ich habe die Prozentcodierung aller URL-Zeichen eingefügt, die dies erfordern. Dies ist wichtig, wenn Sie möchten, dass dies mit allen gültigen Datei- und Verzeichnisnamen funktioniert.

Dadurch wird ein precmdHook registriert , mit dem mehr als eine Funktion in anderen Skripten und Konfigurationsdateien registriert werden kann.

AKTUALISIERT März 2019: Auf LC_ALLleer setzen, damit es nicht außer Kraft gesetzt wird LC_CTYPE. Verwenden Sie precmddiese Option, um das Arbeitsverzeichnis bei jeder Eingabeaufforderung chpwdzu aktualisieren, anstatt es bei jeder Änderung zu aktualisieren. Befehls-Pipelines können es vorübergehend ändern, und das Terminal sollte diese nicht anzeigen. Es kann auch hilfreich sein, bei jeder Eingabeaufforderung den Terminalstatus zu aktualisieren, falls er während des vorherigen Befehls geändert wurde. Verwenden Sie printf -vdiese Option, um explizit in die Variable zu schreiben, anstatt die Subshell-Syntax zu verwenden.

# Tell the terminal about the working directory whenever it changes.

if [[ "$TERM_PROGRAM" == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]]; then

    update_terminal_cwd() {
        # Identify the directory using a "file:" scheme URL, including
        # the host name to disambiguate local vs. remote paths.

        # Percent-encode the pathname.
        local url_path=''
        {
            # Use LC_CTYPE=C to process text byte-by-byte. Ensure that
            # LC_ALL isn't set, so it doesn't interfere.
            local i ch hexch LC_CTYPE=C LC_ALL=
            for ((i = 1; i <= ${#PWD}; ++i)); do
                ch="$PWD[i]"
                if [[ "$ch" =~ [/._~A-Za-z0-9-] ]]; then
                    url_path+="$ch"
                else
                    printf -v hexch "%02X" "'$ch"
                    url_path+="%$hexch"
                fi
            done
        }

        printf '\e]7;%s\a' "file://$HOST$url_path"
    }

    # Register the function so it is called at each prompt.
    autoload add-zsh-hook
    add-zsh-hook precmd update_terminal_cwd
fi