Mac, Automatisierung von iTunes Suche nach einer Liste von Wörtern?

Ich möchte mehrere Suchvorgänge in der iTunes-Mac-App ausführen und pausieren, bis ich mit der nächsten Suche fortfahre. Ich habe eine Liste mit Suchanfragen, die ich durchführen möchte.

Also muss ich entweder eine Art Automatisierungsskript erstellen, das mir eine Art Knopf gibt, auf den ich tippen kann, um fortzufahren.

Oder ich brauche etwas, mit dem ich den nächsten Eintrag in meine Liste einfügen kann.

Ich versuche im Grunde etwas Mühe zu sparen, damit ich die Wörter nicht jedes Mal tippen muss.

Ich habe mir Automator, Alfred, Hazel und den AppleScript-Editor angesehen. Aber ich glaube nicht, dass irgendetwas davon funktionieren wird.

Sie können so etwas in Applescript tun. iTunes bietet einen searchBefehl, der auf einen Titel verweist.

Sie können diesen Befehl also in einer Schleife verwenden, die:

• Zeigt ein Dialogfeld an, in dem Sie nach Suchbegriffen gefragt werden.
• In einem Multiple-Choice-Dialogfeld werden iTunes-Übereinstimmungen für diesen Suchbegriff angezeigt.
• In diesem Dialog wählen Sie den gewünschten Titel aus. Anschließend können Sie Ihre benutzerdefinierte Warteschlange einzeln wiedergeben.

Code:

set lst_tracks to {}
try
    repeat
        display dialog "Please enter search terms" buttons {"Stop Searching", "Search More"} default button 2 cancel button 1 default answer ""
        set the_text to (text returned of result)
        tell application "iTunes"
            set end of lst_tracks to my GetiTunesTrack(the_text)
        end tell
    end repeat
end try
if lst_tracks ≠ {} then
    set the_result to (display dialog "Start Playing?" buttons {"No", "Yes"} default button 2 cancel button 1)
    set the_button to button returned of the_result
    if the_button = "Yes" then
        try
            repeat with i in lst_tracks
                tell application "iTunes"
                    set the_track to (contents of i)
                    set track_name to name of the_track
                    play the_track
                    set the_result to (display dialog "Playing: " & track_name buttons {"Stop", "Next Track"} default button 2 cancel button 1)
                end tell
            end repeat
        on error
            tell application "iTunes" to stop
        end try
    end if
end if
display dialog "Finish"

on GetiTunesTrack(search_str)
    local lst_names

    set lst_names to {}
    tell application "iTunes"
        set lst_results to (search library playlist 1 for search_str)

        repeat with item_ref in lst_results
            set end of lst_names to name of item_ref
        end repeat

        set the_selection to item 1 of (choose from list lst_names with prompt "Choose a Track" default items (item 1 of lst_names))
        set the_track to first track of library playlist 1 whose (name is the_selection)
        return the_track
    end tell
end GetiTunesTrack