Batch-Datei. Löschen Sie alle Dateien und Ordner in einem Verzeichnis

Ich möchte eine Batch-Datei haben, die alle Ordner und Dateien in meinem Cache-Ordner für mein drahtloses Toolkit löscht.

Derzeit habe ich Folgendes:

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

Dadurch werden alle DB-Dateien in meinem RMS- Verzeichnis gelöscht. Ich möchte jedoch alle Elemente aus diesem Verzeichnis löschen. Wie kann ich das machen?

del *.*statt del *.db. Das wird alles entfernen.

Verwenden:

• Erstellen Sie eine Batchdatei

• Kopieren Sie den folgenden Text in die Batch-Datei

  set folder="C:\test"
  cd /d %folder%
  for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
  

Es werden alle Dateien und Ordner gelöscht .

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

Dadurch wird alles aus dem Ordner (und dem Ordner selbst) gelöscht.

del *.*löscht nur Dateien, aber keine Unterverzeichnisse. Um den Inhalt eines Verzeichnisses zu zerstören, können Sie dieses Skript verwenden:

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

Die pushdÄnderungen in dem Verzeichnis, in dem Sie die untergeordneten Elemente löschen möchten. Wenn Sie dann rdaufgefordert werden, das aktuelle Verzeichnis und alle Unterverzeichnisse zu löschen, ist das Löschen der Unterverzeichnisse erfolgreich, aber das Löschen des aktuellen Verzeichnisses schlägt fehl - weil wir uns darin befinden. Dies erzeugt einen Fehler, der 2> NULverschluckt. (2 ist der Fehlerstrom).

Ich habe das gerade aus dem zusammengestellt, was morty346 gepostet hat:

set folder="C:\test"
IF EXIST "%folder%" (
    cd /d %folder%
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
)

Es wird eine schnelle Überprüfung hinzugefügt, ob der in der Variablen definierte Ordner zuerst vorhanden ist, das Verzeichnis in den Ordner geändert und der Inhalt gelöscht.

Sie können dies mit delund dem /SFlag tun (um anzuweisen, alle Dateien aus allen Unterverzeichnissen zu rekursieren):

del /S C:\Path\to\directory\*

Der Befehl RD kann ebenfalls verwendet werden. Rekursiv leise ohne Aufforderung löschen:

@RD /S /Q %VAR_PATH%

Rmdir (rd)

set "DIR_TO_DELETE=your_path_to_the_folder"

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q
    del %DIR_TO_DELETE%\*.* /F /Q
)

Versuche Folgendes; Für mich geht das.

Ich habe eine Anwendung, die Daten in meinem Ordner "C: \ tmp" speichert, und das Folgende funktioniert am besten für mich. Es werden nicht einmal Ja oder Nein gefragt , um die Daten zu löschen. Ich habe einen Zeitplan erstellt, der alle 5 Minuten ausgeführt werden soll

cd "C:\tmp"

del *.* /Q

Besser noch, sagen wir, ich möchte alles unter dem C:\windows\tempOrdner entfernen .

@echo off
rd C:\windows\temp /s /q

Sie können Robocopy verwenden, um einen leeren Ordner in den Ordner zu spiegeln, den Sie löschen.

robocopy "C:\temp\empty" "C:\temp\target" /E /MIR

Es funktioniert auch, wenn Sie den eigentlichen Ordner nicht entfernen oder neu erstellen können.

Es ist ein vorhandenes leeres Verzeichnis erforderlich.

Verwenden

set dir="Your Folder Path Here"
rmdir /s %dir%
mkdir %dir%

Diese Version wird gelöscht, ohne zu fragen:

set dir="Your Folder Here"
rmdir /s /q %dir%
mkdir %dir%

Beispiel:

set dir="C:\foo1\foo\foo\foo3"
rmdir /s /q %dir%
mkdir %dir%

Dies wird klar C:\foo1\foo\foo\foo3.

_{(Ich möchte die Antwort von Abdullah Sabouin erwähnen . Es gab eine Verwechslung damit, dass ich ihn kopiert habe. Ich habe seinen Beitrag nicht bemerkt. Ich möchte Melpomene dafür danken, dass er auf Fehler hingewiesen hat!)}

Sie können nicht alles entweder rmdiroder delalleine löschen :

• rmdir /s /qakzeptiert keine Platzhalterparameter. Also rmdir /s /q *wird Fehler.
• del /s /f /q löscht alle Dateien, aber leere Unterverzeichnisse bleiben erhalten.

Meine bevorzugte Lösung (wie ich sie in vielen anderen Batch-Dateien verwendet habe) ist:

rmdir /s /q . 2>NUL

Nur eine modifizierte Version von GregMs Antwort :

set folder="C:\test"
cd /D %folder%
if NOT %errorlevel% == 0 (exit /b 1)
echo Entire content of %cd% will be deleted. Press Ctrl-C to abort
pause

REM First the directories /ad option of dir
for /F "delims=" %%i in ('dir /b /ad') do (echo rmdir "%%i" /s/q)

REM Now the files /a-d option of dir
for /F "delims=" %%i in ('dir /b /a-d') do (echo del "%%i" /q)

REM To deactivate simulation mode remove the word 'echo' before 'rmdir' and 'del'.

@echo off
@color 0A

echo Deleting logs

rmdir /S/Q c:\log\

ping 1.1.1.1 -n 5 -w 1000 > nul

echo Adding log folder back

md c:\log\

Sie waren auf dem richtigen Weg. Fügen Sie einfach Code hinzu, um den Ordner hinzuzufügen, der wieder gelöscht wird.

Sie sollten diesen Befehl ausführen, um alle Dateien zu löschen:

del*.*