Wie kann ich eine Syntaxtabelle in eine andere verschachteln?

Ich habe einen einfachen Modus für den Umgang mit JSON geschrieben. Es verwendet die abgeleitete Maschinerie, um den größten Teil des Codes von json-mode wiederzuverwenden. Eine Ergänzung ist jedoch, dass Sie elisp in den JSON-Text einfügen können, der zum Zeitpunkt der JSON-Übermittlung ausgewertet wird. Zum Beispiel sieht ein Auszug aus dem json so aus:

{
    "parameters": {
        "IRC_USER": "stsquad",
        "PUB_KEY": `(format "\"%s\"" (s-trim (shell-command-to-string "cat ~/.ssh/id_rsa.pub")))`
    }
}

Derzeit ist die Syntaxhervorhebung dieses Textes unterbrochen, da der JSON-Syntax-Hightlighter vom Elisp geworfen wird. Ich möchte eine verschachtelte Syntaxtabelle einrichten, damit das Elisp innerhalb der Escape-Zeichen ordnungsgemäß als Elisp erkannt wird (in diesem Fall habe ich `gewählt). Ich verstehe, dass Sie char-Tabellen (aus denen Syntax-Tabellen erstellt werden) mit etwas verbinden können wie:

(defvar lava-mode-syntax-table
  (let ((json-table (copy-syntax-table json-mode-syntax-table))
        (elisp-table (copy-syntax-table lisp-mode-syntax-table)))
    (set-char-table-parent elisp-table json-table)
    (modify-syntax-entry ?` "(`" json-table)
    (modify-syntax-entry ?` ")`" json-table)
    json-table)
  "LAVA Mode syntax table.
This is a combination of json-mode-syntax-table with an escape into
  lisp-mode-syntax table for the embedded elisp.")

Aber ich verstehe nicht, wie ich die Syntaxtabelle ändern kann, um die untergeordnete Syntax-Tabelle (elisp) zwischen den Escape-Zeichen zu verwenden?

Sie möchten nicht eine Syntaxtabelle (bei der es sich um eine Vektorstruktur handelt) in eine andere verschachteln, sondern einen Puffer einrichten, in dem je nach Position eine Syntaxtabelle anstelle der anderen verwendet wird.

Die andere Antwort beschreibt, wie dies mithilfe der syntax-tabletext-Eigenschaft durchgeführt wird. Hier erfahren Sie, wie Sie dies mit einem der "Multiple Major Mode" -Pakete, dem mmm-Modus , tun . Es wird alles im Primärmodus auf der obersten Ebene des Puffers und die Syntaxtabelle des Submodus, die Regeln für die Schriftsperre, die Keymap usw. in den "Subregionen" verwendet.

(require 'mmm-auto)
(setq mmm-global-mode 'auto)

(mmm-add-classes
 '((eljson :submode emacs-lisp-mode
           :front ": *\\(`\\)" :back "`"
           :front-match 1
           :face mmm-code-submode-face)))

(mmm-add-mode-ext-class 'json-mode "\\.el\\.json\\'" 'eljson)

Dies setzt voraus, dass Ihre Dateien im gemischten Modus benannt sind *.el.json. Passen Sie die Einstellungen entsprechend an.

Installieren mmm-mode, evaluieren Sie nun das oben Gesagte und öffnen Sie (nur dann) eine der fraglichen Dateien.

Ok, lassen Sie uns einige Grundlagen klarstellen.

Das Verschachteln von Syntaxtabellen ist möglich

Syntaxtabellen müssen nicht für den gesamten Puffer global sein. Sie können sie als Texteigenschaften auf bestimmte Regionen anwenden. Dies bedeutet, dass Sie dieelisp Syntaxtabelle tatsächlich nur auf Regionen anwenden können , die von Backticks umgeben sind.

Wie machst du das?

Hier ist eine Möglichkeit, wie Sie das tun können. Diese Methode führt dies unmittelbar vor dem Durchlaufen der Schriftsperre durch den Puffer durch, sodass Ihre Probleme beim Sperren von Schriftarten speziell vermieden werden sollten.

(defun endless/set-syntax-then-fontify (beg end loudly)
  "Apply elisp syntax table to relevant regions before calling font-lock."
  (save-match-data
    (save-excursion
      (save-restriction
        (widen)
        (narrow-to-region beg end)
        (while (search-forward "`" nil 'noerror)
          ;; Using `end' here excludes the `, I don't know which syntax you
          ;; want to apply to that.
          (let ((left (match-end 0)))
            (when (search-forward "`" nil 'noerror)
              (add-text-properties
               left (match-beginning 0)
               (list 'syntax-table emacs-lisp-mode-syntax-table))))))))
  (font-lock-default-fontify-region beg end loudly))

In Ihrer Definition für den Hauptmodus müssen Sie Folgendes hinzufügen:

(set (make-local-variable 'font-lock-fontify-region-function)
     #'endless/set-syntax-then-fontify)

Syntaxtabellen sind nicht dasselbe wie Syntaxhervorhebung

Der Syntax-Textmarker (das Font-Lock-System) verwendet Syntaxtabellen als Teil seiner Informationen, daher sollte die obige Lösung verhindern, dass der Textmarker verrückt wird.

Dies ist jedoch nur ein Teil der Daten. Wenn Sie auch möchten, dass der Text in Backticks genau so gefärbt wird, wie Sie es in einem Elisp-Puffer sehen würden, müssen Sie die obige Funktion erweitern, um dies speziell zu tun.

(defun endless/set-syntax-then-fontify (beg end loudly)
  "Apply elisp syntax table to relevant regions before calling font-lock."
  (save-match-data
    (save-excursion
      (save-restriction
        (widen)
        (narrow-to-region beg end)
        (while (search-forward "`" nil 'noerror)
          ;; Using `end' here excludes the `, I don't know which syntax you
          ;; want to apply to that.
          (let ((left (match-end 0)))
            (when (search-forward "`" nil 'noerror)
              (add-text-properties
               left (match-beginning 0)
               (list 'syntax-table emacs-lisp-mode-syntax-table))))))))
  (font-lock-default-fontify-region beg end loudly)
  ;; Do some specific elisp fontifying here
  (save-match-data
    (save-excursion
      (save-restriction
        (widen)
        (narrow-to-region beg end)
        (while (search-forward "`" nil 'noerror)
          (let ((left (match-end 0)))
            (when (search-forward "`" nil 'noerror)
              ;; Call some function to fontify elisp between `left' and (match-beginning 0)
              )))))))