Wie führe ich eine Perl-Ersetzung für eine Zeichenfolge durch, während das Original beibehalten wird?

Was ist in Perl eine gute Möglichkeit, eine Ersetzung für eine Zeichenfolge mithilfe eines regulären Ausdrucks durchzuführen und den Wert in einer anderen Variablen zu speichern, ohne das Original zu ändern?

Normalerweise kopiere ich die Zeichenfolge einfach in eine neue Variable und binde sie dann an den s///regulären Ausdruck, der die neue Zeichenfolge ersetzt. Ich habe mich jedoch gefragt, ob es einen besseren Weg gibt, dies zu tun.

$newstring = $oldstring;
$newstring =~ s/foo/bar/g;

Dies ist die Redewendung, mit der ich immer eine modifizierte Kopie eines Strings erhalten habe, ohne das Original zu ändern:

(my $newstring = $oldstring) =~ s/foo/bar/g;

In Perl 5.14.0 oder höher können Sie den neuen /r zerstörungsfreien Substitutionsmodifikator verwenden :

my $newstring = $oldstring =~ s/foo/bar/gr; 

Hinweis: Die oben genannten Lösungen funktionieren auch ohne g. Sie funktionieren auch mit anderen Modifikatoren.

Die Aussage:

(my $newstring = $oldstring) =~ s/foo/bar/g;

Welches ist gleichbedeutend mit:

my $newstring = $oldstring;
$newstring =~ s/foo/bar/g;

Alternativ können Sie ab Perl 5.13.2 /reine zerstörungsfreie Substitution durchführen:

use 5.013;
#...
my $newstring = $oldstring =~ s/foo/bar/gr;

Unter use strictsagen wir:

(my $new = $original) =~ s/foo/bar/;

stattdessen.

Die Einzeilerlösung ist als Shibboleth nützlicher als guter Code. Gute Perl-Codierer werden es wissen und verstehen, aber es ist viel weniger transparent und lesbar als das zweizeilige Couplet zum Kopieren und Ändern, mit dem Sie beginnen.

Mit anderen Worten, ein guter Weg, dies zu tun, ist die Art und Weise, wie Sie es bereits tun. Unnötige Präzision auf Kosten der Lesbarkeit ist kein Gewinn.

Eine weitere Lösung vor 5.14 : http://www.perlmonks.org/?node_id=346719 (siehe Japhys Beitrag)

Wie sein Ansatz verwendet map, funktioniert es auch gut für Arrays, erfordert jedoch eine Kaskadierung map, um ein temporäres Array zu erzeugen (andernfalls würde das Original geändert):

my @orig = ('this', 'this sucks', 'what is this?');
my @list = map { s/this/that/; $_ } map { $_ } @orig;
# @orig unmodified

Ich hasse Foo und Bar. Wer hat sich diese unbeschreiblichen Begriffe in der Programmierung überhaupt ausgedacht?

my $oldstring = "replace donotreplace replace donotreplace replace donotreplace";

my $newstring = $oldstring;
$newstring =~ s/replace/newword/g; # inplace replacement

print $newstring;
%: newword donotreplace newword donotreplace newword donotreplace

Wenn Sie Perl mit schreiben use strict;, werden Sie feststellen, dass die einzeilige Syntax auch dann nicht gültig ist, wenn sie deklariert ist.

Mit:

my ($newstring = $oldstring) =~ s/foo/bar/;

Du erhältst:

Can't declare scalar assignment in "my" at script.pl line 7, near ") =~"
Execution of script.pl aborted due to compilation errors.

Stattdessen ist die Syntax, die Sie verwendet haben, eine Zeile länger, aber die syntaktisch korrekte Methode, um dies zu tun use strict;. Für mich ist das Verwenden use strict;jetzt nur noch eine Gewohnheit. Ich mache es automatisch. Jeder sollte.

#!/usr/bin/env perl -wT

use strict;

my $oldstring = "foo one foo two foo three";
my $newstring = $oldstring;
$newstring =~ s/foo/bar/g;

print "$oldstring","\n";
print "$newstring","\n";