Vim: Erstellen von übergeordneten Verzeichnissen beim Speichern

Wenn ich aufrufe, vim foo/bar/somefileaber foo/barnoch nicht existiere, weigert sich Vim zu speichern.

Ich weiß, dass ich :!mkdir foo/barvon Vim zu einer Shell wechseln oder etwas tun könnte, aber ich bin faul :) Gibt es eine Möglichkeit, Vim dazu zu bringen, dies automatisch zu tun, wenn der Puffer gespeichert wird?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Beachten Sie die Bedingungen: expand("<afile>")!~#'^\w\+:/'Verhindert, dass vim Verzeichnisse für Dateien wie erstellt, ftp://*und !isdirectoryverhindert teure mkdir-Aufrufe.

Update : Etwas bessere Lösung, die auch nach nicht leeren Buftypen sucht und Folgendes verwendet mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

Basierend auf den Vorschlägen zu meiner Frage habe ich Folgendes erhalten:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Dies definiert den :WBefehl. Im Idealfall würde Ich mag alle haben :w!, :wq, :wq!, :wallusw. die gleiche Arbeit, aber ich bin nicht sicher , ob es ohne grundsätzlich Neuimplementierung sie alle mit benutzerdefinierten Funktionen möglich ist.

Ich habe dies zu meinem ~ / .vimrc hinzugefügt

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Wenn ich das Verzeichnis erstellen muss, in dem ich mich :mk.befinde, tippe ich es durch "! Mkdir -p / path / to / my / file /" und kann den Befehl überprüfen, bevor ich ihn aufrufe.

Ich habe :saveas!das Verzeichnis erstellt, wenn es fehlt: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Dieser Code fordert Sie auf, das Verzeichnis mit :woder einfach zu erstellen :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Ich glaube, ich habe es geschafft, dies in drei Zeilen zu tun und zu kombinieren, was andere zu dieser Antwort sagen.

Dies scheint den Trick zu tun:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Es wird versucht, den Ordner beim Speichern eines Puffers automatisch zu erstellen. Wenn etwas Schlimmes passiert (dh Berechtigungsprobleme), wird es einfach heruntergefahren und das Schreiben der Datei schlägt fehl.

Wenn jemand offensichtliche Mängel sieht, schreibe bitte einen Kommentar. Ich bin nicht sehr versiert in Vimscript.

EDIT: Notizen dank ZyX

• Dies funktioniert nicht, wenn Ihre Ordner Leerzeichen enthalten (anscheinend sind sie nicht ordnungsgemäß maskiert oder so).
• Oder wenn Sie Pseudodateien machen.
• Oder wenn Sie Ihr vimrc beziehen.
• Aber mein Sohn, es ist kurz.