Google SpreadSheet Query: Kann ich die Spaltenüberschrift entfernen?

98

Ich mache diese Abfrage in meiner Google-Tabelle:

=QUERY(H4:L35;"select sum(L) where H='First Week'"; -1)

Es wird jedoch eine kleine Tabelle mit "sum" als Header und Ergebnis darunter zurückgegeben. Was ich will, ist nur das Ergebnis! Wie entferne ich den Header? Kann ich?

— Poliane Brito
quelle

Dies scheint einfacher zu sein: stackoverflow.com/a/41797729/5316231

— user19581

186

Versuche dies:

=QUERY(H4:L35,"select sum(L) where H='First Week' label sum(L) ''")

Hoffentlich hilft das!

— KRR
quelle

3

Ich habe dies gerade in einem meiner Blätter getestet und es entfernt den Header aus den zurückgegebenen Ergebnissen. Dies sollte als die richtige Antwort markiert werden. :)

— FooBar

1

Das ist großartig und funktioniert, aber kann jemand erklären, warum die beiden einfachen Anführungszeichen am Ende benötigt werden? Was macht das aus Syntaxperspektive?

— y-i_guy

2

Das einfache Anführungszeichen ersetzt den Summenkopf durch Leerzeichen. Hoffe das erklärt deine Frage !!

— KRR

2

Danke für die Antwort! Ich muss dasselbe mit mehr als einer Spalte tun, aber ich kann es nicht erreichen! Ich habe erwartet, dass dies funktioniert: = QUERY (H4: L35, "wähle Summe (L), Summe (H), wobei H = 'Erste Woche' Etikettensumme (L) '' Etikettensumme (H) ''")

— Emilio Nicolás

11

LABEL B 'Label1', C 'Label2'für mehrere Spalten

— sojim2

30

=QUERY(QUERY(A1:D, "SELECT *", 1), "SELECT * OFFSET 1", 0)

Die äußere Abfrage: "SELECT * OFFSET 1"schließt die erste Zeile (den Header) aus.

Die innere Abfrage gibt explizit eine Zeile von Headern an (über das dritte Argument, an das übergeben wird QUERY), während die äußere Abfrage keine angibt.

— user280150
quelle

3

Ein bisschen Erklärung?

— J Fabian Meier

Warum ist die zweite QUERYnotwendig? Löscht der Parameter "0" nicht die Überschriften, so dass Sie ihn beim ersten Mal QUERYwie folgt verwenden können: QUERY('Form responses 3'!$A$2:$P$1017, "SELECT max(E),max(C), max(D) WHERE B='" & B14 & "' GROUP BY B LIMIT 1 ", 0)

— Steven M. Mortimer

3

Ich glaube, dass OFFSET 1bei der zweiten Abfrage die allererste Zeile des zurückgegebenen Datensatzes gelöscht wird, nicht die Überschriften in der ersten Zeile.

— Steven M. Mortimer

2

Diese Antwort ist möglicherweise ausführlicher, aber auch robuster und kann verwendet werden, ohne dass Spaltenaggregationszeichenfolgen dupliziert werden müssen. Es kann sogar mit verwendet werden pivot, was hier mit keiner anderen Antwort funktioniert.

— 7yl4r

1

Sofern ich mich nicht irre, löst dies nicht die spezifische Herausforderung, die das Originalposter bietet, dh das Entfernen der Header, die von QUERY automatisch generiert werden, wenn Aggregationsfunktionen wie SUM verwendet werden. Bei Verwendung von SUM (oder einer anderen Aggregationsfunktion) erstellt QUERY automatisch eine Kopfzeile, in der die durchgeführte Aggregation angegeben ist, z. B. "sum". Dies ist auch dann der Fall, wenn Sie Header auf 0 setzen und die OFFSET 1-Klausel anwenden. Die folgende Formel gibt weiterhin Header zurück. = QUERY (Sheet1! A: B, "SELECT A, SUM (B) GROUP BY A OFFSET 1", 0) Die akzeptierte Antwort löst diese Herausforderung.

— Dave Meindl

0

Ich habe eine Abfrage, die die Top 3 zurückgibt. Ich konnte dies nicht zum Laufen bringen, wenn ich mehrere Zeilen zurückgab. Am Ende habe ich nur die Zeile mit der Formel versteckt und nur die Antworten werden jetzt angezeigt.

— Brian Wochele
quelle

0

=INDEX(QUERY(H4:L35;"select sum(L) where H='First Week'"; -1),2,1)

Dadurch wird nur das zurückgegebene Array analysiert und der zweite in der ersten Spalte zurückgegebene Datensatz ausgewählt.

Sie können dies auch mit der Filterfunktion tun, die weniger rechenintensiv ist.

=SUM(FILTER(L4:L35, H4:H35 = "First Week"))

— Dean Falconer
quelle

-3

Das Format finden Sie hier .

Beispiel:

=QUERY(B4:C38,
   "SELECT C, sum(B) where C!='' group by C label C 'Member', sum(B) 'Sum'"
)

— Andy
quelle

2

Das bereitgestellte Beispiel gibt kein Ergebnis ohne Header zurück.

— Rubén