UltiSnips und YouCompleteMe

Ich habe Bundles ultisnips und youcompleteme auf meinem Macvim installiert. Das Problem ist, dass ultisnips nicht funktioniert, da die Registerkarte durch ycm gebunden ist. Ich habe versucht zu setzen, let g:UltiSnipsExpandTrigger = "<s-tab>"damit ich die Snippet-Vervollständigung mit der Umschalttaste auslösen kann, aber es funktioniert aus einem unbekannten Grund nicht. Ich könnte Kappen als Auslöser verwenden, aber bisher habe ich keine Möglichkeit gefunden, dies zu tun.

Verwendet einer von Ihnen diese beiden Add-Ons zusammen? Was kann ich tun, damit die Umschalttaste funktioniert? Können Sie einen anderen Schlüssel zum Auslösen von Snippets empfehlen?

Eine weitere Option ist die Verwendung des SuperTab-Plugins:

" if you use Vundle, load plugins:
Bundle 'ervandew/supertab'
Bundle 'Valloric/YouCompleteMe'
Bundle 'SirVer/ultisnips'

" make YCM compatible with UltiSnips (using supertab)
let g:ycm_key_list_select_completion = ['<C-n>', '<Down>']
let g:ycm_key_list_previous_completion = ['<C-p>', '<Up>']
let g:SuperTabDefaultCompletionType = '<C-n>'

" better key bindings for UltiSnipsExpandTrigger
let g:UltiSnipsExpandTrigger = "<tab>"
let g:UltiSnipsJumpForwardTrigger = "<tab>"
let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"

Hier ist YouCompleteMe an eine andere Kombination gebunden Ctrln, aber dann ist diese Kombination über SuperTab an die Registerkarte gebunden. UltiSnips und SuperTab spielen gut zusammen, sodass Sie UltiSnips einfach direkt an die Registerkarte binden können und alles klappt.

Probieren Sie diesen Vorschlag auf einer Seite des YouCompleteMe-Issue-Trackers aus. In Ihrer .vimrc:

let g:UltiSnipsExpandTrigger="<c-j>"

Während diese Einstellung das Erweitern einer Snippet- Freigabe zur Standardzuordnung für das Vorwärtsspringen innerhalb eines Snippets macht , simuliert sie das Verhalten von TextMates, wie in den UltiSnips-Hilfetags erwähnt.

Da ich meine Feststelltaste der Strg-Taste zugeordnet habe, funktioniert diese Zuordnung ziemlich reibungslos.

Kopieren Sie den folgenden Code in Ihr vimrc und genießen Sie. Diese Funktion behandelt alle Probleme zwischen YCM und UltiSnips.

function! g:UltiSnips_Complete()
    call UltiSnips#ExpandSnippet()
    if g:ulti_expand_res == 0
        if pumvisible()
            return "\<C-n>"
        else
            call UltiSnips#JumpForwards()
            if g:ulti_jump_forwards_res == 0
               return "\<TAB>"
            endif
        endif
    endif
    return ""
endfunction

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
let g:UltiSnipsJumpForwardTrigger="<tab>"
let g:UltiSnipsListSnippets="<c-e>"
" this mapping Enter key to <C-y> to chose the current highlight item 
" and close the selection list, same as other IDEs.
" CONFLICT with some plugins like tpope/Endwise
inoremap <expr> <CR> pumvisible() ? "\<C-y>" : "\<C-g>u\<CR>"

Ich habe dies in meinem Vimrc

"" YouCompleteMe
let g:ycm_key_list_previous_completion=['<Up>']

"" Ultisnips
let g:UltiSnipsExpandTrigger="<c-tab>"
let g:UltiSnipsListSnippets="<c-s-tab>"

Das habe ich bei meinem ersten Versuch getan, aber ich habe UltiSnips mit Ultisnips falsch geschrieben. Na ja, am Ende hat es geklappt!

Ich persönlich habe mich dafür entschieden, nicht <tab>mit YouCompleteMe zu verwenden, sondern manuell zu navigieren.

Also habe ich dies zu meinem hinzugefügt .vimrc:

let g:ycm_key_list_select_completion=[]
let g:ycm_key_list_previous_completion=[]

tabDadurch wird der Schlüssel für YCM einfach deaktiviert . Stattdessen verwenden Sie die Bewegungstasten (Pfeile oder CTRL-N/ CTRL-P) und wählen den Eintrag mit aus CR. UltiSnips funktioniert standardmäßig mit tab.

Wenn ich nur die Antworten von Michaelslec, Joey Liu und die Lösungen zusammenstelle, die ich in diesem Themen-Thread und im Vimrc dieses Typen gefunden habe , habe ich jetzt diese, die so ziemlich alle Probleme gelöst haben.

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippet()
  if g:ulti_expand_res == 0
    if pumvisible()
      return "\<C-n>"
    else
      call UltiSnips#JumpForwards()
      if g:ulti_jump_forwards_res == 0
        return "\<TAB>"
      endif
    endif
  endif
  return ""
endfunction

function! g:UltiSnips_Reverse()
  call UltiSnips#JumpBackwards()
  if g:ulti_jump_backwards_res == 0
    return "\<C-P>"
  endif

  return ""
endfunction


if !exists("g:UltiSnipsJumpForwardTrigger")
  let g:UltiSnipsJumpForwardTrigger = "<tab>"
endif

if !exists("g:UltiSnipsJumpBackwardTrigger")
  let g:UltiSnipsJumpBackwardTrigger="<s-tab>"
endif

au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger     . " <C-R>=g:UltiSnips_Complete()<cr>"
au InsertEnter * exec "inoremap <silent> " .     g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Obwohl ich weiß, dass dieser Beitrag etwas alt ist, habe ich meine eigene Funktion, die etwas optimierter ist als die oben angegebene:

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippetOrJump()
  if g:ulti_expand_or_jump_res == 0
    if pumvisible()
      return "\<C-N>"
    else
      return "\<TAB>"
    endif
  endif

  return ""
endfunction

Wenn Sie nur die von Joey Liu bereitgestellten Einstellungen beibehalten und dann diese Funktion verwenden, funktioniert natürlich alles perfekt!

BEARBEITEN: Außerdem verwende ich eine andere Funktion, um die Back-Stepping-Funktionalität zwischen YouCompleteMe und UltiSnips zu erhöhen. Ich zeige dir was ich meine:

function! g:UltiSnips_Reverse()                                                                                               
  call UltiSnips#JumpBackwards()                                                                                              
  if g:ulti_jump_backwards_res == 0        
    return "\<C-P>"                                                                                                           
  endif                                                                                                                       

  return ""                                                                                                                   
endfunction

Dann füge dies einfach in deine .vimrc ein:

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Sowie let g:UltiSnipsJumpBackwardTrigger="<s-tab>"und dein Set!

Ich benutze beide zusammen. Standardmäßig YouCompleteMe bindet <Tab>und <Down>den nächsten Abschluss Punkt auszuwählen und auch <S-Tab>und <Up>den vorherigen Abschluss Punkt auszuwählen. Sie können die YouCompleteMe-Bindungen mit den Optionen g: ycm_key_list_select_completion und g: ycm_key_list_previous_completion ändern . Beachten Sie, dass die Namen dieser Optionen kürzlich geändert wurden, als die Option von einer einzelnen Zeichenfolge in eine Liste von Zeichenfolgen geändert wurde.

Ich habe das UltiSnips-Plugin nach dem YouCompleteMe-Plugin installiert, sodass ich dachte, dass sie in Konflikt stehen, aber in Wirklichkeit hatte ich etwas störenderes:

set paste

Stellen Sie sicher, dass .vimrcSie das entfernen, wenn es vorhanden ist.

Während viele Antworten in diesem Beitrag einwandfrei funktionieren, möchte ich nur sagen, dass das Problem durch eine Kollision der Schlüsselbindung zwischen YCM und UltiSnip verursacht wird. Während YCM UltiSnip-Snippets standardmäßig unterstützt, wird der standardmäßige UltiSnip-Erweiterungsauslöser <tab>als Abschlussauswahlschlüssel verwendet UltiSnip-Snippets werden von nicht erweitert <tab>. Geben Sie ihnen eine andere Schlüsselbindung, um das Problem zu lösen. Ich persönlich verwende <c-nund <c-p>für YCM und verwende die Standardeinstellung <tab>für UltiSnip. Weitere Informationen erhalten Sie mit help youcompletemedoc in vim.

Basierend auf Siegfrieds Antwort verwende ich Folgendes, was natürlicher erscheint:

let g:ycm_key_list_select_completion = ['<C-j>']
let g:ycm_key_list_previous_completion = ['<C-k>']

let g:UltiSnipsExpandTrigger = "<C-l>"
let g:UltiSnipsJumpForwardTrigger = "<C-j>"
let g:UltiSnipsJumpBackwardTrigger = "<C-k>"

Ich verwende die c-hjklBindungen auch woanders (Wechsel von einem Bereich zu einem anderen), aber das wäre nur im normalen Modus, also gibt es kein Problem.

Ich benutze ;UltiSnips, es ist so geschickt für mich

let g:UltiSnipsExpandTrigger = ";"

Ich benutze kj. Das ist was in meinem ist .vimrc:

let g:UltisnipsExpandTrigger="kj".

Es kommt selten vor, dass ich auf ein Wort stoße, das kjdarin enthalten ist. Wenn dies der Fall ist, würde ich nur ein paar Sekunden nach der Eingabe kund dieser Eingabe warten j.

Wie von anderen erwähnt, funktioniert die Zuordnung von Cj zu Ultisnips hervorragend.
let g:UltiSnipsExpandTrigger="<c-j>"

Nun, wenn Sie ein bisschen weiter gehen und xcape installieren und verwenden
xcape -e "Shift_L=Control_R|J"

Sie können nur die Umschalttaste für Utlitsnips verwenden.