Wie kann ich eine umgekehrte Zeichenfolgensuche in Excel durchführen, ohne VBA zu verwenden?

Ich habe eine Excel-Tabelle mit einer Liste von Zeichenfolgen. Jede Zeichenfolge besteht aus mehreren Wörtern, aber die Anzahl der Wörter in jeder Zeichenfolge ist unterschiedlich.

Gibt es eine Möglichkeit, mithilfe der integrierten Excel-Funktionen (kein VBA) das letzte Wort in jeder Zeichenfolge zu isolieren?

Beispiele:

  Bist du als Mensch eingestuft? -> Mensch?
Negativ, ich bin ein Fleisch Eis am Stiel -> Eis am Stiel
                  Aziz! Licht! -> Licht!

Dieser ist getestet und funktioniert (basierend auf Brads ursprünglichem Beitrag):

=RIGHT(A1,LEN(A1)-FIND("|",SUBSTITUTE(A1," ","|",
     LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

Wenn Ihre ursprünglichen Zeichenfolgen eine Pipe enthalten könnten "|" Zeichen, dann ersetzen Sie beide oben durch ein anderes Zeichen, das nicht in Ihrer Quelle erscheint. (Ich vermute, Brads Original war kaputt, weil ein nicht druckbares Zeichen in der Übersetzung entfernt wurde).

Bonus: Wie es funktioniert (von rechts nach links):

LEN(A1)-LEN(SUBSTITUTE(A1," ",""))- Anzahl der Leerzeichen in der ursprünglichen Zeichenfolge
SUBSTITUTE(A1," ","|", ... )- Ersetzt nur das letzte Leerzeichen durch a |
FIND("|", ... )- Ermittelt die absolute Position des ersetzten |(das war das letzte Leerzeichen)
Right(A1,LEN(A1) - ... ))- Gibt danach alle Zeichen zurück|

BEARBEITEN: Um den Fall zu berücksichtigen, in dem der Quelltext keine Leerzeichen enthält, fügen Sie am Anfang der Formel Folgendes hinzu:

=IF(ISERROR(FIND(" ",A1)),A1, ... )

Jetzt die gesamte Formel erstellen:

=IF(ISERROR(FIND(" ",A1)),A1, RIGHT(A1,LEN(A1) - FIND("|",
    SUBSTITUTE(A1," ","|",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))))

Oder Sie können die =IF(COUNTIF(A1,"* *")Syntax der anderen Version verwenden.

Wenn die ursprüngliche Zeichenfolge möglicherweise ein Leerzeichen an der letzten Position enthält, fügen Sie eine Trimmfunktion hinzu, während Sie alle Leerzeichen zählen: Machen Sie die Funktion wie folgt:

=IF(ISERROR(FIND(" ",B2)),B2, RIGHT(B2,LEN(B2) - FIND("|",
    SUBSTITUTE(B2," ","|",LEN(TRIM(B2))-LEN(SUBSTITUTE(B2," ",""))))))

Dies ist die Technik, die ich mit großem Erfolg angewendet habe:

=TRIM(RIGHT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Um das erste Wort in einer Zeichenfolge zu erhalten, wechseln Sie einfach von RECHTS nach LINKS

=TRIM(LEFT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Ersetzen Sie außerdem A1 durch die Zelle, in der sich der Text befindet.

Eine robustere Version von Jerrys Antwort:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))

Das funktioniert unabhängig von der Länge der Zeichenfolge, den führenden oder nachfolgenden Leerzeichen oder was auch immer und es ist immer noch ziemlich kurz und einfach.

Ich habe dies bei Google gefunden, in Excel 2003 getestet und es funktioniert für mich:

=IF(COUNTIF(A1,"* *"),RIGHT(A1,LEN(A1)-LOOKUP(LEN(A1),FIND(" ",A1,ROW(INDEX($A:$A,1,1):INDEX($A:$A,LEN(A1),1))))),A1)

[Bearbeiten] Ich habe nicht genug Wiederholungen, um Kommentare abzugeben, daher scheint dies der beste Ort zu sein ... BradCs Antwort funktioniert auch nicht mit nachgestellten Leerzeichen oder leeren Zellen ...
[2. Bearbeiten] funktioniert tatsächlich nicht einzelne Wörter entweder ...

=RIGHT(TRIM(A1),LEN(TRIM(A1))-FIND(CHAR(7),SUBSTITUTE(" "&TRIM(A1)," ",CHAR(7),
LEN(TRIM(A1))-LEN(SUBSTITUTE(" "&TRIM(A1)," ",""))+1))+1)

Dies ist sehr robust - es funktioniert für Sätze ohne Leerzeichen, führende / nachfolgende Leerzeichen, mehrere Leerzeichen, mehrere führende / nachfolgende Leerzeichen ... und ich habe char (7) für das Trennzeichen anstelle des vertikalen Balkens "|" verwendet. Nur für den Fall, dass dies ein gewünschtes Textelement ist.

Dies ist sehr sauber und kompakt und funktioniert gut.

{=RIGHT(A1,LEN(A1)-MAX(IF(MID(A1,ROW(1:999),1)=" ",ROW(1:999),0)))}

Es gibt keine Fehlerfalle für keine Leerzeichen oder ein Wort, aber das ist einfach hinzuzufügen.

Bearbeiten:
Hiermit werden Leerzeichen, Szenarien mit einzelnen Wörtern und leere Zellen behandelt. Ich habe keinen Weg gefunden, es zu brechen.

{=RIGHT(TRIM(A1),LEN(TRIM(A1))-MAX(IF(MID(TRIM(A1),ROW($1:$999),1)=" ",ROW($1:$999),0)))}

=RIGHT(A1,LEN(A1)-FIND("`*`",SUBSTITUTE(A1," ","`*`",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))) 

Um die Antworten von Jerry und Joe zu ergänzen, wenn Sie den Text VOR dem letzten Wort suchen möchten, das Sie verwenden können:

=TRIM(LEFT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))))-LEN(TRIM(A1))))

Mit 'Meine kleine Katze' in A1 würde sich 'Meine kleine' ergeben (wo Joe und Jerry 'Katze' geben würden)

Auf die gleiche Weise, wie Jerry und Joe das letzte Wort isolieren, wird nur alles links davon angezeigt (und dann zurückgeschnitten).

Stellen Sie sich vor, die Zeichenfolge könnte umgekehrt werden. Dann ist es ganz einfach. Anstatt an der Zeichenfolge zu arbeiten:

"My little cat" (1)

du arbeitest mit

"tac elttil yM" (2)

Mit =LEFT(A1;FIND(" ";A1)-1)in A2 erhalten Sie "My"mit (1) und "tac"mit (2), was umgekehrt ist "cat", das letzte Wort in (1).

Es gibt einige VBAs, um eine Zeichenfolge umzukehren. Ich bevorzuge die öffentliche VBA-Funktion ReverseString.

Installieren Sie das oben beschriebene wie beschrieben. Dann mit Ihrer Zeichenfolge in A1, z. B. "My little cat"und dieser Funktion in A2:

=ReverseString(LEFT(ReverseString(A1);IF(ISERROR(FIND(" ";A1));
  LEN(A1);(FIND(" ";ReverseString(A1))-1))))

Sie werden "cat"in A2 sehen.

Bei der obigen Methode wird davon ausgegangen, dass Wörter durch Leerzeichen getrennt sind. Die IFKlausel gilt für Zellen, die einzelne Wörter enthalten = keine Leerzeichen in der Zelle. Hinweis: TRIMund CLEANdie Originalzeichenfolge sind ebenfalls nützlich. Im Prinzip kehrt es die gesamte Zeichenfolge von A1 um und findet einfach das erste Leerzeichen in der umgekehrten Zeichenfolge, das neben dem letzten (umgekehrten) Wort (dh "tac ") steht. LEFTwählt dieses Wort aus und eine andere Zeichenfolgenumkehr stellt die ursprüngliche Reihenfolge des Wortes ( " cat") wieder her. Das -1am Ende der FINDAnweisung entfernte Leerzeichen.

Die Idee ist , dass es einfach ist, das erste (!) Wort in einer Zeichenfolge zu extrahieren mit LEFTund FINDing den ersten Rohling. Für das letzte (!) Wort ist die RIGHTFunktion jedoch die falsche Wahl, wenn Sie dies versuchen, da FIND leider kein Flag für die Richtung hat, in die Sie Ihren String analysieren möchten.

Daher wird die gesamte Zeichenfolge einfach umgekehrt. LEFTund FINDarbeiten wie gewohnt, aber die extrahierte Zeichenfolge ist umgekehrt. Aber es ist keine große Sache, wenn Sie erst einmal wissen, wie man eine Saite umkehrt. Die erste ReverseStringAnweisung in der Formel erledigt diesen Job.

=LEFT(A1,FIND(IF(
 ISERROR(
  FIND("_",A1)
 ),A1,RIGHT(A1,
  LEN(A1)-FIND("~",
   SUBSTITUTE(A1,"_","~",
    LEN(A1)-LEN(SUBSTITUTE(A1,"_",""))
   )
  )
 )
),A1,1)-2)

In eine Spalte kopieren, diese Spalte auswählen und HOME> Bearbeiten> Suchen & Auswählen, Ersetzen:

Replace All.

Nach dem Sternchen steht ein Leerzeichen.

Ich habe nach PT-BR übersetzt, da ich das auch brauchte.

(Bitte beachten Sie, dass ich das Leerzeichen in geändert habe, \da ich nur den Dateinamen der Pfadzeichenfolgen benötigte.)

=SE(ÉERRO(PROCURAR("\",A1)),A1,DIREITA(A1,NÚM.CARACT(A1)-PROCURAR("|", SUBSTITUIR(A1,"\","|",NÚM.CARACT(A1)-NÚM.CARACT(SUBSTITUIR(A1,"\",""))))))

Ein anderer Weg, um dies zu erreichen, ist wie folgt

=IF(ISERROR(TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14))))),TRIM(D14),TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14)))))

Ich hatte auch eine Aufgabe wie diese und als ich mit der obigen Methode fertig war, kam mir eine neue Methode in den Sinn: Warum machst du das nicht:

1. Kehren Sie die Zeichenfolge um ("Zeichenfolge eins" wird zu "eno gnirts").
2. Verwenden Sie den guten alten Find (der von links nach rechts fest codiert ist).
3. Kehren Sie es wieder in eine lesbare Zeichenfolge um.

Wie klingt das?