Wie liste ich alle "env" -Eigenschaften innerhalb des Jenkins-Pipeline-Jobs auf?

Bei einer Build-Pipeline von Jenkins 2.1 injiziert Jenkins eine envVariable in die node{}. Zum Beispiel BRANCH_NAMEkann mit zugegriffen werden

node {
    echo ${env.BRANCH_NAME}
    ...

Ich möchte alle env Eigenschaften innerhalb der Jenkins-Pipeline wiedergeben

... wenn man bedenkt, dass ich nicht alle Eigenschaften im Voraus kenne .

Ich suche nach Code wie

node {
    for(e in env){
        echo e + " is " + ${e}
    }
    ...

das würde so etwas wie widerhallen

 BRANCH_NAME is myBranch2
 CHANGE_ID is 44
 ...

Ein anderer, prägnanterer Weg:

node {
    echo sh(returnStdout: true, script: 'env')
    // ...
}

vgl. https://jenkins.io/doc/pipeline/steps/workflow-durable-task-step/#code-sh-code-shell-script

Laut Jenkins Dokumentation für deklarative Pipeline :

sh 'printenv'

Für Jenkins Skript-Pipeline :

echo sh(script: 'env|sort', returnStdout: true)

Das Obige sortiert auch Ihre Umgebungsvariablen für die Bequemlichkeit.

Folgendes funktioniert:

@NonCPS
def printParams() {
  env.getEnvironment().each { name, value -> println "Name: $name -> Value $value" }
}
printParams()

Beachten Sie, dass es höchstwahrscheinlich bei der ersten Ausführung fehlschlägt und Sie verschiedene groovige Methoden genehmigen müssen, um in Jenkins Sandbox ausgeführt zu werden. Dies erfolgt unter "Verwalten der Genehmigung von Jenkins / In-Process-Skripten".

Die Liste, die ich bekommen habe, ist enthalten:

• BUILD_DISPLAY_NAME
• BUILD_ID
• BUILD_NUMBER
• BUILD_TAG
• BUILD_URL
• KLASSENPFAD
• HUDSON_HOME
• HUDSON_SERVER_COOKIE
• HUDSON_URL
• JENKINS_HOME
• JENKINS_SERVER_COOKIE
• JENKINS_URL
• JOB_BASE_NAME
• BERUFSBEZEICHNUNG
• JOB_URL

Sie können das Ergebnis mit sh/ batstep und erreichen readFile:

node {
    sh 'env > env.txt'
    readFile('env.txt').split("\r?\n").each {
        println it
    }
}

Leider wird nur eine env.getEnvironment()sehr begrenzte Karte von Umgebungsvariablen zurückgegeben.

Warum all diese Kompliziertheit?

sh 'env'

macht was du brauchst (unter * nix)

Hier ist ein schnelles Skript, das Sie als Pipeline-Job hinzufügen können, um alle Umgebungsvariablen aufzulisten:

node {
    echo(env.getEnvironment().collect({environmentVariable ->  "${environmentVariable.key} = ${environmentVariable.value}"}).join("\n"))
    echo(System.getenv().collect({environmentVariable ->  "${environmentVariable.key} = ${environmentVariable.value}"}).join("\n"))
}

Dadurch werden sowohl System- als auch Jenkins-Variablen aufgelistet.

Plattformübergreifende Auflistung aller Umgebungsvariablen:

if (isUnix()) {
    sh env
}
else {
    bat set
}

Ich benutze das Blue Ocean Plugin und mochte nicht, dass jeder Umgebungseintrag einen eigenen Block bekommt. Ich möchte einen Block mit allen Zeilen.

Druckt schlecht:

sh 'echo `env`'

Druckt schlecht:

sh 'env > env.txt'
for (String i : readFile('env.txt').split("\r?\n")) {
    println i
}

Druckt gut:

sh 'env > env.txt'
sh 'cat env.txt'

Druckt gut: (wie von @mjfroehlich erwähnt)

echo sh(script: 'env', returnStdout: true)

Die obigen Antworten sind aufgrund der neuen Pipeline-Syntax jetzt veraltet. Unten werden die Umgebungsvariablen ausgedruckt.

script {
        sh 'env > env.txt'
        String[] envs = readFile('env.txt').split("\r?\n")

        for(String vars: envs){
            println(vars)
        }
    }

Die reinen Groovy- Lösungen, die die globale envVariable lesen, drucken nicht alle Umgebungsvariablen (z. B. fehlen Variablen aus dem environmentBlock, aus dem withEnvKontext und den meisten maschinenspezifischen Variablen aus dem Betriebssystem). Mit Shell-Schritten ist es möglich, einen vollständigeren Satz zu erhalten, dies erfordert jedoch einen nodeKontext, der nicht immer erwünscht ist.

Hier ist eine Lösung, die den getContextSchritt verwendet, um den vollständigen Satz von Umgebungsvariablen einschließlich der Pipeline-Parameter für den aktuellen Kontext abzurufen und zu drucken.

Vorsichtsmaßnahme: Funktioniert nicht im Groovy-Sandkasten. Sie können es jedoch aus einer vertrauenswürdigen gemeinsam genutzten Bibliothek verwenden.

def envAll = getContext( hudson.EnvVars )
echo envAll.collect{ k, v -> "$k = $v" }.join('\n')

Wenn Sie die envListe wirklich durchlaufen möchten, gehen Sie einfach wie folgt vor :

def envs = sh(returnStdout: true, script: 'env').split('\n')
envs.each { name  ->
    println "Name: $name"
}

Ein anderer Weg, um genau die in der Frage erwähnte Ausgabe zu erhalten:

envtext= "printenv".execute().text
envtext.split('\n').each
{   envvar=it.split("=")
    println envvar[0]+" is "+envvar[1]
}

Dies kann leicht erweitert werden, um eine Karte mit einer Teilmenge von Umgebungsvariablen zu erstellen, die einem Kriterium entsprechen:

envdict=[:]
envtext= "printenv".execute().text
envtext.split('\n').each
{   envvar=it.split("=")
    if (envvar[0].startsWith("GERRIT_"))
        envdict.put(envvar[0],envvar[1])
}    
envdict.each{println it.key+" is "+it.value}

Ich nehme an, Sie brauchten das in Form eines Skripts, aber wenn jemand anderes nur einen Blick auf die Jenkins-GUI werfen möchte, können Sie diese Liste finden, indem Sie den Abschnitt "Umgebungsvariablen" im Kontextmenü jedes Builds auswählen. Wählen Sie project = > Wählen Sie build => Umgebungsvariablen

Ich fand, dass dies der einfachste Weg ist:

pipeline {
    agent {
        node {
            label 'master'
        }
    }   
    stages {
        stage('hello world') {
            steps {
                sh 'env'
            }
        }
    }
}

Sie können alle Variablen von Ihrer Jenkins-Instanz abrufen. Nur besuchen:

• $ {jenkins_host} /env-vars.html
• $ {jenkins_host} / Pipeline-Syntax / Globals