Wie lösche ich alle Tabellen in einer SQL Server-Datenbank?

Ich versuche, ein Skript zu schreiben, das eine SQL Server-Datenbank vollständig leert. Das habe ich bisher:

USE [dbname]
GO
EXEC sp_msforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT all'
EXEC sp_msforeachtable 'DELETE ?'

Wenn ich es im Management Studio ausführe, erhalte ich:

Befehl (e) erfolgreich abgeschlossen.

Aber wenn ich die Tabellenliste aktualisiere, sind sie alle noch da. Was mache ich falsch?

Es funktioniert auch bei mir nicht, wenn mehrere Fremdschlüsseltabellen vorhanden sind.
Ich habe den Code gefunden, der funktioniert und alles tut, was Sie versuchen (alle Tabellen aus Ihrer Datenbank löschen):

DECLARE @Sql NVARCHAR(500) DECLARE @Cursor CURSOR

SET @Cursor = CURSOR FAST_FORWARD FOR
SELECT DISTINCT sql = 'ALTER TABLE [' + tc2.TABLE_SCHEMA + '].[' +  tc2.TABLE_NAME + '] DROP [' + rc1.CONSTRAINT_NAME + '];'
FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc1
LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS tc2 ON tc2.CONSTRAINT_NAME =rc1.CONSTRAINT_NAME

OPEN @Cursor FETCH NEXT FROM @Cursor INTO @Sql

WHILE (@@FETCH_STATUS = 0)
BEGIN
Exec sp_executesql @Sql
FETCH NEXT FROM @Cursor INTO @Sql
END

CLOSE @Cursor DEALLOCATE @Cursor
GO

EXEC sp_MSforeachtable 'DROP TABLE ?'
GO

Den Beitrag finden Sie hier . Es ist der Beitrag von Groker.

Sie können alle Tabellen auch nur mit MSSMS-UI-Tools aus der Datenbank löschen (ohne SQL-Skript). Manchmal kann dieser Weg bequemer sein (besonders wenn er gelegentlich durchgeführt wird)

Ich mache das Schritt für Schritt wie folgt:

1. Wählen Sie im Datenbankbaum 'Tabellen' (Objekt-Explorer).
2. Drücken Sie F7, um die Detailansicht des Objekt-Explorers zu öffnen
3. Wählen Sie in dieser Ansicht Tabellen aus, die gelöscht werden müssen (in diesem Fall alle)
4. Drücken Sie die Entf-Taste, bis alle Tabellen gelöscht wurden (Sie wiederholen sie so oft wie Fehler aufgrund wichtiger Einschränkungen / Abhängigkeiten).

In SSMS:

• Klicken Sie mit der rechten Maustaste auf die Datenbank
• Gehen Sie zu "Aufgaben"
• Klicken Sie auf "Skripte generieren".
• Wählen Sie im Abschnitt "Objekte auswählen" die Option "Gesamte Datenbank und alle Datenbankobjekte skripten" aus.
• Klicken Sie im Abschnitt "Skriptoptionen festlegen" auf die Schaltfläche "Erweitert"
• Schalten Sie bei "Script DROP and CREATE" "Script CREATE" auf "Script DROP" und drücken Sie OK
• Speichern Sie dann entweder in einer Datei, einer Zwischenablage oder einem neuen Abfragefenster.
• Skript ausführen.

Dadurch wird nun alles gelöscht, einschließlich der Datenbank. Stellen Sie sicher, dass Sie den Code für die Elemente entfernen, die nicht gelöscht werden sollen. Alternativ können Sie im Abschnitt "Objekte auswählen" anstelle der Auswahl zum Skripten der gesamten Datenbank nur die Elemente auswählen, die Sie entfernen möchten.

deletewird zum Löschen von Zeilen aus einer Tabelle verwendet. Sie sollten drop tablestattdessen verwenden.

EXEC sp_msforeachtable 'drop table [?]'

Die akzeptierte Antwort unterstützt Azure nicht. Es wird eine undokumentierte gespeicherte Prozedur "sp_MSforeachtable" verwendet. Wenn Sie beim Ausführen den Fehler "azure konnte die gespeicherte Prozedur 'sp_msforeachtable' nicht finden" erhalten oder einfach vermeiden möchten, sich auf undokumentierte Funktionen zu verlassen (die jederzeit entfernt oder deren Funktionalität geändert werden kann), versuchen Sie Folgendes.

Diese Version ignoriert die Entity Framework-Migrationsverlaufstabelle "__MigrationHistory" und die "database_firewall_rules", eine Azure-Tabelle, zu deren Löschung Sie nicht berechtigt sind.

Leicht auf Azure getestet. Stellen Sie sicher, dass dies keine unerwünschten Auswirkungen auf Ihre Umgebung hat.

DECLARE @sql NVARCHAR(2000)

WHILE(EXISTS(SELECT 1 from INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE CONSTRAINT_TYPE='FOREIGN KEY'))
BEGIN
    SELECT TOP 1 @sql=('ALTER TABLE ' + TABLE_SCHEMA + '.[' + TABLE_NAME + '] DROP CONSTRAINT [' + CONSTRAINT_NAME + ']')
    FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS
    WHERE CONSTRAINT_TYPE = 'FOREIGN KEY'
    EXEC(@sql)
    PRINT @sql
END

WHILE(EXISTS(SELECT * from INFORMATION_SCHEMA.TABLES WHERE TABLE_NAME != '__MigrationHistory' AND TABLE_NAME != 'database_firewall_rules'))
BEGIN
    SELECT TOP 1 @sql=('DROP TABLE ' + TABLE_SCHEMA + '.[' + TABLE_NAME + ']')
    FROM INFORMATION_SCHEMA.TABLES
    WHERE TABLE_NAME != '__MigrationHistory' AND TABLE_NAME != 'database_firewall_rules'
    EXEC(@sql)
    PRINT @sql
END

Genommen von:

https://edspencer.me.uk/2013/02/25/drop-all-tables-in-a-sql-server-database-azure-friendly/

http://www.sqlservercentral.com/blogs/sqlservertips/2011/10/11/remove-all-foreign-keys/

/* Drop all Primary Key constraints */
DECLARE @name VARCHAR(128)
DECLARE @constraint VARCHAR(254)
DECLARE @SQL VARCHAR(254)

SELECT @name = (SELECT TOP 1 TABLE_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' ORDER BY TABLE_NAME)

WHILE @name IS NOT NULL
BEGIN
    SELECT @constraint = (SELECT TOP 1 CONSTRAINT_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' AND TABLE_NAME = @name ORDER BY CONSTRAINT_NAME)
    WHILE @constraint is not null
    BEGIN
        SELECT @SQL = 'ALTER TABLE [dbo].[' + RTRIM(@name) +'] DROP CONSTRAINT [' + RTRIM(@constraint)+']'
        EXEC (@SQL)
        PRINT 'Dropped PK Constraint: ' + @constraint + ' on ' + @name
        SELECT @constraint = (SELECT TOP 1 CONSTRAINT_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' AND CONSTRAINT_NAME <> @constraint AND TABLE_NAME = @name ORDER BY CONSTRAINT_NAME)
    END
SELECT @name = (SELECT TOP 1 TABLE_NAME FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS WHERE constraint_catalog=DB_NAME() AND CONSTRAINT_TYPE = 'PRIMARY KEY' ORDER BY TABLE_NAME)
END
GO

/* Drop all tables */
DECLARE @name VARCHAR(128)
DECLARE @SQL VARCHAR(254)

SELECT @name = (SELECT TOP 1 [name] FROM sysobjects WHERE [type] = 'U' AND category = 0 ORDER BY [name])

WHILE @name IS NOT NULL
BEGIN
    SELECT @SQL = 'DROP TABLE [dbo].[' + RTRIM(@name) +']'
    EXEC (@SQL)
    PRINT 'Dropped Table: ' + @name
    SELECT @name = (SELECT TOP 1 [name] FROM sysobjects WHERE [type] = 'U' AND category = 0 AND [name] > @name ORDER BY [name])
END
GO

Sie haben fast Recht, verwenden Sie stattdessen:

EXEC sp_msforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT all'
EXEC sp_msforeachtable 'DROP TABLE ?'

In der zweiten Zeile müssen Sie möglicherweise mehr als einmal ausführen, bis kein Fehler mehr angezeigt wird:

Could not drop object 'dbo.table' because it is referenced by a FOREIGN KEY constraint.

Botschaft:

Command(s) completed successfully.

bedeutet, dass alle Tabellen erfolgreich gelöscht wurden.

Kurz und bündig:

USE YOUR_DATABASE_NAME
-- Disable all referential integrity constraints
EXEC sp_MSforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT ALL'
GO

-- Drop all PKs and FKs
declare @sql nvarchar(max)
SELECT @sql = STUFF((SELECT '; ' + 'ALTER TABLE ' + Table_Name  +'  drop constraint ' + Constraint_Name  from Information_Schema.CONSTRAINT_TABLE_USAGE ORDER BY Constraint_Name FOR XML PATH('')),1,1,'')
EXECUTE (@sql)
GO

-- Drop all tables
EXEC sp_MSforeachtable 'DROP TABLE ?'
GO

Der schnellste Weg ist:

1. Neue Datenbankdiagramme
2. Alle Tabelle hinzufügen
3. Strg + A, um alle auszuwählen
4. Klicken Sie mit der rechten Maustaste auf "Aus Datenbank entfernen".
5. Strg + S zum Speichern
6. Genießen

Scheint, der Befehl sollte ohne die quadratische Decke sein

EXEC sp_msforeachtable 'drop table ?'

Für mich der einfachste Weg:

--First delete all constraints

DECLARE @sql NVARCHAR(MAX);
SET @sql = N'';

SELECT @sql = @sql + N'
ALTER TABLE ' + QUOTENAME(s.name) + N'.'
+ QUOTENAME(t.name) + N' DROP CONSTRAINT '
+ QUOTENAME(c.name) + ';'
FROM sys.objects AS c
INNER JOIN sys.tables AS t
ON c.parent_object_id = t.[object_id]
INNER JOIN sys.schemas AS s 
ON t.[schema_id] = s.[schema_id]
WHERE c.[type] IN ('D','C','F','PK','UQ')
ORDER BY c.[type];

EXEC sys.sp_executesql @sql;

-- Then drop all tables

exec sp_MSforeachtable 'DROP TABLE ?'

Genau richtig !!

Mit der folgenden Abfrage können Sie alle Tabellen aus der Datenbank entfernen

EXEC sp_MSforeachtable @ command1 = "DROP TABLE?"

Viel Spaß beim Codieren!

Wie wäre es, die gesamte Datenbank zu löschen und dann erneut zu erstellen? Das funktioniert bei mir.

DROP DATABASE mydb;
CREATE DATABASE mydb;

Ich weiß, dass dies jetzt ein alter Beitrag ist, aber ich habe alle Antworten hier in einer Vielzahl von Datenbanken ausprobiert und festgestellt, dass sie alle manchmal, aber nicht immer für verschiedene (ich kann nur annehmen) Macken von SQL Server funktionieren.

Irgendwann habe ich mir das ausgedacht. Ich habe dies überall getestet (im Allgemeinen), was ich kann, und es funktioniert (ohne versteckte Speicherprozeduren).

Hinweis hauptsächlich auf SQL Server 2014. (aber die meisten anderen Versionen, die ich ausprobiert habe, scheinen auch gut zu funktionieren).

Ich habe versucht, während Schleifen und Nullen usw. usw., Cursor und verschiedene andere Formen, aber sie scheinen immer auf einigen Datenbanken zu scheitern, aber nicht auf anderen ohne offensichtlichen Grund.

Eine Zählung zu erhalten und diese zum Iterieren zu verwenden, scheint immer bei allem zu funktionieren, was ich getestet habe.

USE [****YOUR_DATABASE****]
GO

SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

-- Drop all referential integrity constraints --
-- Drop all Primary Key constraints.          --

DECLARE @sql  NVARCHAR(296)
DECLARE @table_name VARCHAR(128)

DECLARE @constraint_name VARCHAR(128)
SET @constraint_name = ''

DECLARE @row_number INT

SELECT @row_number = Count(*) FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc1
LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS tc2 ON tc2.CONSTRAINT_NAME = rc1.CONSTRAINT_NAME

WHILE @row_number > 0
BEGIN
    BEGIN
        SELECT TOP 1 @table_name = tc2.TABLE_NAME, @constraint_name = rc1.CONSTRAINT_NAME FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc1
        LEFT JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS tc2 ON tc2.CONSTRAINT_NAME = rc1.CONSTRAINT_NAME
        AND rc1.CONSTRAINT_NAME > @constraint_name
        ORDER BY rc1.CONSTRAINT_NAME
        SELECT @sql = 'ALTER TABLE [dbo].[' + RTRIM(@table_name) +'] DROP CONSTRAINT [' + RTRIM(@constraint_name)+']'
        EXEC (@sql)
        PRINT 'Dropped Constraint: ' + @constraint_name + ' on ' + @table_name
        SET @row_number = @row_number - 1
    END
END
GO

-- Drop all tables --

DECLARE @sql  NVARCHAR(156)
DECLARE @name VARCHAR(128)
SET @name = ''

DECLARE @row_number INT

SELECT @row_number = Count(*) FROM sysobjects WHERE [type] = 'U' AND category = 0

WHILE @row_number > 0
BEGIN
    SELECT @name = (SELECT TOP 1 [name] FROM sysobjects WHERE [type] = 'U' AND category = 0 AND [name] > @name ORDER BY [name])
    SELECT @sql = 'DROP TABLE [dbo].[' + RTRIM(@name) +']'
    EXEC (@sql)
    PRINT 'Dropped Table: ' + @name
    SET @row_number = @row_number - 1
END
GO

Für temporäre Tabellen ist es etwas komplizierter, da es möglicherweise einige Fremdschlüssel gibt und auch eine Ausnahme:

Drop table operation failed on table XXX because it is not a supported operation on system-versioned temporal tables

Was Sie verwenden können, ist:

-- Disable constraints (foreign keys)
EXEC sp_MSForEachTable 'ALTER TABLE ? NOCHECK CONSTRAINT ALL'
GO

-- Disable system versioning (temporial tables)
EXEC sp_MSForEachTable '
 IF OBJECTPROPERTY(object_id(''?''), ''TableTemporalType'') = 2
  ALTER TABLE ? SET (SYSTEM_VERSIONING = OFF)
'
GO

-- Removing tables
EXEC sp_MSForEachTable 'DROP TABLE ?'
GO