TSQL - Wie verwende ich GO in einem BEGIN .. END-Block?

Ich generiere ein Skript für die automatische Migration von Änderungen aus mehreren Entwicklungsdatenbanken zu Staging / Produktion. Grundsätzlich werden eine Reihe von Änderungsskripten benötigt, die zu einem einzigen Skript zusammengeführt werden, wobei jedes Skript in eine IF whatever BEGIN ... ENDAnweisung eingeschlossen wird.

Einige der Skripte erfordern jedoch eine GOAnweisung, damit der SQL-Parser beispielsweise nach der Erstellung eine neue Spalte kennt.

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Sobald ich das jedoch in einen IFBlock einpacke:

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

Es schlägt fehl, weil ich eine BEGINohne Übereinstimmung sende END. Wenn ich das jedoch entferne GO, beschwert es sich erneut über eine unbekannte Spalte.

Gibt es eine Möglichkeit, dieselbe Spalte in einem einzelnen IFBlock zu erstellen und zu aktualisieren ?

GO ist kein SQL - es ist einfach ein Batch-Trennzeichen, das in einigen MS SQL-Tools verwendet wird.

Wenn Sie dies nicht verwenden, müssen Sie sicherstellen, dass die Anweisungen separat ausgeführt werden - entweder in verschiedenen Stapeln oder mithilfe von dynamischem SQL für die Grundgesamtheit (danke @gbn):

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

Ich hatte das gleiche Problem und konnte es schließlich mit SET NOEXEC lösen .

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

Sie können versuchen sp_executesql, den Inhalt zwischen den einzelnen GOAnweisungen in eine separate auszuführende Zeichenfolge aufzuteilen, wie im folgenden Beispiel gezeigt. Außerdem gibt es eine Variable @statementNo, mit der verfolgt werden kann, welche Anweisung zum einfachen Debuggen ausgeführt wird, wenn eine Ausnahme aufgetreten ist. Die Zeilennummern beziehen sich auf den Anfang der entsprechenden Anweisungsnummer, die den Fehler verursacht hat.

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

Sie können auch einfach mehrzeilige Anweisungen ausführen, wie im obigen Beispiel gezeigt, indem Sie sie einfach in einfache Anführungszeichen ( ') setzen. Vergessen Sie nicht, ''beim Erstellen der Skripte einfache Anführungszeichen in der Zeichenfolge mit einem doppelten einfachen Anführungszeichen ( ) zu umgehen.

Ich habe es letztendlich zum Laufen gebracht, indem ich jede Instanz GOauf ihrer eigenen Linie durch ersetzt habe

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

Dies ist stark bevorzugt , jede Gruppe von Anweisungen in einer Zeichenfolge zu wickeln, ist aber noch weit vom Ideal entfernt . Wenn jemand eine bessere Lösung findet, poste sie und ich akzeptiere sie stattdessen.

Sie können die Anweisungen in BEGIN und END anstelle des GO dazwischen einschließen

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

(Getestet in der Northwind-Datenbank)

Bearbeiten: (wahrscheinlich auf SQL2012 getestet)

Sie können diese Lösung ausprobieren:

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

Ich habe RAISERRORin der Vergangenheit dafür verwendet

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Sie können a- GOTOund LABELAnweisungen einfügen, um Code zu überspringen, sodass die GOSchlüsselwörter intakt bleiben.