Lassen Sie beim Kopieren aus der Zelle Anführungszeichen weg

Problem :
Beim Kopieren einer Zelle aus Excel außerhalb des Programms werden doppelte Anführungszeichen automatisch hinzugefügt.

Details :
Ich verwende Excel 2007 auf einem Windows 7-Computer. Wenn ich eine Zelle mit der folgenden Formel habe:

="1"&CHAR(9)&"SOME NOTES FOR LINE 1."&CHAR(9)&"2"&CHAR(9)&"SOME NOTES FOR LINE 2."

Die Ausgabe in der Zelle (als Zahl formatiert) sieht in Excel folgendermaßen aus:

1SOME NOTES FOR LINE 1.2SOME NOTES FOR LINE 2.

Schön und gut. Wenn ich die Zelle jedoch in ein anderes Programm wie den Editor kopiere, werden am Anfang und am Ende nervige doppelte Anführungszeichen angezeigt. Beachten Sie, dass die von "CHAR (9)" erstellten Registerkarten beibehalten werden, was gut ist.

"1  SOME NOTES FOR LINE 1.  2     SOME NOTES FOR LINE 2."

Wie kann ich verhindern, dass diese doppelten Anführungszeichen angezeigt werden, wenn ich in ein anderes Programm kopiere? Mit anderen Worten, kann ich verhindern, dass diese automatisch hinzugefügt werden, wenn die Zelle in die Zwischenablage kopiert wird?

Wenn Sie versuchen, in Word-Pad, Notepad ++ oder Word einzufügen, tritt dieses Problem nicht auf. Um den Zellenwert als reinen Text zu kopieren und das zu erreichen, was Sie beschreiben, müssen Sie ein Makro verwenden:

Fügen Sie in der Arbeitsmappe, in der dies angewendet werden soll (oder in Ihrer Personal.xls, wenn Sie mehrere Arbeitsmappen verwenden möchten) den folgenden Code in ein Standardmodul ein:

Code:

Sub CopyCellContents()
'create a reference in the VBE to Microsft Forms 2.0 Lib
' do this by (in VBA editor) clicking tools - > references and then ticking "Microsoft Forms 2.0 Library"
Dim objData As New DataObject
Dim strTemp As String
strTemp = ActiveCell.Value
objData.SetText (strTemp)
objData.PutInClipboard
End Sub

Um Ihrem Projekt (Arbeitsmappe) ein Standardmodul hinzuzufügen, öffnen Sie die VBE mit Alt+, F11klicken Sie mit der rechten Maustaste auf Ihre Arbeitsmappe im oberen linken Projektfenster und wählen Sie Einfügen> Modul. Fügen Sie den Code in das Fenster des Codemoduls ein, das rechts geöffnet wird.

Gehen Sie in Excel zu Extras> Makro> Makros, wählen Sie das Makro "CopyCellContents" aus und wählen Sie dann im Dialogfeld "Optionen". Hier können Sie das Makro einer Tastenkombination zuweisen (zB wie CTRL+ Cfür normale Kopie) - ich habe CTRL+ verwendet Q.

Wenn Sie dann eine einzelne Zelle in Notepad / wo auch immer kopieren möchten, drücken Sie einfach Strg + q (oder was auch immer Sie ausgewählt haben) und dann ein CTRL+ Voder Bearbeiten> Einfügen in das von Ihnen gewählte Ziel.

Meine Antwort wird (mit ein paar Ergänzungen) von hier kopiert

EDIT : (aus Kommentaren)

Wenn Sie die Microsoft Forms 2.0-Bibliothek nicht in der Referenzliste finden, können Sie es versuchen

• stattdessen nach FM20.DLL suchen (danke @Peter Smallwood)
• Klicken Sie auf Durchsuchen und wählen Sie C:\Windows\System32\FM20.dll(32-Bit-Windows) (danke @JWhy)
• Klicken Sie auf Durchsuchen und wählen Sie C:\Windows\SysWOW64\FM20.dll (auf 64-Bit)

Ich hatte gerade dieses Problem und das Umschließen jeder Zelle mit der CLEANFunktion hat es für mich behoben. =CLEAN(Dies sollte relativ einfach sein , indem Sie Ihre Zelle auswählen und dann den Rest der Spalte automatisch ausfüllen. Nachdem ich dies getan hatte, hatten Einfügungen in Notepad oder ein anderes Programm keine doppelten Anführungszeichen mehr.

Fügen Sie es zuerst in Word ein, dann können Sie es in den Editor einfügen, und es wird ohne Anführungszeichen angezeigt

Wenn Sie mehrere Zellen auswählen und deren Werte ohne all diese lästigen Anführungszeichen in die Zwischenablage kopieren möchten, kann der folgende Code hilfreich sein. Dies ist eine Erweiterung des oben angegebenen Codes von user3616725.

Sub CopyCells()
 'Attach Microsoft Forms 2.0 Library: tools\references\Browse\FM20.DLL
 'Then set a keyboard shortcut to the CopyCells Macro (eg Crtl T)
 Dim objData As New DataObject
 Dim cell As Object
 Dim concat As String
 Dim cellValue As String
 CR = ""
  For Each cell In Selection
  If IsNumeric(cell.Value) Then
   cellValue = LTrim(Str(cell.Value))
  Else
   cellValue = cell.Value
  End If
  concat = concat + CR + cellValue
  CR = Chr(13)
 Next
 objData.SetText (concat)
 objData.PutInClipboard
End Sub

Meine Lösung, als ich auf das Anführungszeichenproblem stieß, bestand darin, Wagenrückläufe vom Ende des Textes meiner Zellen zu entfernen. Aufgrund dieser Wagenrückläufe (von einem externen Programm eingefügt) fügte Excel der gesamten Zeichenfolge Anführungszeichen hinzu.

Mögliches Problem in Bezug auf die Antwort von "user3616725": Ich bin
unter Windows 8.1 und es scheint ein Problem mit dem verknüpften VBA-Code von der akzeptierten Antwort von "user3616725" zu geben:

Sub CopyCellContents()
 ' !!! IMPORTANT !!!:
 ' CREATE A REFERENCE IN THE VBE TO "Microsft Forms 2.0 Library" OR "Microsft Forms 2.0 Object Library"
 ' DO THIS BY (IN VBA EDITOR) CLICKING TOOLS -> REFERENCES & THEN TICKING "Microsoft Forms 2.0 Library" OR "Microsft Forms 2.0 Object Library"
 Dim objData As New DataObject
 Dim strTemp As String
 strTemp = ActiveCell.Value
 objData.SetText (strTemp)
 objData.PutInClipboard
End Sub

Details:
Wenn Sie den obigen Code ausführen und die Zwischenablage in eine Zelle in Excel einfügen, werden zwei Symbole angezeigt, die aus Quadraten mit einem Fragezeichen bestehen: ⍰⍰. Das Einfügen in Notepad zeigt nicht einmal etwas an.

Lösung:
Nachdem ich einige Zeit gesucht hatte, fand ich ein anderes VBA-Skript vom Benutzer "Nepumuk", das die Windows-API verwendet . Hier ist sein Code, der endlich für mich funktioniert hat:

Option Explicit

Private Declare Function OpenClipboard Lib "user32.dll" ( _
    ByVal hwnd As Long) As Long
Private Declare Function CloseClipboard Lib "user32.dll" () As Long
Private Declare Function EmptyClipboard Lib "user32.dll" () As Long
Private Declare Function SetClipboardData Lib "user32.dll" ( _
    ByVal wFormat As Long, _
    ByVal hMem As Long) As Long
Private Declare Function GlobalAlloc Lib "kernel32.dll" ( _
    ByVal wFlags As Long, _
    ByVal dwBytes As Long) As Long
Private Declare Function GlobalLock Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function GlobalFree Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function lstrcpy Lib "kernel32.dll" ( _
    ByVal lpStr1 As Any, _
    ByVal lpStr2 As Any) As Long

Private Const CF_TEXT As Long = 1&

Private Const GMEM_MOVEABLE As Long = 2

Public Sub Beispiel()
    Call StringToClipboard("Hallo ...")
End Sub

Private Sub StringToClipboard(strText As String)
    Dim lngIdentifier As Long, lngPointer As Long
    lngIdentifier = GlobalAlloc(GMEM_MOVEABLE, Len(strText) + 1)
    lngPointer = GlobalLock(lngIdentifier)
    Call lstrcpy(ByVal lngPointer, strText)
    Call GlobalUnlock(lngIdentifier)
    Call OpenClipboard(0&)
    Call EmptyClipboard
    Call SetClipboardData(CF_TEXT, lngIdentifier)
    Call CloseClipboard
    Call GlobalFree(lngIdentifier)
End Sub

Um es wie den ersten VBA-Code von oben zu verwenden, ändern Sie das Sub "Beispiel ()" von:

Public Sub Beispiel()
    Call StringToClipboard("Hallo ...")
End Sub

Zu:

Sub CopyCellContents()
    Call StringToClipboard(ActiveCell.Value)
End Sub

Und führen Sie es über das Excel-Makro-Menü aus, wie von "user3616725" aus der akzeptierten Antwort vorgeschlagen:

Gehen Sie in Excel zu Extras> Makro> Makros, wählen Sie das Makro "CopyCellContents" aus und wählen Sie dann im Dialogfeld "Optionen". Hier können Sie das Makro einer Tastenkombination zuweisen (z. B. Strg + C für normales Kopieren) - ich habe Strg + q verwendet.

Wenn Sie dann eine einzelne Zelle in den Editor kopieren möchten, drücken Sie einfach Strg + q (oder was auch immer Sie ausgewählt haben) und dann Strg + v oder Bearbeiten> Einfügen in das von Ihnen gewählte Ziel.

Edit (21. November 2015):
@ Kommentar von "dotctor":
Nein, das ist ernsthaft keine neue Frage! Meiner Meinung nach ist dies eine gute Ergänzung für die akzeptierte Antwort, da meine Antwort Probleme behebt, die auftreten können, wenn Sie den Code aus der akzeptierten Antwort verwenden. Wenn ich mehr Ruf hätte, hätte ich einen Kommentar erstellt.
@ Kommentar von "Teepeemm":
Ja, Sie haben Recht, Antworten, die mit dem Titel "Problem:" beginnen, sind irreführend. Geändert zu: "Mögliches Problem in Bezug auf die Antwort von" user3616725 ":". Als Kommentar hätte ich sicherlich viel kompakter geschrieben.

"Wenn Sie mehrere Zellen auswählen und ihre Werte ohne all diese lästigen Anführungszeichen in die Zwischenablage kopieren möchten " ( ohne die Fehler in Peter Smallwoods Multi-Cells-Lösung) ", kann der folgende Code nützlich sein." Dies ist eine Erweiterung des oben angegebenen Codes von Peter Smallwood (was "eine Erweiterung des oben angegebenen Codes von user3616725" ist). Dies behebt die folgenden Fehler in der Lösung von Peter Smallwood:

• Vermeidet den Compilerfehler "Variable nicht definiert" (für "CR" - "clibboardFieldDelimiter" hier)
• Konvertieren Sie eine leere Zelle in eine leere Zeichenfolge gegen "0".
• Fügen Sie nach jeder Zelle die Registerkarte (ASCII 9) gegen CR (ASCII 13) hinzu.
• Fügen Sie nach jeder Zeile ein CR (ASCII 13) + LF (ASCII 10) (vs. CR (ASCII 13)) hinzu.

HINWEIS: Sie können immer noch keine in eine Zelle eingebetteten Zeichen kopieren, die zu einem Verlassen des Zielfelds führen würden, in das Sie diese Zelle einfügen (dh Tab oder CR beim Einfügen in das Fenster "Tabelle bearbeiten" von Access oder SSMS).

Option Explicit

Sub CopyCellsWithoutAddingQuotes()

' -- Attach Microsoft Forms 2.0 Library: tools\references\Browse\FM20.DLL
' -- NOTE: You may have to temporarily insert a UserForm into your VBAProject for it to show up.
' -- Then set a Keyboard Shortcut to the "CopyCellsWithoutAddingQuotes" Macro (i.e. Crtl+E)

Dim clibboardFieldDelimiter As String
Dim clibboardLineDelimiter As String
Dim row As Range
Dim cell As Range
Dim cellValueText As String
Dim clipboardText As String
Dim isFirstRow As Boolean
Dim isFirstCellOfRow As Boolean
Dim dataObj As New dataObject

clibboardFieldDelimiter = Chr(9)
clibboardLineDelimiter = Chr(13) + Chr(10)
isFirstRow = True
isFirstCellOfRow = True

For Each row In Selection.Rows

    If Not isFirstRow Then
        clipboardText = clipboardText + clibboardLineDelimiter
    End If

    For Each cell In row.Cells

        If IsEmpty(cell.Value) Then

            cellValueText = ""

        ElseIf IsNumeric(cell.Value) Then

            cellValueText = LTrim(Str(cell.Value))

        Else

            cellValueText = cell.Value

        End If ' -- Else Non-empty Non-numeric

        If isFirstCellOfRow Then

            clipboardText = clipboardText + cellValueText
            isFirstCellOfRow = False

        Else ' -- Not (isFirstCellOfRow)

            clipboardText = clipboardText + clibboardFieldDelimiter + cellValueText

        End If ' -- Else Not (isFirstCellOfRow)

    Next cell

    isFirstRow = False
    isFirstCellOfRow = True

Next row

clipboardText = clipboardText + clibboardLineDelimiter

dataObj.SetText (clipboardText)
dataObj.PutInClipboard

End Sub

Ersetzen Sie diese Zeile im Makro, um Zeilenumbrüche beim Einfügen in den Editor beizubehalten:

strTemp = ActiveCell.Value

durch:

strTemp = Replace(ActiveCell.Value, Chr(10), vbCrLf)

Bitte verwenden Sie die folgende Formel

=Clean("1"&CHAR(9)&"SOME NOTES FOR LINE 1."&CHAR(9)&"2"&CHAR(9)&"SOME NOTES FOR LINE 2.")

und du wirst bekommen was du willst ;-)

Sie können dies in einem Excel-Makro über VBA tun und die Ergebnisse an eine Datei senden:

Sub SimpleVBAWriteToFileWithoutQuotes()
    Open "c:\TEMP\Excel\out.txt" For Output As #1
    Print #1, Application.ActiveSheet.Cells(2, 3)
    Close #1
End Sub

Wenn Sie Dateinamen und Inhalte in mehrere Dateien übertragen möchten, finden Sie hier einen kurzen Ausschnitt, mit dem doppelte Anführungszeichen um die Ausgabe vermieden werden.

Sub DumpCellDataToTextFilesWithoutDoubleQuotes()
    ' this will work for filename and content in two different columns such as:
    ' filename column       data column
    ' 101                   this is some data
    ' 102                   this is more data

    Dim rngData As Range
    Dim strData As String
    Dim strTempFile As String
    Dim strFilename As String
    Dim i As Long
    Dim intFilenameColumn As Integer
    Dim intDataColumn As Integer
    Dim intStartingRow As Integer

    intFilenameColumn = 1     ' the column number containing the filenames
    intDataColumn = 3         ' the column number containing the data
    intStartingRow = 2        ' the row number to start gathering data


    For i = intStartingRow To Range("A1", Range("A1").End(xlDown)).Rows.Count

        ' copy the data cell's value
        Set rngData = Application.ActiveSheet.Cells(i, intDataColumn)

        ' get the base filename
        strFilename = Application.ActiveSheet.Cells(i, intFilenameColumn)

        ' assemble full filename and path
        strTempFile = "w:\TEMP\Excel\" & strFilename & ".txt"

        ' write to temp file
        Open strTempFile For Output As #1
        Print #1, rngData
        Close #1

    Next i

    ' goto home cell
    Application.ActiveSheet.Cells(1, 1).Select
    Range("A1").ClearOutline
End Sub

• Wenn eine Formel mehrzeilig ist (dh einen Zeilenumbruch in der Formel hat), funktioniert das Kopieren und Einfügen auf diese Weise
• Wenn mehrzeilige Zeilen entfernt werden können, werden beim Kopieren und Einfügen keine Anführungszeichen angezeigt.
• Andernfalls verwenden Sie die CLEAN- Funktion, wie von @greg in der vorherigen Antwort angegeben

Hinweis: Die Ursache für die Anführungszeichen ist, dass Daten, wenn sie von Excel in die Zwischenablage verschoben werden, vollständig den CSV-Standards entsprechen, die Anführungszeichen enthalten, die Tabulatoren, neue Zeilen usw. enthalten (und doppelte Anführungszeichen durch zwei doppelte Anführungszeichen ersetzt werden).

Ein anderer Ansatz, insbesondere wie im Fall von OP, wenn Tabulatoren / neue Zeilen auf die Formel zurückzuführen sind, besteht darin, alternative Zeichen für Tabulatoren und harte Rückgaben zu verwenden. Ich verwende ascii Unit Separator = char (31) für Registerkarten und ascii Record Separator = char (30) für neue Zeilen.

Das Einfügen in den Texteditor beinhaltet dann keine zusätzlichen CSV-Regeln, und Sie können schnell suchen und ersetzen, um sie wieder zurück zu konvertieren.

Wenn die Registerkarten / neuen Zeilen in die Daten eingebettet sind, können Sie sie in Excel suchen und ersetzen, um sie zu konvertieren.

Unabhängig davon, ob Sie eine Formel verwenden oder die Daten ändern, besteht der Schlüssel zur Auswahl von Trennzeichen darin, niemals Zeichen zu verwenden, die in den tatsächlichen Daten enthalten sein können. Aus diesem Grund empfehle ich die niedrigen ASCII-Zeichen.

Sie können diese doppelten Anführungszeichen auch entfernen, indem Sie Ihr Ergebnis auf die Funktion "Bereinigen" setzen.

Beispiel:

=CLEAN("1"&CHAR(9)&"SOME NOTES FOR LINE 1."&CHAR(9)&"2"&CHAR(9)&"SOME NOTES FOR LINE 2.")

Die Ausgabe wird ohne doppelte Anführungszeichen in andere Programme wie Notepad ++ eingefügt.