Wie verhindere ich, dass TStrings.SaveToFile eine letzte leere Zeile erstellt?

Ich habe eine Datei .\input.txtwie diese:

aaa
bbb
ccc

Wenn ich es mit lese TStrings.LoadFromFileund zurückschreibe (auch ohne Änderungen vorzunehmen) TStrings.SaveToFile, wird am Ende der Ausgabedatei eine leere Zeile erstellt.

var
  Lines : TStrings;
begin
  Lines := TStringList.Create;
  try
    Lines.LoadFromFile('.\input.txt');

    //...

    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;

Das gleiche Verhalten kann mit der TStrings.TextEigenschaft beobachtet werden, die eine Zeichenfolge zurückgibt, die am Ende eine leere Zeile enthält.

Für Delphi 10.1 und höher gibt es eine Eigenschaft TrailingLineBreak die dieses Verhalten steuert.

Wenn die TrailingLineBreak-Eigenschaft True ist (Standardwert), enthält die Text-Eigenschaft einen Zeilenumbruch nach der letzten Zeile. Wenn es falsch ist, enthält der Textwert keinen Zeilenumbruch nach der letzten Zeile. Dies kann auch durch die Option soTrailingLineBreak gesteuert werden.

Für Delphi 10.1 (Berlin) oder neuer wird die beste Lösung in Uwes Antwort beschrieben.

Für ältere Delphi-Versionen habe ich eine Lösung gefunden, indem ich eine untergeordnete Klasse TStringListder TStrings.GetTextStrvirtuellen Funktion erstellt und diese überschrieben habe. Ich bin jedoch froh zu wissen, ob es eine bessere Lösung gibt oder ob jemand anderes in meiner Lösung einen Fehler gefunden hat

Schnittstelle:

  uses
    Classes;

  type
    TMyStringList = class(TStringList)
    private
      FIncludeLastLineBreakInText : Boolean;
    protected
      function GetTextStr: string; override;
    public
      constructor Create(AIncludeLastLineBreakInText : Boolean = False); overload;
      property IncludeLastLineBreakInText : Boolean read FIncludeLastLineBreakInText write FIncludeLastLineBreakInText;
    end;

Implementierung:

uses
  StrUtils;      

constructor TMyStringList.Create(AIncludeLastLineBreakInText : Boolean = False);
begin
  inherited Create;

  FIncludeLastLineBreakInText := AIncludeLastLineBreakInText;
end;

function TMyStringList.GetTextStr: string;
begin
  Result := inherited;

  if(not IncludeLastLineBreakInText) and EndsStr(LineBreak, Result)
  then SetLength(Result, Length(Result) - Length(LineBreak));
end;

Beispiel:

procedure TForm1.Button1Click(Sender: TObject);
var
  Lines : TStrings;
begin
  Lines := TMyStringList.Create();
  try
    Lines.LoadFromFile('.\input.txt');
    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;