Wie teste ich, ob eine ausführbare Datei in% PATH% aus einer Windows-Batchdatei vorhanden ist?

Ich suche nach einer einfachen Möglichkeit, um zu testen, ob eine ausführbare Datei in der Umgebungsvariablen PATH aus einer Windows-Batchdatei vorhanden ist.

Die Verwendung externer Tools, die nicht vom Betriebssystem bereitgestellt werden, ist nicht zulässig. Die minimal erforderliche Windows-Version ist Windows XP.

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

Wenn Sie dies für verschiedene Erweiterungen benötigen, wiederholen Sie einfach Folgendes PATHEXT:

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

Könnte sein, dass es whereauch bereits in älteren Windows-Versionen existiert, aber ich habe keinen Zugriff auf eine, daher kann ich es nicht sagen. Auf meinem Computer funktioniert auch Folgendes:

where myExecutable

und kehrt mit einem Exit-Code ungleich Null zurück, wenn er nicht gefunden wurde. In einem Stapel möchten Sie wahrscheinlich auch die Ausgabe umleiten NUL.

Merken Sie sich

Das Parsen in Batch ( .bat) - Dateien und in der Befehlszeile ist unterschiedlich (da Batch-Dateien %0- %9) haben, daher müssen Sie das %dort verdoppeln . In der Kommandozeile ist dies nicht erforderlich, also für Variablen nur %X.

Windows Vista und spätere Versionen werden mit einem Programm geliefert where.exe, das nach Programmen im Pfad sucht. Es funktioniert so:

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

Zur Verwendung in einer Batch-Datei können Sie den /qSchalter verwenden, der nur ERRORLEVELeine Ausgabe festlegt und keine Ausgabe erzeugt.

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

Oder eine einfache (aber weniger lesbare) Kurzversion, die die Nachricht druckt und Ihre App beendet:

where /q myapplication || ECHO Cound not find app. && EXIT /B

Hier ist eine einfache Lösung , dass Versuche , die Anwendung und Griffe jeden Fehler laufen hinterher .

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

Fehlercode 9009 bedeutet normalerweise, dass die Datei nicht gefunden wurde.

Der einzige Nachteil ist, dass file.exees tatsächlich ausgeführt wird, wenn es gefunden wird (was in einigen Fällen nicht wünschenswert ist).

Dies kann durch Parametersubstitution erreicht werden.

%~$PATH:1

Dies gibt den vollständigen Pfad des ausführbaren Dateinamens in% 1 zurück, andernfalls eine leere Zeichenfolge.

Dies funktioniert nicht mit benutzerdefinierten Variablen. Wenn der ausführbare Dateiname kein Parameter für Ihr Skript ist, benötigen Sie eine Unterroutine. Beispielsweise:

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

Siehe http://ss64.com/nt/syntax-args.html

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....

Manchmal funktioniert diese einfache Lösung, bei der Sie überprüfen, ob die Ausgabe Ihren Erwartungen entspricht. In der ersten Zeile wird der Befehl ausgeführt und die letzte Zeile der Standardausgabe abgerufen.

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i
if "%xcopyoutput%"=="" echo xcopy not in path.

Wenn Sie etwas wie mich im Startordner suchen, sollte Ordner gehen. Zum Beispiel suche ich exe im Startordner und ich benutze diesen Code wie

@echo off
cd C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
where /q program.exe
IF ERRORLEVEL 1 (
echo F | xcopy /Y /S /I /E "\\programsetup\programsetup.exe" 
"C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\program.exe"
) ELSE (
ECHO Application exists. Let's go!
)

Verwenden Sie den Befehl: Powershell Test-Path "exe, nach dem Sie suchen"

Es wird True zurückgeben, wenn es vorhanden ist, andernfalls False.

Für diejenigen, die nach einer PowerShell-Option suchen. Sie können das Get-CommandCmdlet verwenden, das zwei Elemente übergibt. Geben Sie zuerst den aktuellen Verzeichnisort mit dem .\Präfix an und dann nur den exe-Namen.

(Get-Command ".\notepad", "notepad" -ErrorAction Ignore -CommandType Application) -ne $null

Dies gibt true zurück, wenn es lokal oder in systemweiten Pfaden gefunden wird.