Ist MSIZAP immer noch nützlich oder veraltet?

Ich aktualisiere Flash mithilfe von MSI-Dateien, die durch Gruppenrichtlinien installiert wurden. Bei jedem Update kann jedoch etwa ein Drittel der Arbeitsstationen nicht aktualisiert werden (Windows Vista und Windows 7 32/64-Bit-Editionen). In den Ereignisprotokollen wird folgende Meldung angezeigt:

"Adobe Flash Player 11 ActiveX - Fehler 1714. Die ältere Version von Adobe Flash Player 11 ActiveX kann nicht entfernt werden. Wenden Sie sich an Ihren technischen Support. Systemfehler 1612."

Die einzige Möglichkeit, das Problem zu beheben, ist die Verwendung des Microsoft Fit It-Tools . Es ist jedoch ein sehr zeitaufwändiger Vorgang, dessen manuelle Ausführung für jede Arbeitsstation etwa 15 Minuten in Anspruch nimmt. Daher wird jedes Mal, wenn ein Flash-Update veröffentlicht wird, ein ganzer Tag abgebrochen.

Ich bin auf dieses Skript gestoßen, das MSIZAP enthält, um fehlgeschlagene Deinstallationen von Flash zu entfernen. Meine Frage lautet also : Ist das MSIZAP-Dienstprogramm die beste Methode zum programmgesteuerten Entfernen von Flash, oder ist es an dieser Stelle veraltet? Der Grund, den ich frage, ist, dass die meisten schriftlichen Materialien, die ich zu diesem Thema gefunden habe, aus 2009 oder 2010 stammen.

@echo off
SET MSIZAP=\\my.domain.com\netlogon\bin\msizap.exe
SET DFSPATH=\\my.domain.com\dfsroot\Packages\Adobe

SET UNINSTALL=%DFSPATH%\uninstall_flash_player_x86.exe
SET INSTALL=%DFSPATH%\install_flash_player_11.4.402.278_active_x.exe 

rem Detect 64-bit Windows
IF NOT "%ProgramFiles(x86)%"=="" SET WOW6432NODE=WOW6432NODE\

SET VER_FLAG_KEY=HKEY_LOCAL_MACHINE\SOFTWARE\%WOW6432NODE%Macromedia\FlashPlayer
SET VER_FLAG_VALUE=11,4,402,278

REG QUERY "%VER_FLAG_KEY%" /v CurrentVersion | find /i "%VER_FLAG_VALUE%" > NUL 2>NUL
if errorlevel 1 goto do_install
goto :EOF

:do_install
rem Uninstall all old versions of Flash.
start /wait /min "" "%UNINSTALL%" -uninstall activex

rem MSIZAP all old versions
start /wait /min "" "%MSIZAP%" TW! {2BD2FA21-B51D-4F01-94A7-AC16737B2163}
start /wait /min "" "%MSIZAP%" TW! {B7B3E9B3-FB14-4927-894B-E9124509AF5A}
start /wait /min "" "%MSIZAP%" TW! {FA1D6742-0515-4A94-AD5D-F0484026E4A2}

rem Run new installer
start /wait /min "" "%INSTALL%" -install activex

rem Block future automatic updates
SET DEST="%windir%\system32\Macromed\Flash\mms.cfg"

rem Detect 64-bit Windows
IF NOT "%ProgramFiles(x86)%"=="" SET DEST="%windir%\SysWOW64\Macromed\Flash\mms.cfg"

rem I'm using "sort" here because the redirect is being interpreted as "1>" and
rem doing "1 >" causes a space to be stored in the file, which "breaks" the file.
echo AutoUpdateDisable=1|sort>%DEST%

Quelle: Ich habe Flash Player über eine Softwareinstallationsrichtlinie bereitgestellt. Wie aktualisiere ich?

— Flow erzwingen
quelle

Wenn Sie eine Liste GUIDs haben, warum nicht einfach gehen und deinstallieren? So etwas wie: msiexec /x {the-product-guid} /qn- Das sollte das Produkt deinstallieren. Ich glaube nicht, dass MsiZap unterstützt wird .

— Jscott

Beachten Sie, dass diese Programme nicht vollständig über Gruppenrichtlinien deinstalliert werden konnten und erst dann erneut installiert oder aktualisiert werden können, wenn sie mit dem Fix it-Tool bereinigt wurden. Nach meinem Kenntnisstand funktioniert msiexec nur, wenn die Dinge tatsächlich richtig funktionieren.

— Force Flow

Packen Sie das Flash-Installationsprogramm mit einer MSI neu oder verwenden Sie eine von ihnen bereitgestellte? MSI hat sich seit einigen Jahren nicht wesentlich verändert, sodass sich die zugrunde liegende Mechanik nicht wirklich geändert hat. Allerdings ist das Zappen in erster Linie ein Brute-Force-Mechanismus, der möglicherweise zu zukünftigen Ausfällen geführt hat. Das Update Es ist grundsätzlich automatisierbar, wenn Sie mit PowerShell vertraut sind, obwohl ich es offiziell nicht empfehlen würde. (Ich arbeite für Microsoft, daher kann ich es nicht empfehlen. Ich sage nur, dass es sich um PowerShell handelt und theoretisch könnte es getan werden.)

— Matthew Wetmore,

Versuchen Sie, die neue Version über die alte zu installieren, und verlassen Sie sich beim Entfernen auf das Installationsprogramm? Oder weisen Sie das Windows-Installationsprogramm an, zuerst das alte zu deinstallieren, bevor Sie das neue installieren?

Wenn Sie das erstere tun, empfehle ich Ihnen, zu dem späteren zu wechseln, da ich damit fast nur gute Erfahrungen gemacht habe. Die einzige Ausnahme bestand darin, dass Adobe einmal eine falsche Versionsnummer in den Deinstallationsbefehl innerhalb der MSI eingegeben hatte (diese war jedoch zu 100% reproduzierbar und somit unmittelbar vor der Bereitstellung auf einem Testcomputer sichtbar).

Siehe /server//a/441131/144344 und /server//a/564881/144344

— Klaus Hartnegg
quelle