Wie kann ich eine DMG-Datei vor den Fenstern öffnen?

Wann immer ich eine .dmgDatei herunterlade und dann öffne (normalerweise über die Downloadleiste in Chrome), wird sie im Hintergrund geöffnet. Gibt es eine Möglichkeit, es vor meinem Fenster zu öffnen?

Bearbeiten

Zur Verdeutlichung: Ich möchte, dass das DMG-Fenster als aktives Fenster angezeigt wird.

Ich habe in Applescript ein Ordneraktionsskript erstellt, das genau das tut, was Sie wollen. Kopieren Sie es, fügen Sie es in ein neues Applescript ein und speichern Sie es als Anwendung (ohne Startdialog!) In "/ Library / Scripts / Folder Action Scripts /". Sie können es dann an einen beliebigen Ordner anhängen (höchstwahrscheinlich an Ihren Ordner ~ / Downloads /), indem Sie mit der rechten Maustaste auf den Ordner klicken und im Dropdown-Menü "Dienste" die Option "Ordneraktionen konfigurieren" auswählen. Aktivieren Sie Ordneraktionen und lassen Sie das Skript den Ordner überwachen.

Grundsätzlich reagiert das Skript auf Elemente, die in dem Ordner abgelegt wurden, an den es angehängt ist, und wenn das abgelegte Element vom Typ "Image" ist, hängt es das Image über das Befehlszeilentool "hdiutil" als Volume an.

Sie können das Verhalten konfigurieren, indem Sie die Eigenschaften openWindow und makeFrontmost im Skript festlegen. Dies kann auch durch Doppelklicken auf das Skript erfolgen, nachdem Sie es als Anwendung gespeichert haben. Anschließend werden Sie in zwei Dialogfeldern gefragt, wie es sich standardmäßig verhalten soll.

Ich hoffe das hilft,

Asmus

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

2. Applescript, um die Art der in einem Ordner abgelegten Datei zu bestimmen

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

Bearbeitet Muss "Disk Image" und nicht "Image" sein

Soweit ich weiß, zeigt OS X den Inhalt eines Image nur dann automatisch an, wenn es schreibgeschützt ist. Dies wird durch einen Bleistift mit einem Schrägstrich links unten im Finder-Fenster angezeigt, wenn der Inhalt des Bildes angezeigt wird.

Wenn Sie ein Festplatten-Image so ändern möchten, dass dies der Fall ist, können Sie ein vorhandenes Festplatten-Image mithilfe des Festplatten-Dienstprogramms schreibgeschützt machen. Leider ändert dies nichts am Verhalten falsch produzierter Bilder, die Sie möglicherweise aus dem Internet herunterladen.

1. Hängen Sie das Disk-Image ein, das Sie automatisch öffnen möchten.
2. Öffnen Sie das Festplatten-Dienstprogramm, indem Sie mit Spotlight danach suchen.
3. Wählen Sie das Symbol "Neues Bild" in der Symbolleiste.
4. Benennen Sie die Datei und wählen Sie "Schreibgeschützt" unter "Bildformat".
5. Klicken Sie auf "Speichern". Wenn Sie dieses neue Image einbinden, wird automatisch ein Finder-Fenster geöffnet.

Dies beantwortet die Frage wahrscheinlich auch nicht ausreichend, aber ...

Wenn Sie die Befehlstaste drücken und auf das Objekt in der Download-Leiste klicken, wird das Objekt im Finder angezeigt. Wenn Sie an diesem Punkt einfach Befehl-O drücken (oder auf die DMG-Datei doppelklicken), wird sie geladen und in einem neuen Fenster im Vordergrund geöffnet.