Beim Versuch, einige Dateien in Git festzuschreiben, werden nachgestellte Whitespace-Fehler angezeigt.

Ich möchte diese nachgestellten Leerzeichen automatisch entfernen, bevor ich Python-Dateien speichere.

Können Sie vim dafür konfigurieren? Wenn das so ist, wie?

Ich habe die Antwort hier gefunden .

Das Hinzufügen von Folgendem zu meiner .vimrc-Datei hat den Trick getan.

autocmd BufWritePre *.py :%s/\s\+$//e

Zusammenstellung von oben plus Speichern der Cursorposition:

fun! <SID>StripTrailingWhitespaces()
    let l = line(".")
    let c = col(".")
    keepp %s/\s\+$//e
    call cursor(l, c)
endfun

autocmd FileType c,cpp,java,php,ruby,python autocmd BufWritePre <buffer> :call <SID>StripTrailingWhitespaces()

Wenn Sie dies beim Speichern auf eine beliebige Datei anwenden möchten, lassen Sie die zweite weg autocmdund verwenden Sie einen Platzhalter *:

autocmd BufWritePre * :call <SID>StripTrailingWhitespaces()

Ich habe normalerweise auch eine:

match Todo /\s\+$/

in meiner .vimrcDatei, so dass Leerzeichen am Zeilenende hellig sind.

Todo ein Syntax hilighting wobei group-name , der wie Schlüsselwörter für hilighting verwendet wird TODO, FIXMEoder XXX. Es hat eine ärgerlich hässliche gelbliche Hintergrundfarbe und ich finde es am besten, Dinge zu hellen, die Sie nicht in Ihrem Code haben wollen :-)

Ich hebe sowohl vorhandene nachgestellte Leerzeichen hervor als auch nachfolgende Leerzeichen.

Ich konfiguriere meinen Editor (vim) so, dass am Ende Leerzeichen angezeigt werden, z

mit diesem am Ende meiner .vimrc:

highlight ExtraWhitespace ctermbg=red guibg=red
match ExtraWhitespace /\s\+$/
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
autocmd InsertLeave * match ExtraWhitespace /\s\+$/
autocmd BufWinLeave * call clearmatches()

und ich 'entferne' es automatisch von Dateien, wenn ich sie speichere, in meinem Fall * .rb für Ruby-Dateien, wieder in meinem ~ / .vimrc

function! TrimWhiteSpace()
    %s/\s\+$//e
endfunction
autocmd BufWritePre     *.rb :call TrimWhiteSpace()

Hier ist eine Möglichkeit, nach mehr als einem Dateityp zu filtern.

autocmd FileType c,cpp,python,ruby,java autocmd BufWritePre <buffer> :%s/\s\+$//e

Kopiert und eingefügt von http://blog.kamil.dworakowski.name/2009/09/unobtrusive-highlighting-of-trailing.html (der Link funktioniert nicht mehr, aber das Bit, das Sie benötigen, ist unten)

"Dies hat den Vorteil, dass nicht jedes Leerzeichen am Ende der Zeile hervorgehoben wird, nur wenn Sie eine Datei öffnen oder den Einfügemodus verlassen. Sehr ordentlich."

highlight ExtraWhitespace ctermbg=red guibg=red
au ColorScheme * highlight ExtraWhitespace guibg=red
au BufEnter * match ExtraWhitespace /\s\+$/
au InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
au InsertLeave * match ExtraWhiteSpace /\s\+$/

Ich habe diese Lösung in einem Kommentar bei gesehen VIM Wikia gesehen - Entfernen Sie unerwünschte Leerzeichen

Ich mochte es wirklich. Fügt ein .zu den unerwünschten Leerzeichen hinzu.

Setzen Sie dies in Ihre .vimrc

" Removes trailing spaces
function TrimWhiteSpace()
  %s/\s*$//
  ''
endfunction

set list listchars=trail:.,extends:>
autocmd FileWritePre * call TrimWhiteSpace()
autocmd FileAppendPre * call TrimWhiteSpace()
autocmd FilterWritePre * call TrimWhiteSpace()
autocmd BufWritePre * call TrimWhiteSpace()

So mache ich es. Ich kann mich nicht erinnern, wo ich es von tbh gestohlen habe.

autocmd BufWritePre * :call <SID>StripWhite()
fun! <SID>StripWhite()
    %s/[ \t]\+$//ge
    %s!^\( \+\)\t!\=StrRepeat("\t", 1 + strlen(submatch(1)) / 8)!ge
endfun

Eine Lösung, bei der nachfolgende Leerzeichen einfach aus der Datei entfernt werden, ist nicht unter allen Umständen akzeptabel. Es funktioniert in einem Projekt, in dem diese Richtlinie von Anfang an angewendet wurde. Daher gibt es keine solchen Leerzeichen, die Sie nicht einfach selbst in Ihr bevorstehendes Commit aufgenommen haben.

Angenommen, Sie möchten lediglich keine neuen Instanzen von nachgestellten Leerzeichen hinzufügen, ohne vorhandene Leerzeichen in Zeilen zu beeinflussen, die Sie nicht bearbeitet haben, um Ihr Commit frei von Änderungen zu halten, die für Ihre Arbeit irrelevant sind.

In diesem Fall können Sie mit git ein Skript wie das folgende verwenden:

#!/bin/sh

set -e # bail on errors

git stash save commit-cleanup
git stash show -p | sed '/^\+/s/ *$//' | git apply
git stash drop

Das heißt, wir speichern die Änderungen und filtern dann alle +Zeilen im Diff, um deren nachfolgendes Leerzeichen zu entfernen, wenn wir die Änderung erneut auf das Arbeitsverzeichnis anwenden. Wenn diese Befehlspipe erfolgreich ist, löschen wir den Stash.

Die anderen Ansätze hier funktionierten in MacVim irgendwie nicht, wenn sie in der .vimrcDatei verwendet wurden. Hier ist eine, die nachfolgende Leerzeichen hervorhebt:

set encoding=utf-8
set listchars=trail:·
set list

autocmd BufWritePre * :%s/\s\+$//<CR>:let @/=''<CR>

Für Benutzer, die es für bestimmte Dateitypen ausführen möchten (FileTypes sind nicht immer zuverlässig):

autocmd BufWritePre *.c,*.cpp,*.cc,*.h,*.hpp,*.py,*.m,*.mm :%s/\s\+$//e

Oder mit vim7:

autocmd BufWritePre *.{c,cpp,cc,h,hpp,py,m,mm} :%s/\s\+$//e

Wenn Sie Leerzeichen kürzen, sollten Sie dies nur für Dateien tun, die bereits sauber sind. "Wenn du in Rom bist...". Dies ist eine gute Etikette bei der Arbeit an Codebasen, bei denen falsche Änderungen nicht erwünscht sind.

Diese Funktion erkennt nachgestellte Leerzeichen und aktiviert das Trimmen nur, wenn es bereits sauber war.

Der Verdienst für diese Idee geht an ein Juwel eines Kommentars hier: https://github.com/atom/whitespace/issues/10 (längster Bug-Ticket-Kommentar-Stream aller Zeiten)

autocmd BufNewFile,BufRead *.test call KarlDetectWhitespace()

fun! KarlDetectWhitespace()
python << endpython
import vim
nr_unclean = 0
for line in vim.current.buffer:
    if line.rstrip() != line:
        nr_unclean += 1

print "Unclean Lines: %d" % nr_unclean
print "Name: %s" % vim.current.buffer.name
cmd = "autocmd BufWritePre <buffer> call KarlStripTrailingWhitespace()"
if nr_unclean == 0:
    print "Enabling Whitespace Trimming on Save"
    vim.command(cmd)
else:
    print "Whitespace Trimming Disabled"
endpython
endfun

fun! KarlStripTrailingWhitespace()
    let l = line(".")
    let c = col(".")
    %s/\s\+$//e
    call cursor(l, c)
endfun