x86-64-Maschinencode (Linux-Systemaufruf): 78 Byte
RDTSC- Spin-Loop-Timing, Linuxsys_write -Systemaufruf.
x86-64 bietet keine bequeme Möglichkeit, die RDTSC-Referenztaktfrequenz zur Laufzeit abzufragen. Sie können eine MSR lesen (und eine darauf basierende Berechnung durchführen) , aber dies erfordert den Kernel-Modus oder Root + Opening /dev/cpu/%d/msr. Deshalb habe ich beschlossen, die Frequenz als Build-Zeit-Konstante festzulegen. (EinstellenFREQ_RDTSC Bedarf : Jede 32-Bit-Konstante ändert die Größe des Maschinencodes nicht.)
Beachten Sie, dass x86-CPUs seit mehreren Jahren eine feste RDTSC-Frequenz haben, sodass sie nicht als Zeitquelle verwendet werden können als Leistungsindikator für den Kerntakt verwendet werden können, es sei denn, Sie deaktivieren die Frequenzänderungen. (Es gibt aktuelle Leistungsindikatoren für die Zählung realer CPU-Zyklen.) Normalerweise tickt es mit der nominalen Aufkleberfrequenz, z. B. 4,0 GHz für meinen i7-6700k, unabhängig von Turbo oder Stromsparmodus. Wie auch immer, diese Wartezeit hängt nicht vom Lastdurchschnitt ab (wie dies bei einer kalibrierten Verzögerungsschleife der Fall wäre) und reagiert auch nicht auf CPU-Stromsparmaßnahmen.
Dieser Code funktioniert für alle x86-Geräte mit einer Referenzfrequenz unter 2 ^ 32 Hz, dh bis zu ~ 4,29 GHz. Darüber hinaus würden die niedrigen 32 des Zeitstempels in 1 Sekunde vollständig umgebrochen, sodass ich auch die edxhohen 32 Bits des Ergebnisses betrachten müsste .
Zusammenfassung :
Schiebe 00:00:00\nauf den Stapel. Dann in einer Schleife:
sys_write Systemaufruf- ADC-Schleife über die Ziffern (beginnend mit der letzten), um die Zeit um 1 zu erhöhen. Wrapping / Carry-In mit einem
cmp/ behandelt cmov, wobei das CF-Ergebnis den Carry-In für die nächste Ziffer liefert.
rdtsc und speichern Sie die Startzeit.- drehen Sie,
rdtscbis das Delta> = Ticks pro Sekunde der RDTSC-Frequenz ist.
NASM-Auflistung:
1 Address ; mov %1, %2 ; use this macro to copy 64-bit registers in 2 bytes (no REX prefix)
2 Machine code %macro MOVE 2
3 bytes push %2
4 pop %1
5 %endmacro
6
7 ; frequency as a build-time constant because there's no easy way detect it without root + system calls, or kernel mode.
8 FREQ_RDTSC equ 4000000000
9 global _start
10 _start:
11 00000000 6A0A push 0xa ; newline
12 00000002 48BB30303A30303A3030 mov rbx, "00:00:00"
13 0000000C 53 push rbx
14 ; rsp points to `00:00:00\n`
20
21 ; rbp = 0 (Linux process startup. push imm8 / pop is as short as LEA for small constants)
22 ; low byte of rbx = '0'
23 .print:
24 ; edx potentially holds garbage (from rdtsc)
25
26 0000000D 8D4501 lea eax, [rbp+1] ; __NR_write = 1
27 00000010 89C7 mov edi, eax ; fd = 1 = stdout
28 MOVE rsi, rsp
28 00000012 54 <1> push %2
28 00000013 5E <1> pop %1
29 00000014 8D5008 lea edx, [rax-1 + 9] ; len = 9 bytes.
30 00000017 0F05 syscall ; sys_write(1, buf, 9)
31
32 ;; increment counter string: least-significant digits are at high addresses (in printing order)
33 00000019 FD std ; so loop backwards from the end, wrapping each digit manually
34 0000001A 488D7E07 lea rdi, [rsi+7]
35 MOVE rsi, rdi
35 0000001E 57 <1> push %2
35 0000001F 5E <1> pop %1
36
37 ;; edx=9 from the system call
38 00000020 83C2FA add edx, -9 + 3 ; edx=3 and set CF (so the low digit of seconds will be incremented by the carry-in)
39 ;stc
40 .string_increment_60: ; do {
41 00000023 66B93902 mov cx, 0x0200 + '9' ; saves 1 byte vs. ecx.
42 ; cl = '9' = wrap limit for manual carry of low digit. ch = 2 = digit counter
43 .digitpair:
44 00000027 AC lodsb
45 00000028 1400 adc al, 0 ; carry-in = cmp from previous iteration; other instructions preserve CF
46 0000002A 38C1 cmp cl, al ; manual carry-out + wrapping at '9' or '5'
47 0000002C 0F42C3 cmovc eax, ebx ; bl = '0'. 1B shorter than JNC over a MOV al, '0'
48 0000002F AA stosb
49
50 00000030 8D49FC lea ecx, [rcx-4] ; '9' -> '5' for the tens digit, so we wrap at 59
51 00000033 FECD dec ch
52 00000035 75F0 jnz .digitpair
53 ; hours wrap from 59 to 00, so the max count is 59:59:59
54
55 00000037 AC lodsb ; skip the ":" separator
56 00000038 AA stosb ; and increment rdi by storing the byte back again. scasb would clobber CF
57
58 00000039 FFCA dec edx
59 0000003B 75E6 jnz .string_increment_60
60
61 ; busy-wait for 1 second. Note that time spent printing isn't counted, so error accumulates with a bias in one direction
62 0000003D 0F31 rdtsc ; looking only at the 32-bit low halves works as long as RDTSC freq < 2^32 = ~4.29GHz
63 0000003F 89C1 mov ecx, eax ; ecx = start
64 .spinwait:
65 ; pause
66 00000041 0F31 rdtsc ; edx:eax = reference cycles since boot
67 00000043 29C8 sub eax, ecx ; delta = now - start. This may wrap, but now we have the delta ready for a normal compare
68 00000045 3D00286BEE cmp eax, FREQ_RDTSC ; } while(delta < counts_per_second)
69 ; cmp eax, 40 ; fast count to test printing
70 0000004A 72F5 jb .spinwait
71
72 0000004C EBBF jmp .print
next address = 0x4E = size = 78 bytes.
Kommentieren Sie die pauseAnweisung aus, um signifikanten Strom zu sparen: Dies erwärmt einen Kern um ~ 15 ° C ohne pause, aber nur um ~ 9 mit pause. (Auf Skylake, wo pausefür ~ 100 Zyklen statt ~ 5 geschlafen wird. Ich denke, es würde mehr sparen, wenn rdtsces nicht auch langsam wäre, so dass die CPU nicht viel Zeit benötigt).
Eine 32-Bit-Version wäre einige Bytes kürzer, z. B. wenn Sie eine 32-Bit-Version davon verwenden, um die anfängliche 00: 00: 00 \ n-Zeichenfolge zu übertragen.
16 ; mov ebx, "00:0"
17 ; push rbx
18 ; bswap ebx
19 ; mov dword [rsp+4], ebx ; in 32-bit mode, mov-imm / push / bswap / push would be 9 bytes vs. 11
Und auch mit 1 Byte dec edx. Der int 0x80Systemaufruf ABI würde esi / edi nicht verwenden, so dass die Registereinstellung für den Syscall gegenüber lodsb / stosb möglicherweise einfacher ist.
