Platzieren der Desktopsymbole links statt rechts

Beliebige Möglichkeit, Aliasnamen oder Symbole automatisch auf der linken Seite des Apple Desktops anzuzeigen. Standardmäßig gehen sie nach rechts.

Es gibt keine Möglichkeit, Symbole zu zwingen, automatisch nach links zu gehen (und nach dem ausgewählten Kriterium angeordnet zu bleiben).

Um dieses Problem zu umgehen, können Sie die Ansichtsoptionen im Finder so ändern , dass Elemente nicht nach einem Kriterium angeordnet werden und die Symbole manuell links platziert werden.

• Klicken Sie auf eine freie Stelle auf dem Desktop.
• Drücken Sie Cmd+ Joder navigieren Sie mit der Maus zum Menü Ansicht des Finders > Ansichtsoptionen anzeigen.
• Im Sortieren nach: Drop - Down im Dialog wählen Sie entweder keine oder Raster ausrichten .
• Sie können Dateien überall auf Ihrem Desktop ablegen und sie bleiben dort.

Weitere Informationen finden Sie unter Mac-Grundlagen: Ändern Ihrer Fenster .

Sehen Sie sich auch die Mac-Grundlagen an, um mehr über die Verwendung eines Mac zu erfahren.

Dies ist nicht die beste Lösung, aber es kann funktionieren, wenn nichts anderes tut ...

1. Erstellen Sie eine Automator-Ordneraktion, die dem Desktop zugeordnet ist.
2. Fügen Sie den Artikel hinzu: "run applescript"

3. Fügen Sie den folgenden Code in das Applescript-Textfeld ein:

   -- https://gist.github.com/mrienstra/8330528
   -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
   -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
   
   -- Rearranges Desktop icons to flow from left to right, top to bottom.
   
   -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
   
   -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
   
   -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
   
   
   
   -- Adjust these for different spacing
   property theSpacingFactor : 1.0
   property theGutterXFactor : 0.57
   property theGutterYFactor : 0.57
   
   
   
   on rearrangeDesktopIcons()
       tell application "Finder"
           tell icon view options of window of desktop
               set theArrangement to arrangement
               set theArrangementString to theArrangement as string
               if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                   display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                   return
               end if
               set theIconSize to icon size
               set theLabelSize to text size
           end tell
   
           set theDesktopBounds to bounds of window of desktop
           set theDesktopWidth to item 3 of theDesktopBounds
           set theDesktopHeight to item 4 of theDesktopBounds
   
           -- Retrieve a list of items on the desktop
           set theDesktopItems to every item of desktop
           set theContestantOffset to theIconSize / 2
   
           set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
           set theGuttersX to theSpacing * theGutterXFactor
           set theGuttersY to theSpacing * theGutterYFactor
           set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
           set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
           set theMaxLocations to theMaxRows * theMaxColumns
   
           set y to 1
           repeat with a from 1 to length of theDesktopItems
               set x to a mod theMaxColumns
               if x is 0 then
                   set x to theMaxColumns
               end if
   
               if a is greater than theMaxLocations then
                   set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
               else
                   set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
               end if
   
               if a mod theMaxColumns is 0 then
                   set y to y + 1
               end if
           end repeat
       end tell
   end rearrangeDesktopIcons
   
   
   
   on adding folder items to alias after receiving listOfAlias
       rearrangeDesktopIcons()
   end adding folder items to
   
   on removing folder items from alias after losing listOfAliasOrText
       rearrangeDesktopIcons()
   end removing folder items from
   
   rearrangeDesktopIcons()
   

Wenn also eine Datei zu Ihrem Desktop hinzugefügt wird, werden alle Dateien alphabetisch neu angeordnet ...

Ordnen Sie alle Ordner in der gewünschten Reihenfolge. Klicken Sie dann unter "Ansicht" auf "Aufräumen". Dies wird alles schön ausrichten. Dann können Sie einfach alle Ordner markieren und genau dort platzieren, wo Sie sie haben möchten. Macs organisieren Ordner nicht auf der linken Seite, sondern nur auf der rechten Seite. Mit ein paar einfachen Schritten können Sie jedoch alles auf der linken Seite ordentlich organisieren.

Ich habe nur alle Ordner auf der rechten Seite markiert, sie dann alle gepackt und auf der linken Seite eingefügt.