Gibt es unter Windows eine Möglichkeit, ausgewählten Text als Ordner zu öffnen?

Angenommen, ich habe den Text irgendwo (Editor, Word ...):

Zum Verzeichnis gehen C: \ Programme , dann...

Ich möchte Fettdruck auswählen, mit der rechten Maustaste darauf klicken und einen Menüeintrag mit der Aufschrift " Wechseln Sie zu C: \ Programme ".

Gibt es eine Erweiterung dafür (oder vielleicht einen Windows-Weg)?

windows context-menu

— Leo Heinsaar
quelle

Ich weiß nicht, wie Sie genau das erreichen können, was Sie wollen, aber Sie können natürlich den 'fetten' Text kopieren (STRG + C), ein Datei-Explorer-Fenster öffnen, diesen Text in die Adressleiste einfügen und Drücken Sie Enter...

— gogoud

Vielen Dank :-). Genau dafür versuche ich natürlich eine Kurzversion zu finden.

— Leo Heinsaar

Sie können den Text auch kopieren und dann Windows-Taste + R, dann Strg + V und Eingabe ausführen. Etwas schneller. Ich glaube nicht, dass Sie eine Möglichkeit finden werden, dies zum Kontextmenü hinzuzufügen, da es sich um verschiedene Kontextmenüs in verschiedenen Programmen handelt. Sie müssen Notepad selbst oder Word selbst ändern.

— tomysshadow

Wenn nicht jemand eine App erstellt hat, um genau das zu tun, was Sie beschreiben (mir ist keine bekannt), würde die Lösung gerne Codierung oder Skripterstellung beinhalten.

Wie ich die Frage verstehe, gibt es zwei Teile:

1) So öffnen Sie einen Pfad aus einer ausgewählten Textstelle

2) So fügen Sie einem Kontextmenü die Nummer 1 hinzu.

Für # 1 (Skript für die Aktion):

Dies könnte programmgesteuert aus einer Reihe von Sprachen erfolgen. Persönlich würde ich ein Autohotkey-Skript verwenden, aber es könnte auch auf andere Weise erfolgen.

Das folgende Skript funktionierte für mich unter Autohotkey L (1.1), das Sie hier finden https://www.autohotkey.com/download/

Derzeit habe ich es an die F3-Taste gebunden. Aber es könnte hier auf jeden Schlüssel basierend auf der Syntax angepasst werden: https://www.autohotkey.com/docs/Hotkeys.htm

Installieren Sie AHK_L und speichern Sie es als openSelPath.ahk:

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

; test folder D:\Downloads
; test file D:\Dev\YOmDuDV.jpg
; no-existent path D:\Dev\doesnotexist.foo

~F3::
    openSelectedPath()
    return



openSelectedPath() {
    send, ^c
    sleep, 200
    strPath := Clipboard 
    intLen := StrLen(strPath)
    if ( intLen > 0) {
        ;check if path exists
        strResult := FileExist(strPath)
        if ( "" == strResult) {
            msgbox, 48, Error:, Path "%strPath%" not found.
            return
        }
        isDir := (0 != InStr(strResult, "D"))
        if ( 1 == isDir ) {
            Run, explorer.exe "%strPath%"
            return
        }

        intLastSlash := InStr(strPath, "\", false, 0)
        if ( 0 == intLastSlash ) {
            msgbox, 48, Error:, Path "%strPath%" not found.
            return
        }
        strParentDir := SubStr(strPath, 1, intLastSlash- 1)

        ;check if path exists
        strResult := FileExist(strParentDir)
        if ( "" == strResult) {
            msgbox, 48, Error:, Path "%strParentDir%" not found.
            return
        }
        isDir := (0 != InStr(strResult, "D"))
        if ( 1 == isDir ) {
            Run, explorer.exe "%strParentDir%"
            return
        }
    }
    return
}

Für # 2 (Hinzufügen zu einem Kontextmenü):

Ich sehe, dass eines der Tags "Kontextmenü" ist ... Ich gebe zu, ich bin mir nicht sicher, ob Sie dies über ein Kontextmenü tun würden. Ausgehend von der Beschreibung klingt es so, als ob Sie dies direkt aus dem Editor / Wordpad / etc. heraus tun möchten. Die Unterstützung von Kontextmenüs ist programmspezifisch.

Ich glaube nicht, dass Sie für Microsoft-Apps (Notepad / Wordpad / Word / Excel / usw.) über ein Kontextmenü darauf zugreifen können, da es sich um Closed Source-Apps handelt. Sie könnten vielleicht einige Plugins für die Office-Apps machen, aber ich glaube, das erfordert Programmierung.

Ich kenne einige Open-Source-Apps wie Notepad ++, die das Definieren von Verknüpfungen über XML usw. unterstützen.

Wenn Sie Windows Explorer / File Explorer verwenden, ist es möglich, Kontextmenü-Verben hinzuzufügen, aber für mich ist dies in diesem Szenario nicht sinnvoll, da Sie möglicherweise von einem anderen Programm aus gestartet werden.

— spiritpyre
quelle

Auto-Hotkey ist in Ordnung (und noch besser). Vielen Dank.

— Leo Heinsaar