Erstellen Sie eine symbolische Verknüpfung im Mac OS X Finder

Gibt es eine Möglichkeit, die gleiche Funktionalität wie beim Unix-Befehl ln -sim Mac OS X Finder (OS 10.5) zu erhalten? Ich möchte in der Lage sein, symbolische Links zu erstellen, während ich im Finder-Fenster arbeite, ohne das Terminal zu öffnen.

Beachten Sie, dass der Make AliasBefehl in Finder nicht das ist, was ich möchte, da diese Aliase nicht im Terminal ln -snavigiert werden können (aber mit erstellte Links können sowohl vom Terminal als auch vom Finder navigiert werden).

Wie wäre es damit, symbolische Links im Finder über AppleScript zu erstellen ?

Hier ist das relevanteste Skript in diesem Link:

on run
    open {choose file with prompt "Choose a file to create a symbolic link:" without invisibles}
end run

on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Fügen Sie es einfach in den AppleScript-Editor ein und speichern Sie es als Anwendung . Dann können Sie es über die Symbolleiste Ihres Finders ziehen oder im Dock verknüpfen .

SymbolicLinker wird genau das tun, wonach Sie suchen, und es ist kostenlos.

Ein Applescript unter dem Link von User NUC hat meine Frage beantwortet. Hier ist das Applescript für den Fall, dass der Link verschwindet.

Ich bevorzuge das Skript des Kommentators jonn8n, der auch als Macworld-Artikel reproduziert wurde .

on run
    open {choose file with prompt ¬
        "Choose a file to create a symbolic link:" without invisibles}
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path ¬
                & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Ich habe dies mit dem Skript-Editor als Anwendung gespeichert und die Anwendung in die Finder-Seitenleiste gezogen, damit ich jetzt symbolische Links erstellen kann, indem ich Dateien oder Ordner auf das Anwendungssymbol ziehe.

Path Finder fügt dies zu Ihrem Finder hinzu und fügt viel mehr Funktionen hinzu.

Verwenden Sie Automator.app, um einen Service zu erstellen , der ein Bash-Skript ausführt. Dies ist einfacher als AppleScript und zuverlässiger als die Installation von Software von Drittanbietern.

for f in "$@"
do
    ln -s "$f" "$f.symlink"
done

Anschließend können Sie über das Menü Dienste auf den Befehl Symbolischen Link erstellen zugreifen :

Das Ergebnis:

Eine mögliche Verbesserung dieses Skripts besteht darin, den Run-Handler so zu ändern, dass die aktuell im Finder ausgewählten Dateien verwendet werden.

on run
    tell application "Finder" to set sel to selection
    open sel
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files as alias)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            try
                do shell script "ln -s " & quoted form of posix_path ¬
                    & " " & quoted form of (posix_path & ".sym")
            on error
                try
                    do shell script "ln -s " & quoted form of posix_path ¬
                        & " " & quoted form of (posix_path & ".sym") with administrator privileges

                end try
            end try
        end try
    end repeat
end open

Sie können zum Hinzufügen auch [application] /Contents/Info.plist bearbeiten

<key>LSUIElement</key>
<true/>

Kurz vor dem letzten </ dict>. Dies würde bedeuten, dass die App im Hintergrund ausgeführt wird und nicht in den Vordergrund tritt, wenn Sie darauf klicken.

In Snow Leopard, in dem SymbolicLinker nicht funktioniert, können Sie mit Automator einen Dienst erstellen, um entweder den Terminalbefehl oder AppleScript zum Erstellen einer symbolischen Verknüpfung auszuführen.

Eine weitere AS:

tell application "Finder"
    repeat with f in (get selection)
        set p to POSIX path of (f as text)
        set p2 to POSIX path of (desktop as text) & name of f
        do shell script "ln -s " & quoted form of p & " " & quoted form of p2
    end repeat
end tell

Versuchen Sie es hier: http://www.techiecorner.com/528/how-to-create-shortcut-in-mac-os-x/

Dies ist bereits in OSX integriert, wenn Sie die Steuertaste drücken, wenn Sie auf etwas klicken.