Wie bekomme ich das sp_executesql-Ergebnis in eine Variable?

Ich habe ein Stück dynamisches SQL, das ich ausführen muss, und muss dann das Ergebnis in einer Variablen speichern.

Ich weiß, dass ich verwenden kann sp_executesql, kann aber keine klaren Beispiele dafür finden.

Wenn Sie OUTPUT-Parameter haben, können Sie dies tun

DECLARE @retval int   
DECLARE @sSQL nvarchar(500);
DECLARE @ParmDefinition nvarchar(500);

DECLARE @tablename nvarchar(50)  
SELECT @tablename = N'products'  

SELECT @sSQL = N'SELECT @retvalOUT = MAX(ID) FROM ' + @tablename;  
SET @ParmDefinition = N'@retvalOUT int OUTPUT';

EXEC sp_executesql @sSQL, @ParmDefinition, @retvalOUT=@retval OUTPUT;

SELECT @retval;

Aber wenn Sie dies nicht tun und den SP nicht ändern können:

-- Assuming that your SP return 1 value
create table #temptable (ID int null)
insert into #temptable exec mysp 'Value1', 'Value2'
select * from #temptable

Nicht schön, funktioniert aber.

DECLARE @tab AS TABLE (col1 VARCHAR(10), col2 varchar(10)) 
INSERT into @tab EXECUTE  sp_executesql N'
SELECT 1 AS col1, 2 AS col2
UNION ALL
SELECT 1 AS col1, 2 AS col2
UNION ALL
SELECT 1 AS col1, 2 AS col2'

SELECT * FROM @tab

DECLARE @vi INT
DECLARE @vQuery NVARCHAR(1000)

SET @vQuery = N'SELECT @vi= COUNT(*) FROM <TableName>'

EXEC SP_EXECUTESQL 
        @Query  = @vQuery
      , @Params = N'@vi INT OUTPUT'
      , @vi = @vi OUTPUT

SELECT @vi

Deklarieren Sie @variable int

Exec @variable = proc_name

Rückgabewerte werden im Allgemeinen nicht verwendet, um ein Ergebnis "zurückzugeben", sondern um Erfolg (0) oder eine Fehlernummer (1-65 KB) zurückzugeben. Dies scheint vor allem darauf hinzudeuten, dass sp_executesql keinen Wert zurückgibt, der nicht korrekt ist. sp_executesql gibt 0 für den Erfolg und eine andere Zahl für den Fehler zurück.

Im Folgenden gibt @i 2727 zurück

DECLARE @s NVARCHAR(500)
DECLARE @i INT;
SET @s = 'USE [Blah]; UPDATE STATISTICS [dbo].[TableName] [NonExistantStatisticsName];';
EXEC @i = sys.sp_executesql @s
SELECT @i AS 'Blah'

SSMS zeigt diese Meldung 2727, Ebene 11, Status 1, Zeile 1 an. Der Index 'NonExistantStaticsName' kann nicht gefunden werden.

DECLARE @ValueTable TABLE (Wert VARCHAR (100))

                    SELECT @sql = N'SELECT SRS_SizeSetDetails.'+@COLUMN_NAME+' FROM SRS_SizeSetDetails WHERE FSizeID = '''+@FSizeID+''' AND SRS_SizeSetID = '''+@SRS_SizeSetID+'''';

                    INSERT INTO @ValueTable
                    EXEC sp_executesql @sql;

                    SET @Value='';

                    SET @Value = (SELECT TOP 1  Value FROM @ValueTable)

                    DELETE FROM @ValueTable

Wenn Sie mehr als einen Wert zurückgeben möchten, verwenden Sie Folgendes:

DECLARE @sqlstatement2      NVARCHAR(MAX);
DECLARE @retText            NVARCHAR(MAX);  
DECLARE @ParmDefinition     NVARCHAR(MAX);
DECLARE @retIndex           INT = 0;

SELECT @sqlstatement = 'SELECT @retIndexOUT=column1 @retTextOUT=column2 FROM XXX WHERE bla bla';

SET @ParmDefinition = N'@retIndexOUT INT OUTPUT, @retTextOUT NVARCHAR(MAX) OUTPUT';

exec sp_executesql @sqlstatement, @ParmDefinition, @retIndexOUT=@retIndex OUTPUT, @retTextOUT=@retText OUTPUT;

Die zurückgegebenen Werte befinden sich in @retIndex und @retText

Hier ist etwas, das Sie ausprobieren können

DECLARE  @SqlStatement  NVARCHAR(MAX) = ''
       ,@result     XML
       ,@DatabaseName  VARCHAR(100)
       ,@SchemaName    VARCHAR(10)
       ,@ObjectName    VARCHAR(200);

SELECT   @DatabaseName = 'some database'
       ,@SchemaName   = 'some schema'
       ,@ObjectName   = 'some object (Table/View)'

SET @SqlStatement = '
                    SELECT @result = CONVERT(XML,
                                            STUFF( ( SELECT *
                                                     FROM 
                                                       (
                                                          SELECT TOP(100) 
                                                          * 
                                                          FROM ' + QUOTENAME(@DatabaseName) +'.'+ QUOTENAME(@SchemaName) +'.' + QUOTENAME(@ObjectName) + '
                                                       ) AS A1 
                                                    FOR XML PATH(''row''), ELEMENTS, ROOT(''recordset'')
                                                 ), 1, 0, '''')
                                       )
                ';

EXEC sp_executesql @SqlStatement,N'@result XML OUTPUT', @result = @result OUTPUT;

SELECT DISTINCT
    QUOTENAME(r.value('fn:local-name(.)', 'VARCHAR(200)')) AS ColumnName
FROM @result.nodes('//recordset/*/*') AS records(r)
ORDER BY ColumnName

Dies ist lange her, daher nicht sicher, ob dies noch benötigt wird, aber Sie können die Variable @@ ROWCOUNT verwenden, um zu sehen, wie viele Zeilen von der vorherigen SQL-Anweisung betroffen waren.

Dies ist hilfreich, wenn Sie beispielsweise eine dynamische Update-Anweisung erstellen und mit exec ausführen. @@ ROWCOUNT würde anzeigen, wie viele Zeilen aktualisiert wurden.

Hier ist die Definition

Das hat bei mir funktioniert:

DECLARE @SQL NVARCHAR(4000)

DECLARE @tbl Table (
    Id int,
    Account varchar(50),
    Amount int
) 

-- Lots of code to Create my dynamic sql statement

insert into @tbl EXEC sp_executesql @SQL

select * from @tbl