Bewegen Sie die gesamte Linie in Vim auf und ab

In Notepad ++ kann ich Ctrl+ Shift+ Up/ verwenden Down, um die aktuelle Zeile nach oben und unten zu verschieben. Gibt es einen ähnlichen Befehl wie in Vim? Ich habe endlose Führer durchgesehen, aber nichts gefunden.

Wenn nicht, wie kann ich die Aktion an diese Tastenkombination binden?

Bearbeiten: Die Antwort von Mykola funktioniert für alle Zeilen, außer für die am Anfang und Ende des Puffers. Wenn Sie die erste Zeile nach oben oder unten verschieben, wird die Zeile gelöscht, und wenn Sie die untere Zeile nach oben verschieben, werden zunächst zwei Felder wie bei einem Bauern übersprungen! Kann jemand irgendwelche Verfeinerungen anbieten?

Stellen Sie Folgendes in Ihre .vimrc-Datei, um die Aufgabe zu erledigen

noremap <c-s-up> :call feedkeys( line('.')==1 ? '' : 'ddkP' )<CR>
noremap <c-s-down> ddp

Das Verschwinden der Linie sieht aus wie ein Vim-Bug. Ich habe einen Hack gemacht, um das zu vermeiden. Wahrscheinlich gibt es eine genauere Lösung.

Aktualisieren

Es gibt viele ungeklärte Schwierigkeiten, nur Vim-Kombinationen zu verwenden. Dies sind fehlende Linien und zusätzliches Linienspringen.

Hier ist also die Skriptlösung, die entweder in .vimrc oder ~ / .vim / plugin / swap_lines.vim platziert werden kann

function! s:swap_lines(n1, n2)
    let line1 = getline(a:n1)
    let line2 = getline(a:n2)
    call setline(a:n1, line2)
    call setline(a:n2, line1)
endfunction

function! s:swap_up()
    let n = line('.')
    if n == 1
        return
    endif

    call s:swap_lines(n, n - 1)
    exec n - 1
endfunction

function! s:swap_down()
    let n = line('.')
    if n == line('$')
        return
    endif

    call s:swap_lines(n, n + 1)
    exec n + 1
endfunction

noremap <silent> <c-s-up> :call <SID>swap_up()<CR>
noremap <silent> <c-s-down> :call <SID>swap_down()<CR>

Wenn ich eine Zeile mit der obigen Zeile tauschen möchte, gehe ich normalerweise wie folgt vor

ddkP

Erläuterung

• dd löscht die Zeile und fügt sie dem Standardregister hinzu.
• k bewegt sich eine Linie nach oben (j bewegt sich eine Linie nach unten)
• P wird über der aktuellen Zeile eingefügt

Angenommen, der Cursor befindet sich auf der Linie, die Sie bewegen möchten.

Auf und ab :mbewegen : zum Bewegen

:m +1 - bewegt sich 1 Zeile nach unten

:m -2 - 1 Zeile nach oben bewegen

(Beachten Sie, dass Sie +1 durch beliebige Zahlen ersetzen können, je nachdem, wie viele Zeilen Sie nach oben oder unten verschieben möchten, dh +2 würde es um 2 Zeilen nach unten verschieben, -3 würde es um 2 Zeilen nach oben verschieben.)

Zu einer bestimmten Zeile wechseln

:set number - Zahlenzeilen anzeigen (leichter zu erkennen, wohin Sie sie verschieben)

:m 3 - Verschieben Sie die Zeile nach der 3. Zeile (ersetzen Sie 3 durch eine beliebige Zeile)

Mehrere Zeilen verschieben:

V(dh Shift- V) und bewegen Sie den Courser nach oben und unten, um mehrere Zeilen in VIM auszuwählen

Einmal ausgewählt, drücken Sie :die obigen Befehle m +1usw.

Verschieben Sie eine Zeile nach oben: ddkP

Bewegen Sie eine Zeile nach unten: ddp

Das hat bei mir funktioniert:

http://vim.wikia.com/wiki/Moving_lines_up_or_down_in_a_file

Übrigens, wenn Sie ALT + some_key verwenden möchten und Ihr Terminal (urxvt tut dies) die Einhaltung verweigert, sollten Sie Folgendes in Ihre .vimrc eingeben:

" For moving lines (^] is a special character; use <M-k> and <M-j> if it works)
nnoremap ^]k mz:m-2<CR>`z==
inoremap ^]j <Esc>:m+<CR>==gi
inoremap ^]k <Esc>:m-2<CR>==gi
vnoremap ^]j :m'>+<CR>gv=`<my`>mzgv`yo`z
nnoremap ^]j mz:m+<CR>`z==
vnoremap ^]k :m'<-2<CR>gv=`>my`<mzgv`yo`z

Dabei ist ^] ein einzelnes Zeichen , das die ALT-Taste darstellt. Verwenden Sie zur Eingabe dieses Zeichens C+v, EscVim ( C+q, Escunter Windows).

Fügen Sie der Datei ~ / .vimrc Folgendes hinzu (stellen Sie sicher, dass Sie keine Zuordnung für n, m haben).

nmap n :m +1<CR>
nmap m :m -2<CR>

Durch Drücken der nTaste wird eine Linie nach unten und meine Linie nach oben verschoben.

Positionieren Sie im Befehlsmodus den Cursor auf der Zeile, die Sie nach unten bewegen möchten, und dann

ddp

Erläuterung: dd löscht die aktuelle Zeile in den allgemeinen Puffer. P setzt sie NACH der Cursorposition oder bei ganzen Zeilen eine Zeile darunter zurück.

In vielen Dokumenten gibt es einige Verwirrung hinsichtlich der Befehle p und P. In Wirklichkeit fügt p AFTER cursor und P AT cursor ein.

Fügen Sie diesen Code einfach zu .vimrc (oder .gvimrc) hinzu.

nnoremap <A-j> :m+<CR>==
nnoremap <A-k> :m-2<CR>==
inoremap <A-j> <Esc>:m+<CR>==gi
inoremap <A-k> <Esc>:m-2<CR>==gi
vnoremap <A-j> :m'>+<CR>gv=gv
vnoremap <A-k> :m-2<CR>gv=gv

Genau das, wonach Sie in diesem fantastischen Plugin suchen : https://github.com/vim-scripts/upAndDown

Eine einfache Lösung besteht darin, folgende .vimrcZeilen einzugeben:

nmap <C-UP> :m-2<CR>  
nmap <C-DOWN> :m+1<CR>

Ich habe Folgendes am Ende meiner .vimrc-Datei eingefügt:

noremap H ddkkp
noremap N ddp

Jetzt bewegen 'H' und 'N' die aktuelle Linie nach oben bzw. unten.

Hier ist eine vereinfachte Version für MacVim unter Verwendung der Wikia-Artikelbeispiele (siehe Link aus dem Kommentar der Waffe ).

" Move selection up/down (add =gv to reindent after move)
:vmap <D-S-Up> :m-2<CR>gv
:vmap <D-S-Down> :m'>+<CR>gv

Ich verwende nur die Blockauswahlvariante, da nur Umschalt-V erforderlich ist, um die aktuelle Zeile auszuwählen, und optional Cursor nach oben / unten, um weitere Zeilen auszuwählen.

Gemäß den obigen Verknüpfungen wird durch Drücken von Cmd-Shift-Up / Down die Blockauswahl nach oben / unten verschoben. "D" ist die Befehlstaste in MacVim, für Windows versuchen Sie "C" (Steuerelement) oder "A" (Alt) (z. B. <CAf> wäre Steuerelement Alt f).

Der Wikia-Artikel fügt diesen "= gv" hinzu, wodurch die Einrückung des Blocks nach dem Verschieben basierend auf dem umgebenden Text angepasst wird. Das ist verwirrend, deshalb habe ich es entfernt und stattdessen Verknüpfungen hinzugefügt, um die Auswahl schnell einzurücken.

" Indent selection left/right (Cmd Shift Left/Right is used for Tab switching)
:vmap <D-A-Left> <gv
:vmap <D-A-Right> >gv

Beachten Sie, dass dies auch mit << und >> möglich ist, die Auswahl jedoch verloren geht. Mit diesen Verknüpfungen können Sie den Block mehrmals einrücken und den Block trotzdem verschieben, da die Auswahl beibehalten wird.

Mein MacVim ist so konfiguriert, dass Tabs mit Cmd-Shift-Left / Right gewechselt werden, also habe ich Cmd-Alt-Left / Right verwendet.

Hier ist die Tab-Umschaltung für MacVim (geben Sie .gvimrc mit dem Rest oben ein):

:macm Window.Select\ Previous\ Tab key=<D-S-Left>
:macm Window.Select\ Next\ Tab key=<D-S-Right>

vim plugin unimpaired.vim [e und] e

Wenn Sie den Befehl :help moveeingeben vim, ist hier das Ergebnis:

:[range]m[ove] {address} *:m* *:mo* *:move* *E134* Move the lines given by [range] to below the line given by {address}.

Beispiel: Verschieben Sie die aktuelle Zeile um eine Zeile nach unten => :m+1 .

Beispiel: Verschieben Sie die Zeile mit der Nummer 100 unter die Zeile mit der Nummer 80 => :100 m 80 .

Beispiel: Verschieben Sie die Zeile mit der Nummer 100 unter die Zeile mit der Nummer 200 => :100 m 200 .

Beispiel: Verschieben Sie Zeilen mit der Nummer innerhalb von [100, 120] unter die Zeile mit der Nummer 200 => :100,120 m 200 .

Hier ist eine Lösung, die auf meinem Computer funktioniert : MacBook Pro mit VIM 8.1

Diese Befehle löschen Ihre Zeilen am oberen oder unteren Rand Ihres Puffers nicht.

Die Verwendung der tatsächlichen Symbole, die Alt-J und Alt-K ausgeben, ist eine Problemumgehung für ihre Schlüsselcodes, die in meiner Umgebung nicht richtig zugeordnet sind.

Werfen Sie dies in die alte .vimrc und sehen Sie, ob es für Sie funktioniert.

" Maps Alt-J and Alt-K to macros for moving lines up and down
" Works for modes: Normal, Insert and Visual
nnoremap ∆ :m .+1<CR>==
nnoremap ˚ :m .-2<CR>==
inoremap ∆ <Esc>:m .+1<CR>==gi
inoremap ˚ <Esc>:m .-2<CR>==gi
vnoremap ∆ :m '>+1<CR>gv=gv
vnoremap ˚ :m '<-2<CR>gv=gv

Für mich ddkkptat es (anstatt ddkPmit einem Großbuchstaben P, das auch funktionieren würde).

: m. + 1 oder: m.-2 würde ausreichen, wenn Sie eine einzelne Linie verschieben. Hier ist mein Skript zum Verschieben mehrerer Zeilen. Im visuellen Modus werden die Zeilen mit der visuellen Auswahl durch Alt-Auf / Alt-Ab um eine Zeile nach oben / unten verschoben. Im Einfügemodus oder im normalen Modus verschiebt Alt-Up / Alt-Down die aktuelle Zeile, wenn kein Zählpräfix angegeben ist. Wenn es ein Zählpräfix gibt, verschiebt Alt-up / Alt-down so viele Zeilen, beginnend mit der aktuellen Zeile, um eine Zeile nach oben / unten.

function! MoveLines(offset) range
    let l:col = virtcol('.')
    let l:offset = str2nr(a:offset)
    exe 'silent! :' . a:firstline . ',' . a:lastline . 'm'
        \ . (l:offset > 0 ? a:lastline + l:offset : a:firstline + l:offset)
    exe 'normal ' . l:col . '|'
endf

imap <silent> <M-up> <C-O>:call MoveLines('-2')<CR>
imap <silent> <M-down> <C-O>:call MoveLines('+1')<CR>
nmap <silent> <M-up> :call MoveLines('-2')<CR>
nmap <silent> <M-down> :call MoveLines('+1')<CR>
vmap <silent> <M-up> :call MoveLines('-2')<CR>gv
vmap <silent> <M-down> :call MoveLines('+1')<CR>gv

Wenn Sie dies in mehreren Zeilen tun möchten, die einer bestimmten Suche entsprechen:

• Oben: :g/Your query/ normal ddp oder:g/Your query/ m -1
• Runter :g/Your query/ normal ddpoder:g/Your query/ m +1