Sagen wir, ich habe eine Formel wie (Q7+Q11)÷Q20 in der Zelle O20 und ich möchte es in eine andere Zelle kopieren, sagen wir mal D47Gibt es einen Schlüsselmodifikator oder eine Tastenkombination, um dies zu tun, ohne die ursprünglichen Verweise der Formel zu verlieren und ohne sie neu zu schreiben?

So etwas wie Cmd+Alt ziehen und ablegen ?

Ich bin mit Nummer 4 unter Mac OS Sierra

Mit der eingebauten Methode

Wie pro Apples Wissensdatenbank , Numbers unterstützt absolute referenzen :

Sie können Zeilen- und Spaltenreferenzen in einer Formel als absolut festlegen, sodass Sie dieselbe Formel an anderer Stelle in Ihrer Tabelle verwenden können, ohne dass sich die Zellreferenzen ändern, wie dies ansonsten der Fall wäre.

Gehen Sie folgendermaßen vor, um Ihre ursprüngliche Formel zu ändern, um absolute Verweise zu verwenden:

1. Doppelklicken Sie auf die ursprüngliche Zelle, um in den Bearbeitungsmodus zu wechseln.
2. Klicken Sie für jede Referenz auf das Dreieck. kreuzen Sie dann beide Kästchen an Zeile beibehalten und Spalte beibehalten.

Alternativ zu Schritt 2 können Sie die Referenz auch manuell bearbeiten, indem Sie beispielsweise e eingeben. G. $A$1 anstatt A1.

Das Offensichtliche Nachteile dieser Methode sind:

• Die Methode sperrt Ihre Formel grundsätzlich in einem Modus, der es schwierig macht, dieselbe Formel an anderen Stellen wiederzuverwenden, an denen Sie sie tatsächlich verwenden wollen flexible Referenzen.

• Wenn Sie viele verschiedene Originalformeln kopieren möchten, müssen Sie die Methode immer wieder wiederholen.

Mit einem AppleScript zu Formeln kopieren

Ein wiederverwendbarer Ansatz wäre ein einfacher AppleScript, das das repliziert Kopieren Befehl kopiert aber nur die nackten Formeln:

on join(cells, delimiter)
  set previousDelimiters to AppleScript's text item delimiters
  set AppleScript's text item delimiters to delimiter
  set resultString to (cells as text)
  set AppleScript's text item delimiters to previousDelimiters
  return resultString
end join

on getSelectedFormulas()
  set tab to character id 9
  set lf to character id 10

  tell application "Numbers"
    tell document 1's sheet 1's table 1
      tell selection range
        set {min, max} to {column 1's address, column -1's address}
        set formulaRows to {}
        repeat with aRow in rows
          set formulaCells to {}
          repeat with aCell in aRow's cells min thru max
            set formulaCells to formulaCells & (aCell's formula)
          end repeat
          set formulaRows to formulaRows & ¬
            my join(formulaCells, tab)
        end repeat
        return my join(formulaRows, lf)
      end tell
    end tell
  end tell
end getSelectedFormulas

on run()
  tell application "Numbers"
    set the clipboard to my getSelectedFormulas()
  end tell
end run

(Hinweis: Ich bin der Autor des Skripts. Es befindet sich unter der ISC Open Source Lizenz .)

Dadurch entfällt auch die Notwendigkeit, die ursprünglichen Formeln zu ändern.

Binden des Skripts an eine Tastenkombination

Öffnen Sie Automator.app, um dieses Skript an eine Tastenkombination in Numbers zu binden und einen Automator-Workflow zu erstellen. Wählen Sie die Option Dienst erhält keine Eingabe in Zahlen , erstelle eine Single Führen Sie AppleScript aus Schritt und fügen Sie den AppleScript-Code dort ein.

Speichern Sie den Workflow unter dem Namen Copy Formulas, dann öffne Systemeinstellungen und klicken Sie auf Tastatur, dann Tastatürkürzel » Dienstleistungen » Zahlen » Formeln kopieren. Konfigurieren Sie eine Tastenkombination. Ich würde empfehlen ⌥⇧⌘C weil Sie es wahrscheinlich oft mit seinem Gegenüber verwenden werden, Einfügen und Anpassen, das hat schon die Abkürzung ⌥⇧⌘V .