Meiner Meinung nach wurde SET XACT_ABORT ON durch das Hinzufügen von BEGIN TRY / BEGIN CATCH in SQL 2k5 überholt. Vor Ausnahmeblöcken in Transact-SQL war es wirklich schwierig, Fehler zu behandeln, und unausgeglichene Prozeduren waren allzu häufig (Prozeduren, die beim Beenden ein anderes @@ TRANCOUNT hatten als beim Eintritt).
Mit der Hinzufügung von Transact-SQL ist die Ausnahmebehandlung viel einfacher, korrekte Prozeduren zu schreiben, die garantiert einen ordnungsgemäßen Ausgleich der Transaktionen gewährleisten. Zum Beispiel verwende ich diese Vorlage für die Ausnahmebehandlung und verschachtelte Transaktionen :
create procedure [usp_my_procedure_name]
as
begin
set nocount on;
declare @trancount int;
set @trancount = @@trancount;
begin try
if @trancount = 0
begin transaction
else
save transaction usp_my_procedure_name;
-- Do the actual work here
lbexit:
if @trancount = 0
commit;
end try
begin catch
declare @error int, @message varchar(4000), @xstate int;
select @error = ERROR_NUMBER(), @message = ERROR_MESSAGE(), @xstate = XACT_STATE();
if @xstate = -1
rollback;
if @xstate = 1 and @trancount = 0
rollback
if @xstate = 1 and @trancount > 0
rollback transaction usp_my_procedure_name;
raiserror ('usp_my_procedure_name: %d: %s', 16, 1, @error, @message) ;
end catch
end
go
Es ermöglicht mir, atomare Prozeduren zu schreiben, die bei behebbaren Fehlern nur ihre eigene Arbeit zurücksetzen.
Eines der Hauptprobleme bei Transact-SQL-Prozeduren ist die Datenreinheit : Manchmal sind die empfangenen Parameter oder die Daten in den Tabellen einfach falsch, was zu doppelten Schlüsselfehlern, referenziellen Einschränkungsfehlern, Überprüfungsbeschränkungsfehlern usw. führt. Schließlich ist dies genau die Rolle dieser Einschränkungen. Wenn diese Datenreinheitsfehler unmöglich wären und alle von der Geschäftslogik erfasst würden, wären die Einschränkungen veraltet (dramatische Übertreibung für den Effekt hinzugefügt). Wenn XACT_ABORT aktiviert ist, gehen all diese Fehler dazu, dass die gesamte Transaktion verloren geht, anstatt Ausnahmeblöcke codieren zu können, die die Ausnahme ordnungsgemäß behandeln. Ein typisches Beispiel ist der Versuch, ein INSERT durchzuführen und bei einer PK-Verletzung zu einem UPDATE zurückzukehren.