So behalten Erinnerungen an Outlook-Kalender in Windows 7 den Überblick

Ich fange gerade an, Windows 7 zu verwenden, und ich möchte wissen, wie meine Outlook-Erinnerungen angezeigt und hervorgehoben werden. Sie öffnen sich unauffällig wie ein weiteres Fenster im Outlook-Stapel in der Taskleiste. Infolgedessen überseh ich sie immer wieder, weil sie hinter allem anderen auftauchen.

Wie mache ich sie weniger leicht zu übersehen?

(Natürlich möchte man normalerweise keine abscheulichen Apps, die sich in den Vordergrund rücken. Es gibt jedoch einige Stellen, an denen ein solches Verhalten wünschenswert ist, und Outlook-Kalendererinnerungen sind eine davon.)

Ich hatte das gleiche Problem mit Outlook 2010. Verwenden Sie die unten genannten Schritte, es funktioniert wie ein Zauber. Vergessen Sie nicht, alle Makros zu aktivieren: Vertrauensstellungscenter> Makroeinstellungen.

• Erstellen Sie ein digitales Zertifikat für später: Klicken Sie auf Start und geben Sie "Zertifikat" ein. Wählen Sie "Digitales Zertifikat für VBA-Projekte".
• Geben Sie einen Namen für Ihr Zertifikat ein. OK klicken. Öffnen Sie Outlook und drücken Sie Alt+ F11, um den VBA-Editor zu starten.
• Erweitern Sie im linken Baum "Microsoft Office Outlook-Objekte" und doppelklicken Sie auf "ThisOutlookSession".

• Füge diesen Code ein:

  Private Declare PtrSafe Function FindWindowA Lib "user32" _
  (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
  
  Private Declare PtrSafe Function SetWindowPos Lib "user32" ( _
  ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
  ByVal X As Long, ByVal Y As Long, ByVal cx As Long, _
  ByVal cy As Long, ByVal wFlags As Long) As Long
  
  Private Const SWP_NOSIZE = &H1
  Private Const SWP_NOMOVE = &H2
  Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
  Private Const HWND_TOPMOST = -1
  
  Private Sub Application_Reminder(ByVal Item As Object)
  Dim ReminderWindowHWnd As Variant
  On Error Resume Next
  ReminderWindowHWnd = FindWindowA(vbNullString, "1 Reminder")
  SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
  
  End Sub
  

• Signieren Sie das Makro, damit es ausgeführt wird: Extras> Digitale Signatur ... und wählen Sie das zuvor erstellte Zertifikat aus

• Schließen Sie das VBA-Fenster
• Aktivieren Sie alle Makros unter Datei> Optionen> Vertrauensstellungscenter> Vertrauensstellungscenter-Einstellungen> Makroeinstellungen

AutoHotKey kann ebenfalls zur Lösung dieses Problems verwendet werden. Mit diesem Skript wird das Erinnerungsfenster oben angezeigt, ohne den Fokus zu stehlen (getestet mit Win10 / Outlook 2013).

TrayTip Script, Looking for Reminder window to put on top, , 16
SetTitleMatchMode  2 ; windows contains
loop {
  WinWait, Reminder(s), 
  WinSet, AlwaysOnTop, on, Reminder(s)
  WinRestore, Reminder(s)
  TrayTip Outlook Reminder, You have an outlook reminder open, , 16
  WinWaitClose, Reminder(s), ,30
}

AHK Script - Kompilierte EXE

Die beste Antwort, die ich gefunden habe, ist hier: So erhalten Sie Outlook-Terminerinnerungen, die mithilfe eines einfachen VBA erneut vor anderen Fenstern angezeigt werden.

Dazu müssen "ThisOutlookSession" einige Zeilen einfachen VBA-Codes hinzugefügt werden. Jetzt wird jedes Mal ein Fenster geöffnet. Viel besser.

• Erstellen Sie ein digitales Zertifikat für später
• Klicken Sie auf Start und geben Sie "Zertifikat" ein. Wählen Sie "Digitales Zertifikat für VBA-Projekte".
• Geben Sie einen Namen für Ihr Zertifikat ein
• Getan
• Öffnen Sie Outlook und drücken Sie Alt + F11, um den VBA-Editor zu starten.
• Erweitern Sie im linken Baum "Microsoft Office Outlook-Objekte" und doppelklicken Sie auf "ThisOutlookSession".

• Fügen Sie diesen Code ein und ändern Sie den Text in Anführungszeichen nach Ihren Wünschen. Lassen Sie die Anführungszeichen in.

  Private Sub Application_Reminder(ByVal Item As Object)
  
  
      If TypeOf Item Is AppointmentItem Then
      MsgBox "Message text", vbSystemModal, "Message title"
      End If
  
  
  End Sub
  

• Signieren Sie das Makro, damit es ausgeführt wird, indem Sie zu Extras> Digitale Signatur ... wechseln und das zuvor erstellte Zertifikat auswählen

• Schließen Sie das VBA-Fenster

Ab Version 1803 (Februar 2018) ist jetzt die Option "Erinnerungen über anderen Fenstern anzeigen" verfügbar. Es scheint nicht standardmäßig aktiviert zu sein.

Es gibt keine Möglichkeit. Unser Unternehmen hat versucht, es direkt an Microsoft weiterzuleiten. Eine Sache, die die Leute hier tun, ist, ihr einen widerlicheren Klang zuzuweisen, damit sie es bemerken. Microsoft hat uns jedoch mitgeteilt, dass dies beabsichtigt ist.

Wie Gullus Antwort oben, jedoch mit Änderung, um andere Fenstertitel aufzunehmen:

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

'// TO ACCOUNT FOR WINDOW TITLE CHANGING WITH NOTIFICATION COUNT:
Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    'On Error Resume Next
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder(s)"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

Das nervte mich auch. Nach einiger intensiver Suche fand ich eine teilweise Antwort: http://www.pcreview.co.uk/forums/hidden-outlook-reminders-t3972914.html

Wenn Sie die Einstellung "Taskleisten-Schaltflächen" unter "Eigenschaften von Taskleiste und Startmenü" in "Niemals kombinieren" ändern, wird die Gruppierung getrennt und die Erinnerung wird vor allen anderen geöffneten Elementen angezeigt.

Ich versuchte es zu testen und stellte fest, dass es inkonsistent war; Einmal blieb es hinter dem verborgen, woran ich arbeitete, und ein anderes Mal tauchte es vorne auf. In beiden Fällen befand sich ein Symbol in der Taskleiste, das sich von Outlook selbst unterschied, sodass zumindest die Möglichkeit bestand, dass ich es bemerkte.

Ich habe Filebox eXtender verwendet. Wenn die erste Erinnerung eingeht, öffne ich sie und klicke oben rechts in der Titelleiste auf das neue Pin-Symbol. Wenn dann die nächste Erinnerung eingeht, steht sie im Vordergrund ...

Ich habe ein Addin namens ShowReminders ( http://www.sagelamp.com/pages/showreminders.aspx ) gefunden, das das Erinnerungsfenster nach oben bringt. Es funktioniert sogar, wenn Sie das Erinnerungsfenster minimieren.

Endlich finde ich eine einfache Lösung mit Outlook VBA und einer einfachen EXE.

So verpassen Sie nie wieder einen Outlook-Besprechungstermin.

Warum eine eigenständige exe-Anwendung nur für diesen Zweck? Nun, ich hatte die große rote Box in der VBA eingebettet, aber diese Lösung war voller Probleme (ich glaube, es liegt daran, dass ich hwnd und andere ungewöhnliche Systemeigenschaften verwenden muss, um die große rote Box oben zu halten). Also, um die Dinge einfacher zu machen, warum nicht eine grundlegende EXE, die eine Sache macht. Sie können kostenlose Tools von Microsoft verwenden (Visual Studio Community 2015 ist kostenlos).

Dies ist der EXE-Code. einfache Windows-Formularanwendung mit einem Formular. Kompilieren Sie diesen Code.

Imports System.Timers
Public Class Form1
    Dim tTimer As New Timer
    Public Sub New()
        InitializeComponent()
        Me.StartPosition = Windows.Forms.FormStartPosition.CenterScreen
        Me.TopMost = True
        Me.TopLevel = True
    End Sub
    Private Sub Form1_DoubleClick(sender As Object, e As EventArgs) Handles Me.DoubleClick
        Application.Exit()
    End Sub 
    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
        flashingQuick()
    End Sub
    Sub flashingQuick()
        tTimer.Start()
        AddHandler tTimer.Elapsed, New ElapsedEventHandler(AddressOf TimerTick)
    End Sub
    Sub TimerTick(ByVal source As [Object], ByVal e As ElapsedEventArgs)
        Dim theTimer As System.Timers.Timer = DirectCast(source, System.Timers.Timer)
        theTimer.Interval = 500
        theTimer.Enabled = True
        If Me.BackColor = System.Drawing.SystemColors.Control Then
            Me.BackColor = Color.Red
        Else
            Me.BackColor = System.Drawing.SystemColors.Control
        End If
    End Sub
End Class

Und das ist alles, was ich im Outlook VBA brauche. Fügen Sie dies in ThisOutlookSession ein

Private Sub Application_Reminder(ByVal Item As Object)
    On Error Resume Next
    If Item.MessageClass <> "IPM.Appointment" Then
      Exit Sub
    End If
    Dim sAPPData As String
    Dim sFileName As String
    sAPPData = Environ("AppData")
    sFileName = "\Microsoft\Windows\Start Menu\Programs\BigRedBox\BigRedBox.exe"
    If Dir(sAPPData & sFileName) <> "" Then
        Call Shell(sAPPData & sFileName)
    End If
End Sub

Dies ist eine erweiterte Version der Antwort von tbone, die auf deutschen Versionen funktioniert.

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Private Declare PtrSafe Function BringWindowToTop Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hwnd As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop (ReminderWindowHWnd)
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung(en)")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop ReminderWindowHWnd
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

Ich habe deutsche Fenstertitel und auch einige neue Funktionen ( BringWindowToTop, SetForegroundWindowund SetFocus) hinzugefügt .

Funktioniert auf meinem deutschen Windows 10 zusammen mit Outlook 2016.

Ich habe es nicht geschafft, ein neues Zertifikat zu generieren (Drücken von Start und Eingabe von "Zertifikat" ergab nichts), sondern beim Signieren einfach ein anderes Zertifikat in der Liste ausgewählt.