Wie kann ich die Ausgabe eines Shell-Befehls ausführen, der mit einer Variablen aus Jenkinsfile (groovy) ausgeführt wird?

Ich habe so etwas in einer Jenkins-Datei (Groovy) und möchte den Standard- und den Exit-Code in einer Variablen aufzeichnen, um die Informationen später zu verwenden.

sh "ls -l"

Wie kann ich das tun, zumal es den Anschein hat, dass Sie keinen wirklich groovigen Code innerhalb von ausführen können Jenkinsfile?

Mit der neuesten Version des Pipeline- shSchritts können Sie Folgendes tun:

// Git committer email
GIT_COMMIT_EMAIL = sh (
    script: 'git --no-pager show -s --format=\'%ae\'',
    returnStdout: true
).trim()
echo "Git committer email: ${GIT_COMMIT_EMAIL}"

Ein weiteres Feature ist die returnStatusOption.

// Test commit message for flags
BUILD_FULL = sh (
    script: "git log -1 --pretty=%B | grep '\\[jenkins-full]'",
    returnStatus: true
) == 0
echo "Build full flag: ${BUILD_FULL}"

Diese Optionen wurden aufgrund dieses Problems hinzugefügt .

Siehe offizielle Dokumentation zum shBefehl.

Die aktuelle Pipeline-Version unterstützt nativ returnStdoutund returnStatus, wodurch die Ausgabe oder der Status von sh/ batstep abgerufen werden kann.

Ein Beispiel:

def ret = sh(script: 'uname', returnStdout: true)
println ret

Eine offizielle Dokumentation .

Die schnelle Antwort lautet:

sh "ls -l > commandResult"
result = readFile('commandResult').trim()

Ich denke, es gibt eine Feature-Anfrage, um das Ergebnis von sh step zu erhalten, aber soweit ich weiß, gibt es derzeit keine andere Option.

EDIT: JENKINS-26133

EDIT2: Nicht ganz sicher seit welcher Version, aber sh / bat Schritte können jetzt die Standardausgabe zurückgeben, einfach:

def output = sh returnStdout: true, script: 'ls -l'

Wenn Sie die Standardausgabe erhalten möchten UND wissen möchten, ob der Befehl erfolgreich war oder nicht, verwenden Sie ihn einfach returnStdoutund verpacken Sie ihn in einen Ausnahmebehandler:

Skript-Pipeline

try {
    // Fails with non-zero exit if dir1 does not exist
    def dir1 = sh(script:'ls -la dir1', returnStdout:true).trim()
} catch (Exception ex) {
    println("Unable to read dir1: ${ex}")
}

Ausgabe :

[Pipeline] sh
[Test-Pipeline] Running shell script
+ ls -la dir1
ls: cannot access dir1: No such file or directory
[Pipeline] echo
unable to read dir1: hudson.AbortException: script returned exit code 2

Leider fehlt bei hudson.AbortException eine nützliche Methode, um diesen Exit-Status zu erhalten. Wenn also der tatsächliche Wert erforderlich ist, müssen Sie ihn aus der Nachricht analysieren (ugh!).

Im Gegensatz zu Javadoc https://javadoc.jenkins-ci.org/hudson/AbortException.html ist der Build nicht fehlgeschlagen, wenn diese Ausnahme abgefangen wird. Es schlägt fehl, wenn es nicht gefangen wird!

Update: Wenn Sie auch die STDERR-Ausgabe vom Shell-Befehl erhalten möchten, unterstützt Jenkins diesen allgemeinen Anwendungsfall leider nicht richtig. Ein Ticket für 2017 JENKINS-44930 steckt in einem Ping-Pong-Zustand, ohne Fortschritte bei der Lösung zu machen. Bitte fügen Sie Ihre Gegenstimme hinzu.

Für eine Lösung könnte es jetzt einige mögliche Ansätze geben:

a) Leiten 2>&1 Sie STDERR zu STDOUT um - aber es liegt dann an Ihnen, dies aus der Hauptausgabe zu analysieren, und Sie erhalten die Ausgabe nicht, wenn der Befehl fehlschlägt - weil Sie sich im Ausnahmebehandler befinden.

b) Leiten Sie STDERR in eine temporäre Datei um (deren Namen Sie zuvor vorbereitet haben) 2>filename(denken Sie jedoch daran, die Datei anschließend zu bereinigen). Hauptcode wird:

def stderrfile = 'stderr.out'
try {
    def dir1 = sh(script:"ls -la dir1 2>${stderrfile}", returnStdout:true).trim()
} catch (Exception ex) {
    def errmsg = readFile(stderrfile)
    println("Unable to read dir1: ${ex} - ${errmsg}")
}

c) Gehen Sie in die andere Richtung, setzen Sie returnStatus=truestattdessen, verzichten Sie auf den Ausnahmebehandler und erfassen Sie die Ausgabe immer in einer Datei, dh:

def outfile = 'stdout.out'
def status = sh(script:"ls -la dir1 >${outfile} 2>&1", returnStatus:true)
def output = readFile(outfile).trim()
if (status == 0) {
    // output is directory listing from stdout
} else {
    // output is error message from stderr
}

Vorsichtsmaßnahme: Der obige Code ist Unix / Linux-spezifisch - Windows erfordert völlig andere Shell-Befehle.

Dies ist ein Beispielfall, der meiner Meinung nach Sinn machen wird!

node('master'){
    stage('stage1'){
    def commit = sh (returnStdout: true, script: '''echo hi
    echo bye | grep -o "e"
    date
    echo lol''').split()


    echo "${commit[-1]} "

    }
}

Für diejenigen, die die Ausgabe in nachfolgenden Shell-Befehlen verwenden müssen, anstatt groovig zu sein, könnte so etwas wie dieses Beispiel getan werden:

    stage('Show Files') {
        environment {
          MY_FILES = sh(script: 'cd mydir && ls -l', returnStdout: true)
        }
        steps {
          sh '''
            echo "$MY_FILES"
          '''
        }
    }

Ich fand die Beispiele auf Code Maven sehr nützlich.

Der einfachste Weg ist, diesen Weg zu benutzen

my_var=`echo 2` echo $my_var Ausgabe: 2

Beachten Sie, dass ein einfaches Anführungszeichen kein einfaches Anführungszeichen (`) ist.